media-libs/gegl: Add live ebuild

(Portage version: 2.1.10.65/cvs/Linux x86_64)

2 files changed, 122 insertions, 1 deletions

diff --git a/media-libs/gegl/ChangeLog b/media-libs/gegl/ChangeLog
index c71479e5e1fd..f680b0a58c82 100644
--- a/media-libs/gegl/ChangeLog
+++ b/media-libs/gegl/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for media-libs/gegl
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-libs/gegl/ChangeLog,v 1.72 2012/07/13 11:25:35 hanno Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-libs/gegl/ChangeLog,v 1.73 2012/09/06 22:20:41 sping Exp $
+
+*gegl-9999 (06 Sep 2012)
+
+  06 Sep 2012; Sebastian Pipping <sping@gentoo.org> +gegl-9999.ebuild:
+  Added live ebuild from co-op with Sam Tygier
 
   13 Jul 2012; Hanno Boeck <hanno@gentoo.org> gegl-0.2.0.ebuild,
   +files/gegl-0.2.0-ffmpeg-0.11.diff:
diff --git a/media-libs/gegl/gegl-9999.ebuild b/media-libs/gegl/gegl-9999.ebuild
new file mode 100644
index 000000000000..dd2ad6b027b4
--- /dev/null
+++ b/media-libs/gegl/gegl-9999.ebuild
@@ -0,0 +1,116 @@
+# Copyright 1999-2012 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-libs/gegl/gegl-9999.ebuild,v 1.1 2012/09/06 22:20:41 sping Exp $
+
+EAPI=4
+
+inherit gnome2-utils eutils autotools git-2
+
+DESCRIPTION="A graph based image processing framework"
+HOMEPAGE="http://www.gegl.org/"
+EGIT_REPO_URI="git://git.gnome.org/${PN}"
+
+LICENSE="|| ( GPL-3 LGPL-3 )"
+SLOT="0"
+KEYWORDS=""
+
+IUSE="cairo debug exif ffmpeg graphviz introspection jpeg jpeg2k lensfun lua mmx openexr png raw sdl sse svg umfpack v4l vala"
+
+VALASLOT="0.14"
+
+RDEPEND=">=media-libs/babl-0.1.10[introspection?]
+	>=dev-libs/glib-2.28:2
+	>=x11-libs/gdk-pixbuf-2.18:2
+	x11-libs/pango
+	sys-libs/zlib
+	cairo? ( x11-libs/cairo )
+	exif? ( media-gfx/exiv2 )
+	ffmpeg? ( virtual/ffmpeg )
+	graphviz? ( media-gfx/graphviz )
+	jpeg? ( virtual/jpeg )
+	jpeg2k? ( >=media-libs/jasper-1.900.1 )
+	lua? ( >=dev-lang/lua-5.1 )
+	openexr? ( media-libs/openexr )
+	png? ( media-libs/libpng )
+	raw? ( >=media-libs/libopenraw-0.0.5 )
+	sdl? ( media-libs/libsdl )
+	svg? ( >=gnome-base/librsvg-2.14:2 )
+	umfpack? ( sci-libs/umfpack )
+	v4l? ( media-libs/libv4l )
+	dev-lang/perl
+	introspection? ( >=dev-libs/gobject-introspection-0.10
+			>=dev-python/pygobject-2.26:2 )
+	lensfun? ( >=media-libs/lensfun-0.2.5 )"
+DEPEND="${RDEPEND}
+	>=dev-util/intltool-0.40.1
+	virtual/pkgconfig
+	>=sys-devel/libtool-2.2
+	vala? ( dev-lang/vala:${VALASLOT}[vapigen] )"
+
+# tests fail in various ways:
+#   see bug #362215
+RESTRICT="test"
+
+DOCS=( ChangeLog NEWS )
+
+src_prepare() {
+	epatch "${FILESDIR}/${PN}-0.2.0-ffmpeg-0.11.diff"
+	# fix OSX loadable module filename extension
+	sed -i -e 's/\.dylib/.bundle/' configure.ac || die
+	# don't require Apple's OpenCL on versions of OSX that don't have it
+	if [[ ${CHOST} == *-darwin* && ${CHOST#*-darwin} -le 9 ]] ; then
+		sed -i -e 's/#ifdef __APPLE__/#if 0/' gegl/opencl/* || die
+	fi
+	eautoreconf
+}
+
+src_configure() {
+	# never enable altering of CFLAGS via profile option
+	# libspiro: not in portage main tree
+	# disable documentation as the generating is bit automagic
+	#    if anyone wants to work on it just create bug with patch
+	VAPIGEN="$(type -p vapigen-${VALASLOT})" \
+	econf \
+		--disable-profile \
+		--without-libspiro \
+		--disable-docs --disable-workshop \
+		--with-pango --with-gdk-pixbuf \
+		$(use_enable mmx) \
+		$(use_enable sse) \
+		$(use_enable debug) \
+		$(use_with cairo) \
+		$(use_with cairo pangocairo) \
+		$(use_with exif exiv2) \
+		$(use_with ffmpeg libavformat) \
+		$(use_with graphviz) \
+		$(use_with jpeg libjpeg) \
+		$(use_with jpeg2k jasper) \
+		$(use_with lua) \
+		$(use_with openexr) \
+		$(use_with png libpng) \
+		$(use_with raw libopenraw) \
+		$(use_with sdl) \
+		$(use_with svg librsvg) \
+		$(use_with umfpack) \
+		$(use_with v4l libv4l) \
+		$(use_enable introspection) \
+		$(use_with lensfun) \
+		$(use_with vala)
+}
+
+src_test() {
+	gnome2_environment_reset  # sandbox issues
+	default
+}
+
+src_compile() {
+	gnome2_environment_reset  # sandbox issues (bug #396687)
+	default
+
+	emake ./ChangeLog  # "./" prevents "Circular ChangeLog <- ChangeLog dependency dropped."
+}
+
+src_install() {
+	default
+	find "${ED}" -name '*.la' -delete
+}