Version bump.

(Portage version: 2.2.0_alpha43/cvs/Linux x86_64)

2 files changed, 75 insertions, 1 deletions

diff --git a/media-libs/raptor/ChangeLog b/media-libs/raptor/ChangeLog
index 6864793eb34e..39565123726b 100644
--- a/media-libs/raptor/ChangeLog
+++ b/media-libs/raptor/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for media-libs/raptor
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-libs/raptor/ChangeLog,v 1.94 2011/05/03 12:20:14 grobian Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-libs/raptor/ChangeLog,v 1.95 2011/07/09 07:57:24 ssuominen Exp $
+
+*raptor-2.0.3 (09 Jul 2011)
+
+  09 Jul 2011; Samuli Suominen <ssuominen@gentoo.org> +raptor-2.0.3.ebuild:
+  Version bump.
 
   03 May 2011; Fabian Groffen <grobian@gentoo.org> raptor-1.4.21-r1.ebuild,
   raptor-2.0.2.ebuild:
diff --git a/media-libs/raptor/raptor-2.0.3.ebuild b/media-libs/raptor/raptor-2.0.3.ebuild
new file mode 100644
index 000000000000..c0a1209d2784
--- /dev/null
+++ b/media-libs/raptor/raptor-2.0.3.ebuild
@@ -0,0 +1,69 @@
+# Copyright 1999-2011 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-libs/raptor/raptor-2.0.3.ebuild,v 1.1 2011/07/09 07:57:24 ssuominen Exp $
+
+EAPI=4
+inherit eutils libtool
+
+MY_P=${PN}2-${PV}
+
+DESCRIPTION="The RDF Parser Toolkit"
+HOMEPAGE="http://librdf.org/raptor/"
+SRC_URI="http://download.librdf.org/source/${MY_P}.tar.gz"
+
+LICENSE="Apache-2.0 GPL-2 LGPL-2.1"
+SLOT="2"
+KEYWORDS="~amd64 ~arm ~hppa ~ppc ~ppc64 ~x86 ~x86-fbsd ~x64-freebsd ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
+IUSE="+curl debug json static-libs unicode +xml"
+
+RDEPEND="unicode? ( dev-libs/glib:2 )
+	xml? ( >=dev-libs/libxml2-2.6.8 )
+	!xml? ( dev-libs/expat )
+	curl? ( net-misc/curl )
+	json? ( dev-libs/yajl )
+	dev-libs/libxslt
+	!<media-libs/raptor-1.4.21-r1"
+DEPEND="${RDEPEND}
+	sys-devel/flex
+	dev-util/pkgconfig"
+
+S=${WORKDIR}/${MY_P}
+
+DOCS=( AUTHORS ChangeLog NEWS NOTICE README )
+
+src_prepare() {
+	epunt_cxx
+	elibtoolize
+}
+
+src_configure() {
+	local myconf
+
+	if use xml; then
+		myconf+=" --with-xml-parser=libxml"
+	else
+		myconf+=" --with-xml-parser=expat"
+	fi
+
+	if use curl; then
+		myconf+=" --with-www=curl"
+	elif use xml; then
+		myconf+=" --with-www=xml"
+	else
+		myconf+=" --with-www=none"
+	fi
+
+	econf \
+		$(use_enable static-libs static) \
+		$(use_enable unicode nfc-check) \
+		$(use_enable debug) \
+		$(use_with json yajl) \
+		--with-html-dir="${EPREFIX}"/usr/share/doc/${PF}/html \
+		${myconf}
+}
+
+src_install() {
+	default
+	dohtml {NEWS,README,RELEASE,UPGRADING}.html
+	find "${ED}" -name '*.la' -exec rm -f {} +
+}