Bump to 3.5.5 (pre-release). Sorry for being late on this, mips disallow repoman commits.

(Portage version: 2.1.2_pre2-r2)

3 files changed, 84 insertions, 1 deletions

diff --git a/kde-base/kdegraphics/ChangeLog b/kde-base/kdegraphics/ChangeLog
index 80771a08d242..e71974f6b157 100644
--- a/kde-base/kdegraphics/ChangeLog
+++ b/kde-base/kdegraphics/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for kde-base/kdegraphics
 # Copyright 2002-2006 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/kde-base/kdegraphics/ChangeLog,v 1.267 2006/09/17 22:53:12 carlo Exp $
+# $Header: /var/cvsroot/gentoo-x86/kde-base/kdegraphics/ChangeLog,v 1.268 2006/10/04 14:19:36 flameeyes Exp $
+
+*kdegraphics-3.5.5 (03 Oct 2006)
+
+  03 Oct 2006; Diego Pettenò <flameeyes@gentoo.org>
+  +kdegraphics-3.5.5.ebuild:
+  Bump to 3.5.5 (pre-release)
 
   17 Sep 2006; Carsten Lohrke <carlo@gentoo.org>
   -kdegraphics-3.4.3-r4.ebuild:
diff --git a/kde-base/kdegraphics/files/digest-kdegraphics-3.5.5 b/kde-base/kdegraphics/files/digest-kdegraphics-3.5.5
new file mode 100644
index 000000000000..0298d4d6afa0
--- /dev/null
+++ b/kde-base/kdegraphics/files/digest-kdegraphics-3.5.5
@@ -0,0 +1,6 @@
+MD5 cdbe15afc01c5da7af9557e803bbb7e6 kdegraphics-3.5.5.tar.bz2 7334117
+RMD160 c6febdf8ebd67110be3f27ada4c00e148403217f kdegraphics-3.5.5.tar.bz2 7334117
+SHA256 b6706d37568686e1ca4b4bb2cf1f79c027b94a512f6fe1156b7c7b7f79336f16 kdegraphics-3.5.5.tar.bz2 7334117
+MD5 6bffd8365786b79b10db269588a8a281 kpdf-3.5.3-poppler-bis.patch.bz2 6283
+RMD160 b4d4bffd22a67cfdb86cf9c4614d31e56ed01757 kpdf-3.5.3-poppler-bis.patch.bz2 6283
+SHA256 08ea2cda6088ec33da22f0fbb2046de08bc6e26167b8373bbc22f891ed021a02 kpdf-3.5.3-poppler-bis.patch.bz2 6283
diff --git a/kde-base/kdegraphics/kdegraphics-3.5.5.ebuild b/kde-base/kdegraphics/kdegraphics-3.5.5.ebuild
new file mode 100644
index 000000000000..9282c8f908fb
--- /dev/null
+++ b/kde-base/kdegraphics/kdegraphics-3.5.5.ebuild
@@ -0,0 +1,71 @@
+# Copyright 1999-2006 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/kde-base/kdegraphics/kdegraphics-3.5.5.ebuild,v 1.1 2006/10/04 14:19:36 flameeyes Exp $
+
+inherit kde-dist eutils
+
+DESCRIPTION="KDE graphics-related apps"
+
+KEYWORDS="~alpha ~amd64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sparc ~x86"
+IUSE="gphoto2 imlib openexr opengl pdf povray scanner tetex"
+
+DEPEND="~kde-base/kdebase-${PV}
+	>=media-libs/freetype-2
+	media-libs/fontconfig
+	gphoto2? ( media-libs/libgphoto2 )
+	scanner? ( media-gfx/sane-backends )
+	media-libs/libart_lgpl
+	media-libs/lcms
+	dev-libs/fribidi
+	imlib? ( media-libs/imlib )
+	virtual/ghostscript
+	media-libs/tiff
+	openexr? ( >=media-libs/openexr-1.2 )
+	povray? ( media-gfx/povray
+		  virtual/opengl )
+	pdf? ( >=app-text/poppler-0.5.1
+		>=app-text/poppler-bindings-0.5.1 )"
+
+RDEPEND="${DEPEND}
+	tetex? (
+	|| ( >=app-text/tetex-2
+		 app-text/ptex
+		 app-text/cstetex
+		 app-text/dvipdfm ) )"
+
+DEPEND="${DEPEND}
+	dev-util/pkgconfig"
+
+SRC_URI="${SRC_URI}
+	mirror://gentoo/kpdf-3.5.3-poppler-bis.patch.bz2"
+
+PATCHES="${DISTDIR}/kpdf-3.5.3-poppler-bis.patch.bz2"
+
+pkg_setup() {
+	kde_pkg_setup
+	for ghostscript in app-text/ghostscript-{gnu,esp,afpl}; do
+		if has_version ${ghostscript} && ! built_with_use ${ghostscript} X; then
+			eerror "This package requires ${ghostscript} compiled with X11 support."
+			eerror "Please reemerge ${ghostscript} with USE=\"X\"."
+			die "Please reemerge ${ghostscript} with USE=\"X\"."
+		fi
+	done
+	if use pdf && ! built_with_use app-text/poppler-bindings qt3; then
+		eerror "This package requires app-text/poppler-bindings compiled with Qt 3.x support."
+		eerror "Please reemerge app-text/poppler-bindings with USE=\"qt3\"."
+		die "Please reemerge app-text/poppler-bindings with USE=\"qt3\"."
+	fi
+}
+
+src_compile() {
+	local myconf="$(use_with openexr) $(use_with pdf poppler)
+				  $(use_with gphoto2 kamera)"
+
+	use imlib || export DO_NOT_COMPILE="${DO_NOT_COMPILE} kuickshow"
+	use scanner || export DO_NOT_COMPILE="${DO_NOT_COMPILE} kooka libkscan"
+	use povray || export DO_NOT_COMPILE="${DO_NOT_COMPILE} kpovmodeler"
+	use pdf || export DO_NOT_COMPILE="${DO_NOT_COMPILE} kpdf"
+
+	rm -f ${S}/configure # ask rebuilding
+	kde_src_compile
+}