Version bump to a 5.2 pre-release, which is needed for some gnome-3.6 applications. Update description. Switch to global introspection flag.

(Portage version: 2.2.0_alpha148/cvs/Linux x86_64, signed Manifest commit with key CF0ADD61)

5 files changed, 155 insertions, 7 deletions

diff --git a/gnome-extra/libgda/ChangeLog b/gnome-extra/libgda/ChangeLog
index edb0f8bfbf90..27dcc164f75e 100644
--- a/gnome-extra/libgda/ChangeLog
+++ b/gnome-extra/libgda/ChangeLog
@@ -1,6 +1,14 @@
 # ChangeLog for gnome-extra/libgda
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/gnome-extra/libgda/ChangeLog,v 1.213 2012/11/05 08:27:47 tetromino Exp $
+# $Header: /var/cvsroot/gentoo-x86/gnome-extra/libgda/ChangeLog,v 1.214 2012/12/17 08:01:40 tetromino Exp $
+
+*libgda-5.1.1-r1 (17 Dec 2012)
+
+  17 Dec 2012; Alexandre Rostovtsev <tetromino@gentoo.org>
+  libgda-4.2.13.ebuild, libgda-5.0.3-r1.ebuild, +libgda-5.1.1-r1.ebuild,
+  metadata.xml:
+  Version bump to a 5.2 pre-release, which is needed for some gnome-3.6
+  applications. Update description. Switch to global introspection flag.
 
   05 Nov 2012; Alexandre Rostovtsev <tetromino@gentoo.org>
   -files/libgda-4.2.0-missing-include-in-keyword_hash-generator.patch,
diff --git a/gnome-extra/libgda/libgda-4.2.13.ebuild b/gnome-extra/libgda/libgda-4.2.13.ebuild
index f350c65c299a..08a696f4ff47 100644
--- a/gnome-extra/libgda/libgda-4.2.13.ebuild
+++ b/gnome-extra/libgda/libgda-4.2.13.ebuild
@@ -1,6 +1,6 @@
 # Copyright 1999-2012 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/gnome-extra/libgda/libgda-4.2.13.ebuild,v 1.9 2012/11/05 08:27:47 tetromino Exp $
+# $Header: /var/cvsroot/gentoo-x86/gnome-extra/libgda/libgda-4.2.13.ebuild,v 1.10 2012/12/17 08:01:40 tetromino Exp $
 
 EAPI="4"
 GCONF_DEBUG="yes"
@@ -8,7 +8,7 @@ GNOME2_LA_PUNT="yes"
 
 inherit db-use flag-o-matic gnome2 java-pkg-opt-2
 
-DESCRIPTION="Gnome Database Access Library"
+DESCRIPTION="GNOME database access library"
 HOMEPAGE="http://www.gnome-db.org/"
 LICENSE="GPL-2+ LGPL-2+"
 
diff --git a/gnome-extra/libgda/libgda-5.0.3-r1.ebuild b/gnome-extra/libgda/libgda-5.0.3-r1.ebuild
index 5253009a8b7a..e1074b4fb4e0 100644
--- a/gnome-extra/libgda/libgda-5.0.3-r1.ebuild
+++ b/gnome-extra/libgda/libgda-5.0.3-r1.ebuild
@@ -1,6 +1,6 @@
 # Copyright 1999-2012 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/gnome-extra/libgda/libgda-5.0.3-r1.ebuild,v 1.9 2012/11/05 08:27:47 tetromino Exp $
+# $Header: /var/cvsroot/gentoo-x86/gnome-extra/libgda/libgda-5.0.3-r1.ebuild,v 1.10 2012/12/17 08:01:41 tetromino Exp $
 
 EAPI="4"
 GNOME2_LA_PUNT="yes"
@@ -9,7 +9,7 @@ PYTHON_DEPEND="2"
 
 inherit autotools db-use eutils flag-o-matic gnome2 java-pkg-opt-2 python
 
-DESCRIPTION="Gnome Database Access Library"
+DESCRIPTION="GNOME database access library"
 HOMEPAGE="http://www.gnome-db.org/"
 LICENSE="GPL-2+ LGPL-2+"
 
diff --git a/gnome-extra/libgda/libgda-5.1.1-r1.ebuild b/gnome-extra/libgda/libgda-5.1.1-r1.ebuild
new file mode 100644
index 000000000000..7c9f2b05451b
--- /dev/null
+++ b/gnome-extra/libgda/libgda-5.1.1-r1.ebuild
@@ -0,0 +1,141 @@
+# Copyright 1999-2012 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/gnome-extra/libgda/libgda-5.1.1-r1.ebuild,v 1.1 2012/12/17 08:01:41 tetromino Exp $
+
+EAPI="5"
+GNOME2_LA_PUNT="yes"
+GCONF_DEBUG="yes"
+PYTHON_COMPAT=( python{2_6,2_7} )
+#VALA_MIN_API_VERSION="0.16"
+#VALA_MAX_API_VERSION="0.16" # configure explicitly checks for 0.16
+#VALA_USE_DEPEND="vapigen"
+
+inherit autotools db-use eutils flag-o-matic gnome2 java-pkg-opt-2 python-single-r1 # vala
+
+DESCRIPTION="GNOME database access library"
+HOMEPAGE="http://www.gnome-db.org/"
+LICENSE="GPL-2+ LGPL-2+"
+
+IUSE="berkdb bindist canvas firebird gnome-keyring gtk graphviz http +introspection json ldap mdb mysql oci8 postgres reports sourceview ssl" # vala
+REQUIRED_USE="canvas? ( gtk )
+	firebird? ( !bindist )
+	graphviz? ( gtk )
+	sourceview? ( gtk )"
+# firebird license is not GPL compatible
+SLOT="5/4" # subslot = libgda-5.0 soname version
+KEYWORDS="~alpha ~amd64 ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd"
+
+RDEPEND="
+	app-text/iso-codes
+	>=dev-libs/glib-2.32:2
+	>=dev-libs/libxml2-2
+	dev-libs/libxslt
+	sys-libs/readline:=
+	sys-libs/ncurses:=
+	berkdb?   ( sys-libs/db )
+	!bindist? ( firebird? ( dev-db/firebird ) )
+	gtk? (
+		>=x11-libs/gtk+-3.0.0:3
+		canvas? ( x11-libs/goocanvas:2.0= )
+		sourceview? ( x11-libs/gtksourceview:3.0 )
+		graphviz? ( media-gfx/graphviz )
+	)
+	gnome-keyring? ( app-crypt/libsecret )
+	http? ( >=net-libs/libsoup-2.24:2.4 )
+	introspection? ( >=dev-libs/gobject-introspection-1.30 )
+	json?     ( dev-libs/json-glib )
+	ldap?     ( net-nds/openldap:= )
+	mdb?      ( >app-office/mdbtools-0.5:= )
+	mysql?    ( virtual/mysql:= )
+	postgres? ( dev-db/postgresql-base:= )
+	reports? (
+		${PYTHON_DEPS}
+		dev-java/fop
+		dev-python/reportlab )
+	ssl?      ( dev-libs/openssl:= )
+	>=dev-db/sqlite-3.6.22:3=
+"
+DEPEND="${RDEPEND}
+	>=app-text/gnome-doc-utils-0.9
+	dev-util/gtk-doc-am
+	>=dev-util/intltool-0.40.6
+	virtual/pkgconfig
+	java? ( virtual/jdk:1.6 )"
+#	vala? ( $(vala_depend) )
+
+# FIXME: lots of tests failing. Check if they still fail in 5.1.2
+RESTRICT="test"
+
+pkg_setup() {
+	java-pkg-opt-2_pkg_setup
+	use reports && python-single-r1_pkg_setup
+}
+
+src_prepare() {
+	G2CONF="${G2CONF}
+		--disable-scrollkeeper
+		--disable-static
+		--enable-system-sqlite
+		$(use_with berkdb bdb /usr)
+		$(use_with canvas goocanvas)
+		$(use_with firebird firebird /usr)
+		$(use_with gnome-keyring)
+		$(use_with graphviz)
+		$(use_with gtk ui)
+		$(use_with http libsoup)
+		$(use_enable introspection)
+		$(use_with java java $JAVA_HOME)
+		$(use_enable json)
+		$(use_with ldap)
+		$(use_with mdb mdb /usr)
+		$(use_with mysql mysql /usr)
+		$(use_with postgres postgres /usr)
+		$(use_enable ssl crypto)
+		$(use_with sourceview gtksourceview)
+		--disable-default-binary
+		--disable-vala"
+	# vala bindings fail to build
+
+	use berkdb && append-cppflags "-I$(db_includedir)"
+	use oci8 || G2CONF="${G2CONF} --without-oracle"
+
+	use reports ||
+		sed -e '/SUBDIRS =/ s/trml2html//' \
+			-e '/SUBDIRS =/ s/trml2pdf//' \
+			-i libgda-report/RML/Makefile.{am,in} || die
+
+	# Prevent file collisions with libgda:4
+	epatch "${FILESDIR}/${PN}-4.99.1-gda-browser-help-collision.patch"
+	epatch "${FILESDIR}/${PN}-4.99.1-gda-browser-doc-collision.patch"
+	epatch "${FILESDIR}/${PN}-4.99.1-control-center-icon-collision.patch"
+	# Move files with mv (since epatch can't handle rename diffs) and
+	# update pre-generated gtk-doc files (for non-git versions of libgda)
+	local f
+	for f in tools/browser/doc/gda-browser* ; do
+		mv ${f} ${f/gda-browser/gda-browser-5.0} || die "mv ${f} failed"
+	done
+	for f in tools/browser/doc/html/gda-browser.devhelp* ; do
+		sed -e 's:name="gda-browser":name="gda-browser-5.0":' \
+			-i ${f} || die "sed ${f} failed"
+		mv ${f} ${f/gda-browser/gda-browser-5.0} || die "mv ${f} failed"
+	done
+	for f in control-center/data/*_gda-control-center.png ; do
+		mv ${f} ${f/_gda-control-center.png/_gda-control-center-5.0.png} ||
+			die "mv ${f} failed"
+	done
+
+	eautoreconf
+	gnome2_src_prepare
+	java-pkg-opt-2_src_prepare
+	# use vala && vala_src_prepare
+}
+
+src_install() {
+	gnome2_src_install
+	if use reports; then
+		for t in trml2{html,pdf}; do
+			python_scriptinto /usr/share/libgda-5.0/gda_${t}
+			python_doscript libgda-report/RML/${t}/${t}.py
+		done
+	fi
+}
diff --git a/gnome-extra/libgda/metadata.xml b/gnome-extra/libgda/metadata.xml
index 0dccce1fcd47..a420d4f99c6b 100644
--- a/gnome-extra/libgda/metadata.xml
+++ b/gnome-extra/libgda/metadata.xml
@@ -5,11 +5,10 @@
 <use>
 	<flag name="canvas">Enable support for <pkg>x11-libs/goocanvas</pkg></flag>
 	<flag name="http">Enable embedded <pkg>net-libs/libsoup</pkg> based server</flag>
-	<flag name="introspection">Use <pkg>dev-libs/gobject-introspection</pkg> for
-		introspection</flag>
 	<flag name="json">Enable support for JSON format</flag>
 	<flag name="mdb">Enable support for Microsoft Access database using 
 		<pkg>app-office/mdbtools</pkg></flag>
+	<flag name="reports">Install tools for generating graphical reports</flag>
 	<flag name="sourceview">Enable support for <pkg>x11-libs/gtksourceview</pkg></flag>
 </use>
 </pkgmetadata>