Default to alsa support, fix jack deps, and add REQUIRED_USE (fixes bug #514304).

(Portage version: 2.2.10/cvs/Linux x86_64, signed Manifest commit with key 4AB3E85B4F064CA3)

2 files changed, 72 insertions, 2 deletions

diff --git a/media-libs/rtaudio/ChangeLog b/media-libs/rtaudio/ChangeLog
index 301908981812..e0988aa5b5ec 100644
--- a/media-libs/rtaudio/ChangeLog
+++ b/media-libs/rtaudio/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for media-libs/rtaudio
-# Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-libs/rtaudio/ChangeLog,v 1.2 2013/06/15 11:43:29 radhermit Exp $
+# Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/media-libs/rtaudio/ChangeLog,v 1.3 2014/06/22 00:57:30 radhermit Exp $
+
+*rtaudio-4.0.12-r1 (22 Jun 2014)
+
+  22 Jun 2014; Tim Harder <radhermit@gentoo.org> +rtaudio-4.0.12-r1.ebuild:
+  Default to alsa support, fix jack deps, and add REQUIRED_USE (fixes bug
+  #514304).
 
 *rtaudio-4.0.12 (15 Jun 2013)
 
diff --git a/media-libs/rtaudio/rtaudio-4.0.12-r1.ebuild b/media-libs/rtaudio/rtaudio-4.0.12-r1.ebuild
new file mode 100644
index 000000000000..9d2843e7826b
--- /dev/null
+++ b/media-libs/rtaudio/rtaudio-4.0.12-r1.ebuild
@@ -0,0 +1,64 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-libs/rtaudio/rtaudio-4.0.12-r1.ebuild,v 1.1 2014/06/22 00:57:30 radhermit Exp $
+
+EAPI=5
+
+inherit eutils autotools toolchain-funcs
+
+DESCRIPTION="A set of cross-platform C++ classes for realtime audio I/O"
+HOMEPAGE="http://www.music.mcgill.ca/~gary/rtaudio/"
+SRC_URI="http://www.music.mcgill.ca/~gary/${PN}/release/${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="+alsa doc jack pulseaudio static-libs"
+REQUIRED_USE="|| ( alsa jack pulseaudio )"
+
+RDEPEND="alsa? ( media-libs/alsa-lib )
+	jack? (
+		media-libs/alsa-lib
+		media-sound/jack-audio-connection-kit
+	)
+	pulseaudio? ( media-sound/pulseaudio )"
+DEPEND="${RDEPEND}"
+
+src_prepare() {
+	epatch "${FILESDIR}"/${PN}-4.0.11-cflags.patch
+	epatch "${FILESDIR}"/${P}-makefile.patch
+	epatch "${FILESDIR}"/${P}-configure.patch
+
+	if ! use static-libs ; then
+		sed -i '/^LIBRARIES =/s/$(STATIC)//' Makefile.in || die
+	fi
+
+	eautoreconf
+}
+
+src_configure() {
+	# OSS support requires OSSv4
+	econf \
+		--without-oss \
+		$(use_with alsa) \
+		$(use_with jack) \
+		$(use_with pulseaudio pulse)
+}
+
+src_compile() {
+	emake AR="$(tc-getAR)"
+}
+
+src_install() {
+	dolib.so librtaudio.so*
+	use static-libs && dolib.a librtaudio.a
+
+	dobin rtaudio-config
+	doheader *.h
+	dodoc readme doc/release.txt
+
+	if use doc ; then
+		dohtml -r doc/html/*
+		dodoc -r doc/images
+	fi
+}