Revision bump adds multibuild support by Karol Herbst <git@karolherbst.de>.

(Portage version: 2.2.18/cvs/Linux x86_64, signed Manifest commit with key F3CFD2BD)

2 files changed, 86 insertions, 1 deletions

diff --git a/media-libs/qt-gstreamer/ChangeLog b/media-libs/qt-gstreamer/ChangeLog
index a13983e7e72a..362f0060c402 100644
--- a/media-libs/qt-gstreamer/ChangeLog
+++ b/media-libs/qt-gstreamer/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for media-libs/qt-gstreamer
 # Copyright 1999-2015 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-libs/qt-gstreamer/ChangeLog,v 1.21 2015/01/31 12:11:09 johu Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-libs/qt-gstreamer/ChangeLog,v 1.22 2015/03/05 19:38:35 johu Exp $
+
+*qt-gstreamer-1.2.0-r1 (05 Mar 2015)
+
+  05 Mar 2015; Johannes Huber <johu@gentoo.org> +qt-gstreamer-1.2.0-r1.ebuild:
+  Revision bump adds multibuild support by Karol Herbst <git@karolherbst.de>.
 
   31 Jan 2015; Johannes Huber <johu@gentoo.org> -qt-gstreamer-0.10.3.ebuild,
   qt-gstreamer-1.2.0.ebuild:
diff --git a/media-libs/qt-gstreamer/qt-gstreamer-1.2.0-r1.ebuild b/media-libs/qt-gstreamer/qt-gstreamer-1.2.0-r1.ebuild
new file mode 100644
index 000000000000..12d3837c1e7d
--- /dev/null
+++ b/media-libs/qt-gstreamer/qt-gstreamer-1.2.0-r1.ebuild
@@ -0,0 +1,80 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-libs/qt-gstreamer/qt-gstreamer-1.2.0-r1.ebuild,v 1.1 2015/03/05 19:38:35 johu Exp $
+
+EAPI=5
+
+if [[ ${PV} != *9999* ]]; then
+	SRC_URI="http://gstreamer.freedesktop.org/src/${PN}/${P}.tar.xz"
+	KEYWORDS="~amd64 ~arm ~x86"
+else
+	GIT_ECLASS="git-r3"
+	EGIT_REPO_URI=( "git://anongit.freedesktop.org/gstreamer/${PN}" )
+	KEYWORDS=""
+fi
+
+inherit cmake-utils ${GIT_ECLASS} multibuild
+
+DESCRIPTION="QtGStreamer provides C++ bindings for GStreamer with a Qt-style API"
+HOMEPAGE="http://gstreamer.freedesktop.org/modules/qt-gstreamer.html"
+
+LICENSE="LGPL-2.1"
+SLOT="0"
+IUSE="qt4 qt5 test"
+
+RDEPEND="
+	dev-libs/glib:2
+	>=dev-libs/boost-1.40:=
+	qt4? (
+		dev-qt/qtcore:4
+		dev-qt/qtdeclarative:4
+		dev-qt/qtgui:4
+		dev-qt/qtopengl:4
+	)
+	qt5? (
+		dev-qt/qtcore:5
+		dev-qt/qtdeclarative:5
+		dev-qt/qtgui:5
+		dev-qt/qtopengl:5
+		dev-qt/qtquick1:5
+		dev-qt/qtwidgets:5
+	)
+	media-libs/gstreamer:1.0
+	media-libs/gst-plugins-base:1.0
+"
+DEPEND="
+	${RDEPEND}
+	test? (
+		qt4? (
+			dev-qt/qttest:4
+		)
+	)
+"
+
+# bug 497880
+RESTRICT="test"
+
+pkg_setup() {
+	MULTIBUILD_VARIANTS=( $(usex qt4 4 '') $(usex qt5 5 '') )
+}
+
+src_configure() {
+	myconfigure() {
+		local mycmakeargs=(
+			-DQTGSTREAMER_EXAMPLES=OFF
+			$(cmake-utils_use test QTGSTREAMER_TESTS)
+			-DQT_VERSION=${MULTIBUILD_VARIANT}
+		)
+		cmake-utils_src_configure
+	}
+
+	multibuild_foreach_variant myconfigure
+}
+
+src_compile() {
+	multibuild_foreach_variant cmake-utils_src_compile
+}
+
+src_install() {
+	multibuild_foreach_variant cmake-utils_src_install
+}