Version bump.

(Portage version: 2.2.10/cvs/Linux x86_64, signed Manifest commit with key 4AB3E85B4F064CA3)

2 files changed, 79 insertions, 1 deletions

diff --git a/media-gfx/gmic/ChangeLog b/media-gfx/gmic/ChangeLog
index cd3c2a509db4..41fb34a1ca00 100644
--- a/media-gfx/gmic/ChangeLog
+++ b/media-gfx/gmic/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for media-gfx/gmic
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-gfx/gmic/ChangeLog,v 1.49 2014/06/06 06:16:39 radhermit Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-gfx/gmic/ChangeLog,v 1.50 2014/06/16 06:37:59 radhermit Exp $
+
+*gmic-1.5.9.2 (16 Jun 2014)
+
+  16 Jun 2014; Tim Harder <radhermit@gentoo.org> +gmic-1.5.9.2.ebuild:
+  Version bump.
 
 *gmic-1.5.9.1 (06 Jun 2014)
 
diff --git a/media-gfx/gmic/gmic-1.5.9.2.ebuild b/media-gfx/gmic/gmic-1.5.9.2.ebuild
new file mode 100644
index 000000000000..9cbeb4c6aa26
--- /dev/null
+++ b/media-gfx/gmic/gmic-1.5.9.2.ebuild
@@ -0,0 +1,73 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-gfx/gmic/gmic-1.5.9.2.ebuild,v 1.1 2014/06/16 06:37:59 radhermit Exp $
+
+EAPI=5
+
+inherit eutils toolchain-funcs bash-completion-r1 flag-o-matic
+
+DESCRIPTION="GREYC's Magic Image Converter"
+HOMEPAGE="http://gmic.sourceforge.net/"
+SRC_URI="mirror://sourceforge/${PN}/${PN}_${PV}.tar.gz"
+
+LICENSE="CeCILL-2 FDL-1.3"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="ffmpeg fftw graphicsmagick jpeg opencv openexr png tiff X zlib"
+
+RDEPEND="
+	ffmpeg? ( virtual/ffmpeg )
+	fftw? ( sci-libs/fftw:3.0[threads] )
+	graphicsmagick? ( media-gfx/graphicsmagick )
+	jpeg? ( virtual/jpeg )
+	opencv? ( >=media-libs/opencv-2.3.1a-r1 )
+	openexr? (
+		media-libs/ilmbase
+		media-libs/openexr
+	)
+	png? ( media-libs/libpng )
+	tiff? ( media-libs/tiff )
+	X? (
+		x11-libs/libX11
+		x11-libs/libXext
+	)
+	zlib? ( sys-libs/zlib )"
+DEPEND="${RDEPEND}"
+
+S=${WORKDIR}/${P}/src
+
+src_prepare() {
+	epatch "${FILESDIR}"/${PN}-1.5.9.1-makefile.patch
+	epatch "${FILESDIR}"/${PN}-1.5.8.2-ffmpeg.patch
+
+	for i in ffmpeg fftw jpeg opencv png tiff zlib ; do
+		use $i || { sed -i -r "s/^(${i}_(C|LD)FLAGS =).*/\1/I" Makefile || die ; }
+	done
+
+	use graphicsmagick || { sed -i -r "s/^(MAGICK_(C|LD)FLAGS =).*/\1/" Makefile || die ; }
+	use openexr || { sed -i -r "s/^(EXR_(C|LD)FLAGS =).*/\1/" Makefile || die ; }
+
+	if ! use X ; then
+		sed -i -r "s/^((X11|XSHM)_(C|LD)FLAGS =).*/\1/" Makefile || die
+
+		# disable display capabilities when X support is disabled
+		append-cppflags -Dcimg_display=0
+	fi
+}
+
+src_compile() {
+	emake AR="$(tc-getAR)" CC="$(tc-getCXX)" CFLAGS="${CXXFLAGS}" OPT_CFLAGS= DEBUG_CFLAGS= linux lib
+}
+
+src_install() {
+	dobin gmic
+	newlib.so libgmic.so libgmic.so.1
+
+	insinto /usr/include
+	doins gmic.h
+
+	doman ../man/gmic.1.gz
+	dodoc ../README
+
+	newbashcomp ../resources/gmic_bashcompletion.sh ${PN}
+}