Version bump wrt bug #490758. Automagic dependency on media-sound/pulseaudio fixed by upstream, bug #433627.

(Portage version: 2.2.7/cvs/Linux x86_64, signed Manifest commit with key F3CFD2BD)

3 files changed, 157 insertions, 17 deletions

diff --git a/media-libs/phonon-vlc/ChangeLog b/media-libs/phonon-vlc/ChangeLog
index b46fe164c4f5..f931eaedcf84 100644
--- a/media-libs/phonon-vlc/ChangeLog
+++ b/media-libs/phonon-vlc/ChangeLog
@@ -1,6 +1,13 @@
 # ChangeLog for media-libs/phonon-vlc
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-libs/phonon-vlc/ChangeLog,v 1.40 2013/04/09 17:52:38 kensington Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-libs/phonon-vlc/ChangeLog,v 1.41 2013/11/11 21:09:31 johu Exp $
+
+*phonon-vlc-0.7.0 (11 Nov 2013)
+
+  11 Nov 2013; Johannes Huber <johu@gentoo.org> +phonon-vlc-0.7.0.ebuild,
+  phonon-vlc-9999.ebuild:
+  Version bump wrt bug #490758. Automagic dependency on media-sound/pulseaudio
+  fixed by upstream, bug #433627.
 
   09 Apr 2013; Michael Palimaka <kensington@gentoo.org>
   -files/phonon-vlc-0.6.0-desktop.patch, -phonon-vlc-0.6.0-r1.ebuild,
diff --git a/media-libs/phonon-vlc/phonon-vlc-0.7.0.ebuild b/media-libs/phonon-vlc/phonon-vlc-0.7.0.ebuild
new file mode 100644
index 000000000000..f2bde7f29d49
--- /dev/null
+++ b/media-libs/phonon-vlc/phonon-vlc-0.7.0.ebuild
@@ -0,0 +1,95 @@
+# Copyright 1999-2013 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-libs/phonon-vlc/phonon-vlc-0.7.0.ebuild,v 1.1 2013/11/11 21:09:31 johu Exp $
+
+EAPI=5
+
+MY_PN="phonon-backend-vlc"
+MY_P="${MY_PN}-${PV}"
+EGIT_REPO_URI=( "git://anongit.kde.org/${PN}" )
+[[ ${PV} == 9999 ]] && git_eclass=git-r3
+inherit cmake-utils multibuild ${git_eclass}
+unset git_eclass
+
+DESCRIPTION="Phonon VLC backend"
+HOMEPAGE="https://projects.kde.org/projects/kdesupport/phonon/phonon-vlc"
+[[ ${PV} == 9999 ]] || SRC_URI="mirror://kde/stable/phonon/${MY_PN}/${PV}/src/${MY_P}.tar.xz"
+
+LICENSE="LGPL-2.1"
+
+# Don't move KEYWORDS on the previous line or ekeyword won't work # 399061
+[[ ${PV} == 9999 ]] || \
+KEYWORDS="~amd64 ~arm ~ppc ~ppc64 ~x86 ~amd64-fbsd"
+
+SLOT="0"
+IUSE="debug +qt4 qt5"
+REQUIRED_USE="|| ( qt4 qt5 )"
+
+RDEPEND="
+	>=media-libs/phonon-4.7.0[qt4=,qt5=]
+	>=media-video/vlc-2.0.1[dbus,ogg,vorbis]
+	qt4? (
+		dev-qt/qtcore:4
+		dev-qt/qtdbus:4
+		dev-qt/qtgui:4
+	)
+	qt5? (
+		dev-qt/qtcore:5
+		dev-qt/qtdbus:5
+		dev-qt/qtgui:5
+	)
+"
+DEPEND="${RDEPEND}
+	app-arch/xz-utils
+	qt4? ( >=dev-util/automoc-0.9.87 )
+	virtual/pkgconfig
+"
+
+[[ ${PV} == 9999 ]] || S=${WORKDIR}/${MY_P}
+
+DOCS=( AUTHORS )
+
+pkg_setup() {
+	MULTIBUILD_VARIANTS=()
+	if use qt4; then
+		MULTIBUILD_VARIANTS+=(qt4)
+	fi
+	if use qt5; then
+		MULTIBUILD_VARIANTS+=(qt5)
+	fi
+}
+
+src_configure() {
+	myconfigure() {
+		local mycmakeargs=()
+		if [[ ${MULTIBUILD_VARIANT} = qt4 ]]; then
+			mycmakeargs+=(-DPHONON_BUILD_PHONON4QT5=OFF)
+		fi
+		if [[ ${MULTIBUILD_VARIANT} = qt5 ]]; then
+			mycmakeargs+=(-DPHONON_BUILD_PHONON4QT5=ON)
+		fi
+		cmake-utils_src_configure
+	}
+
+	multibuild_foreach_variant myconfigure
+}
+
+src_compile() {
+	multibuild_foreach_variant cmake-utils_src_compile
+}
+
+src_install() {
+	multibuild_foreach_variant cmake-utils_src_install
+}
+
+src_test() {
+	multibuild_foreach_variant cmake-utils_src_test
+}
+
+pkg_postinst() {
+	elog "For more verbose debug information, export the following variables:"
+	elog "PHONON_DEBUG=1"
+	elog ""
+	elog "To make KDE detect the new backend without reboot, run:"
+	elog "kbuildsycoca4 --noincremental"
+}
diff --git a/media-libs/phonon-vlc/phonon-vlc-9999.ebuild b/media-libs/phonon-vlc/phonon-vlc-9999.ebuild
index c06adb33d068..001133f25250 100644
--- a/media-libs/phonon-vlc/phonon-vlc-9999.ebuild
+++ b/media-libs/phonon-vlc/phonon-vlc-9999.ebuild
@@ -1,19 +1,19 @@
 # Copyright 1999-2013 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/media-libs/phonon-vlc/phonon-vlc-9999.ebuild,v 1.12 2013/03/17 16:48:38 kensington Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-libs/phonon-vlc/phonon-vlc-9999.ebuild,v 1.13 2013/11/11 21:09:31 johu Exp $
 
 EAPI=5
 
 MY_PN="phonon-backend-vlc"
 MY_P="${MY_PN}-${PV}"
-EGIT_REPO_URI="git://anongit.kde.org/${PN}"
-[[ ${PV} == 9999 ]] && git_eclass=git-2
-inherit cmake-utils ${git_eclass}
+EGIT_REPO_URI=( "git://anongit.kde.org/${PN}" )
+[[ ${PV} == 9999 ]] && git_eclass=git-r3
+inherit cmake-utils multibuild ${git_eclass}
 unset git_eclass
 
 DESCRIPTION="Phonon VLC backend"
 HOMEPAGE="https://projects.kde.org/projects/kdesupport/phonon/phonon-vlc"
-[[ ${PV} == 9999 ]] || SRC_URI="mirror://kde/stable/phonon/${MY_PN}/${PV}/${MY_P}.tar.xz"
+[[ ${PV} == 9999 ]] || SRC_URI="mirror://kde/stable/phonon/${MY_PN}/${PV}/src/${MY_P}.tar.xz"
 
 LICENSE="LGPL-2.1"
 
@@ -22,30 +22,68 @@ LICENSE="LGPL-2.1"
 KEYWORDS="~amd64 ~arm ~ppc ~ppc64 ~x86 ~amd64-fbsd"
 
 SLOT="0"
-IUSE="debug"
+IUSE="debug +qt4 qt5"
+REQUIRED_USE="|| ( qt4 qt5 )"
 
 RDEPEND="
-	>=media-libs/phonon-4.6.0
+	>=media-libs/phonon-4.7.0[qt4=,qt5=]
 	>=media-video/vlc-2.0.1[dbus,ogg,vorbis]
-	>=dev-qt/qtcore-4.6.0:4
-	>=dev-qt/qtdbus-4.6.0:4
-	>=dev-qt/qtgui-4.6.0:4
+	qt4? (
+		dev-qt/qtcore:4
+		dev-qt/qtdbus:4
+		dev-qt/qtgui:4
+	)
+	qt5? (
+		dev-qt/qtcore:5
+		dev-qt/qtdbus:5
+		dev-qt/qtgui:5
+	)
 "
 DEPEND="${RDEPEND}
 	app-arch/xz-utils
-	>=dev-util/automoc-0.9.87
+	qt4? ( >=dev-util/automoc-0.9.87 )
 	virtual/pkgconfig
 "
 
-S=${WORKDIR}/${MY_P}
+[[ ${PV} == 9999 ]] || S=${WORKDIR}/${MY_P}
 
 DOCS=( AUTHORS )
 
+pkg_setup() {
+	MULTIBUILD_VARIANTS=()
+	if use qt4; then
+		MULTIBUILD_VARIANTS+=(qt4)
+	fi
+	if use qt5; then
+		MULTIBUILD_VARIANTS+=(qt5)
+	fi
+}
+
 src_configure() {
-	local mycmakeargs=(
-		-DPhonon_DIR=/usr/$(get_libdir)/cmake/phonon/
-	)
-	cmake-utils_src_configure
+	myconfigure() {
+		local mycmakeargs=()
+		if [[ ${MULTIBUILD_VARIANT} = qt4 ]]; then
+			mycmakeargs+=(-DPHONON_BUILD_PHONON4QT5=OFF)
+		fi
+		if [[ ${MULTIBUILD_VARIANT} = qt5 ]]; then
+			mycmakeargs+=(-DPHONON_BUILD_PHONON4QT5=ON)
+		fi
+		cmake-utils_src_configure
+	}
+
+	multibuild_foreach_variant myconfigure
+}
+
+src_compile() {
+	multibuild_foreach_variant cmake-utils_src_compile
+}
+
+src_install() {
+	multibuild_foreach_variant cmake-utils_src_install
+}
+
+src_test() {
+	multibuild_foreach_variant cmake-utils_src_test
 }
 
 pkg_postinst() {