Version bumped. Make ebuild detect if it is a snapshot or normal version.

(Portage version: 2.1.2.3)

5 files changed, 184 insertions, 7 deletions

diff --git a/media-plugins/vdr-softdevice/ChangeLog b/media-plugins/vdr-softdevice/ChangeLog
index caeb33249ce1..28bddb477179 100644
--- a/media-plugins/vdr-softdevice/ChangeLog
+++ b/media-plugins/vdr-softdevice/ChangeLog
@@ -1,6 +1,13 @@
 # ChangeLog for media-plugins/vdr-softdevice
 # Copyright 1999-2007 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-plugins/vdr-softdevice/ChangeLog,v 1.36 2007/04/10 09:38:13 zzam Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-plugins/vdr-softdevice/ChangeLog,v 1.37 2007/04/11 15:38:25 zzam Exp $
+
+*vdr-softdevice-0.4.0 (11 Apr 2007)
+
+  11 Apr 2007; Matthias Schwarzott <zzam@gentoo.org>
+  +files/vdr-softdevice-0.4.0-xinerama-configure-opts.patch,
+  vdr-softdevice-0.3.1.20070410.ebuild, +vdr-softdevice-0.4.0.ebuild:
+  Version bumped. Make ebuild detect if it is a snapshot or normal version.
 
 *vdr-softdevice-0.3.1.20070410 (10 Apr 2007)
 
diff --git a/media-plugins/vdr-softdevice/files/digest-vdr-softdevice-0.4.0 b/media-plugins/vdr-softdevice/files/digest-vdr-softdevice-0.4.0
new file mode 100644
index 000000000000..3a934228ef70
--- /dev/null
+++ b/media-plugins/vdr-softdevice/files/digest-vdr-softdevice-0.4.0
@@ -0,0 +1,3 @@
+MD5 216dff52bbde4cd5ed30a8c71938d064 vdr-softdevice-0.4.0.tgz 190505
+RMD160 78c49568776b71d3b892de8cdc7406f31fd90115 vdr-softdevice-0.4.0.tgz 190505
+SHA256 4a43426e03a36771bce272123d2b3a0a7dc5aac05b98277a985ba277e3c0b9c9 vdr-softdevice-0.4.0.tgz 190505
diff --git a/media-plugins/vdr-softdevice/files/vdr-softdevice-0.4.0-xinerama-configure-opts.patch b/media-plugins/vdr-softdevice/files/vdr-softdevice-0.4.0-xinerama-configure-opts.patch
new file mode 100644
index 000000000000..d9e735bf1c00
--- /dev/null
+++ b/media-plugins/vdr-softdevice/files/vdr-softdevice-0.4.0-xinerama-configure-opts.patch
@@ -0,0 +1,19 @@
+diff -ru softdevice-0.4.0-orig/configure softdevice-0.4.0/configure
+--- softdevice-0.4.0-orig/configure	2007-04-11 17:30:54.486914045 +0200
++++ softdevice-0.4.0/configure	2007-04-11 17:31:38.619850758 +0200
+@@ -59,6 +59,7 @@
+   echo "  --disable-mmx"
+   echo "  --disable-mmx2"
+   echo "  --disable-alsa"
++  echo "  --disable-xinerama"
+   echo "  --disable-oss"
+   echo "  --disable-suspendkey"
+   echo "  --disable-yaepg / --enable-yapg (yaepg patch support)"
+@@ -83,6 +84,7 @@
+     --disable-mmx) shift; with_mmx="no";;
+     --disable-mmx2) shift; with_mmx2="no";;
+     --disable-alsa) shift; alsa="no";;
++    --disable-xinerama) shift; xinerama="no";;
+     --disable-oss) shift; oss="no";;
+     --disable-suspendkey) shift; suspendkey="no";;
+     --disable-yaepg) shift; yaepg="no";;
diff --git a/media-plugins/vdr-softdevice/vdr-softdevice-0.3.1.20070410.ebuild b/media-plugins/vdr-softdevice/vdr-softdevice-0.3.1.20070410.ebuild
index d2008dfced48..9e9406879c3d 100644
--- a/media-plugins/vdr-softdevice/vdr-softdevice-0.3.1.20070410.ebuild
+++ b/media-plugins/vdr-softdevice/vdr-softdevice-0.3.1.20070410.ebuild
@@ -1,16 +1,23 @@
 # Copyright 1999-2007 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/media-plugins/vdr-softdevice/vdr-softdevice-0.3.1.20070410.ebuild,v 1.1 2007/04/10 09:38:13 zzam Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-plugins/vdr-softdevice/vdr-softdevice-0.3.1.20070410.ebuild,v 1.2 2007/04/11 15:38:25 zzam Exp $
 
-inherit vdr-plugin
+inherit vdr-plugin versionator
 
-MY_P="${PN}-cvs-${PV#0.3.1.}"
-S="${WORKDIR}/${MY_P#vdr-}"
 
 DESCRIPTION="VDR Plugin: Software output-Device"
 HOMEPAGE="http://softdevice.berlios.de/"
-SRC_URI="mirror://gentoo/${MY_P}.tar.bz2
-		http://dev.gentoo.org/~zzam/distfiles/${MY_P}.tar.bz2"
+
+# Detect snapshots
+SNAP_V="$(get_version_component_range 4)"
+if [[ "$SNAP_V" ]]; then
+	MY_P="${PN}-cvs-${SNAP_V}"
+	S="${WORKDIR}/${MY_P#vdr-}"
+	SRC_URI="mirror://gentoo/${MY_P}.tar.bz2
+			http://dev.gentoo.org/~zzam/distfiles/${MY_P}.tar.bz2"
+else
+	SRC_URI="mirror://berlios/${PN#vdr-}/${P}.tgz"
+fi
 
 LICENSE="GPL-2"
 SLOT="0"
diff --git a/media-plugins/vdr-softdevice/vdr-softdevice-0.4.0.ebuild b/media-plugins/vdr-softdevice/vdr-softdevice-0.4.0.ebuild
new file mode 100644
index 000000000000..3b109a78e973
--- /dev/null
+++ b/media-plugins/vdr-softdevice/vdr-softdevice-0.4.0.ebuild
@@ -0,0 +1,141 @@
+# Copyright 1999-2007 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-plugins/vdr-softdevice/vdr-softdevice-0.4.0.ebuild,v 1.1 2007/04/11 15:38:25 zzam Exp $
+
+inherit vdr-plugin versionator
+
+
+DESCRIPTION="VDR Plugin: Software output-Device"
+HOMEPAGE="http://softdevice.berlios.de/"
+
+# Detect snapshots
+SNAP_V="$(get_version_component_range 4)"
+if [[ "$SNAP_V" ]]; then
+	MY_P="${PN}-cvs-${SNAP_V}"
+	S="${WORKDIR}/${MY_P#vdr-}"
+	SRC_URI="mirror://gentoo/${MY_P}.tar.bz2
+			http://dev.gentoo.org/~zzam/distfiles/${MY_P}.tar.bz2"
+else
+	SRC_URI="mirror://berlios/${PN#vdr-}/${P}.tgz"
+fi
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="xv fbcon directfb mmx mmxext xinerama"
+
+RDEPEND=">=media-video/vdr-1.3.36
+	>=media-video/ffmpeg-0.4.9_pre1
+	directfb? (
+		dev-libs/DirectFB
+		dev-libs/DFB++
+	)
+	media-libs/alsa-lib
+	xv? ( || ( ( x11-libs/libX11
+				x11-libs/libXext
+				x11-libs/libXi
+				x11-libs/libXv
+				xinerama? ( x11-libs/libXinerama )
+			)
+			virtual/x11
+		) )"
+
+DEPEND="${RDEPEND}
+	xv? ( || ( ( x11-proto/xproto
+				x11-proto/xextproto
+				x11-libs/libXv
+				xinerama? ( x11-proto/xineramaproto )
+			)
+			virtual/x11
+	) )
+	fbcon? ( sys-kernel/linux-headers )
+	dev-util/pkgconfig"
+# Make sure the assembler USE flags are unmasked on amd64
+# Remove this once default-linux/amd64/2006.1 is deprecated
+DEPEND="${DEPEND} amd64? ( >=sys-apps/portage-2.1.2 )"
+
+PATCHES="
+		${FILESDIR}/${PN}-0.2.3-shm-fullscreen.diff
+		${FILESDIR}/${PN}-0.4.0-xinerama-configure-opts.patch
+		${FILESDIR}/${PN}-0.3.1-osdmode-software-default.diff"
+
+pkg_setup() {
+	vdr-plugin_pkg_setup
+
+	if use !xv && use !fbcon && use !directfb; then
+		ewarn "You need to set at least one of these use-flags: xv fbcon directfb"
+		die "no output-method enabled"
+	fi
+
+	COMPILE_SHM=0
+	if has_version ">=media-video/vdr-1.3.0"; then
+		if use xv; then
+			COMPILE_SHM=1
+		else
+			elog "SHM does only support xv at the moment"
+		fi
+	else
+		elog "SHM not supported on vdr-1.2"
+	fi
+	case ${COMPILE_SHM} in
+		0)	elog "SHM support will not be compiled." ;;
+		1)	elog "SHM support will be compiled." ;;
+	esac
+
+	# Check for ffmpeg relying on libtheora without pkg-config-file
+	# Bug #142250
+	if built_with_use media-video/ffmpeg theora	&& \
+		has_version "<media-libs/libtheora/libtheora-1.0_alpha4"; then
+
+			eerror "This package will not work when using ffmpeg with"
+			eerror "USE=\"theora\" combined with media-libs/libtheora"
+			eerror "older than version 1.0_alpha4."
+			eerror "Please update to at least media-libs/libtheora-1.0_alpha4."
+			die "Please update to at least media-libs/libtheora-1.0_alpha4."
+	fi
+}
+
+src_compile() {
+	local MYOPTS=""
+	MYOPTS="${MYOPTS} --disable-vidix"
+	use xv || MYOPTS="${MYOPTS} --disable-xv"
+	use fbcon || MYOPTS="${MYOPTS} --disable-fb"
+	use directfb || MYOPTS="${MYOPTS} --disable-dfb"
+
+	use mmx || MYOPTS="${MYOPTS} --disable-mmx"
+	use mmxext || MYOPTS="${MYOPTS} --disable-mmx2"
+
+	if use !mmx && use !mmxext; then
+		ewarn "${PN}"' does not compile with USE="-mmx -mmxext".'
+		ewarn 'Please enable at least one of these two use-flags.'
+		die "${PN}"' does not compile with USE="-mmx -mmxext".'
+	fi
+
+	use xinerama || MYOPTS="${MYOPTS} --disable-xinerama"
+
+	[[ ${COMPILE_SHM} == 1 ]] || MYOPTS="${MYOPTS} --disable-shm"
+
+	cd ${S}
+	elog configure ${MYOPTS}
+	./configure ${MYOPTS} || die "configure failed"
+
+	vdr-plugin_src_compile
+}
+
+src_install() {
+	vdr-plugin_src_install
+
+	cd ${S}
+
+	insinto "${VDR_PLUGIN_DIR}"
+	doins libsoftdevice-*.so.*
+
+	if [[ "${COMPILE_SHM}" = "1" ]]; then
+		exeinto "/usr/bin"
+		doexe ShmClient
+	fi
+
+	insinto /usr/include/vdr-softdevice
+	doins *.h
+}
+