Fix build failure with mozjs17, bug #499980.

(Portage version: 2.2.8-r1/cvs/Linux x86_64, signed Manifest commit with key EFB4464E!)

3 files changed, 297 insertions, 2 deletions

diff --git a/gnome-extra/cinnamon/ChangeLog b/gnome-extra/cinnamon/ChangeLog
index a8e235eaa035..fcd975147cb3 100644
--- a/gnome-extra/cinnamon/ChangeLog
+++ b/gnome-extra/cinnamon/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for gnome-extra/cinnamon
-# Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/gnome-extra/cinnamon/ChangeLog,v 1.31 2013/12/12 07:38:27 jlec Exp $
+# Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/gnome-extra/cinnamon/ChangeLog,v 1.32 2014/02/26 10:52:07 mgorny Exp $
+
+*cinnamon-1.8.8.1-r2 (26 Feb 2014)
+
+  26 Feb 2014; Michał Górny <mgorny@gentoo.org> +cinnamon-1.8.8.1-r2.ebuild,
+  +files/cinnamon-1.8.8.1-mozjs17.patch:
+  Fix build failure with mozjs17, bug #499980.
 
   12 Dec 2013; Justin Lecher <jlec@gentoo.org> cinnamon-1.8.8.1-r1.ebuild,
   metadata.xml:
diff --git a/gnome-extra/cinnamon/cinnamon-1.8.8.1-r2.ebuild b/gnome-extra/cinnamon/cinnamon-1.8.8.1-r2.ebuild
new file mode 100644
index 000000000000..d2b05a64ebb3
--- /dev/null
+++ b/gnome-extra/cinnamon/cinnamon-1.8.8.1-r2.ebuild
@@ -0,0 +1,253 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/gnome-extra/cinnamon/cinnamon-1.8.8.1-r2.ebuild,v 1.1 2014/02/26 10:52:07 mgorny Exp $
+
+EAPI="5"
+GCONF_DEBUG="no"
+GNOME2_LA_PUNT="yes"
+PYTHON_COMPAT=( python{2_6,2_7} )
+PYTHON_REQ_USE="xml"
+
+inherit autotools eutils gnome2 multilib pax-utils python-single-r1
+
+DESCRIPTION="A fork of GNOME Shell with layout similar to GNOME 2"
+HOMEPAGE="http://cinnamon.linuxmint.com/"
+
+MY_PV="${PV/_p/-UP}"
+MY_P="${PN}-${MY_PV}"
+
+SRC_URI="https://github.com/linuxmint/Cinnamon/archive/${MY_PV}.tar.gz -> ${MY_P}.tar.gz
+	http://dev.gentoo.org/~pacho/gnome/cinnamon-1.8/gnome-3.8.patch"
+
+LICENSE="GPL-2+"
+SLOT="0"
+IUSE="+bluetooth +networkmanager"
+KEYWORDS="~amd64 ~x86"
+
+# gnome-desktop-2.91.2 is needed due to header changes, db82a33 in gnome-desktop
+# latest gsettings-desktop-schemas is needed due to commit 602fa1c6
+# latest g-c-c is needed due to https://bugs.gentoo.org/show_bug.cgi?id=360057
+# libXfixes-5.0 needed for pointer barriers
+# gnome-menus-3.2.0.1-r1 needed for new 10-xdg-menu-gnome
+COMMON_DEPEND="
+	>=dev-libs/glib-2.29.10:2
+	>=dev-libs/gjs-1.29.18
+	>=dev-libs/gobject-introspection-0.10.1
+	x11-libs/gdk-pixbuf:2[introspection]
+	>=x11-libs/gtk+-3.0.0:3[introspection]
+	>=media-libs/clutter-1.7.5:1.0[introspection]
+	media-libs/cogl:1.0=[introspection]
+	app-misc/ca-certificates
+	>=dev-libs/json-glib-0.13.2
+	>=gnome-base/gnome-desktop-3.0.0:3=[introspection]
+	>=gnome-base/gsettings-desktop-schemas-2.91.91
+	>=media-libs/gstreamer-0.10.16:0.10
+	>=media-libs/gst-plugins-base-0.10.16:0.10
+	net-libs/libsoup:2.4[introspection]
+	>=sys-auth/polkit-0.100[introspection]
+	>=x11-wm/muffin-1.7.4[introspection]
+
+	dev-libs/dbus-glib
+	dev-libs/libxml2:2
+	x11-libs/pango[introspection]
+	>=dev-libs/libcroco-0.6.2:0.6
+
+	gnome-base/gconf:2[introspection]
+	>=gnome-base/gnome-menus-3.2.0.1-r1:3[introspection]
+	gnome-base/librsvg
+	media-libs/libcanberra
+	media-sound/pulseaudio
+
+	>=x11-libs/startup-notification-0.11
+	x11-libs/libX11
+	>=x11-libs/libXfixes-5.0
+	x11-apps/mesa-progs
+
+	${PYTHON_DEPS}
+
+	bluetooth? ( >=net-wireless/gnome-bluetooth-3.4:=[introspection] )
+	networkmanager? (
+		gnome-base/libgnome-keyring
+		>=net-misc/networkmanager-0.8.999[introspection] )
+"
+# Runtime-only deps are probably incomplete and approximate.
+# Each block:
+# 2. Introspection stuff + dconf needed via imports.gi.*
+# 3. gnome-session is needed for gnome-session-quit
+# 4. Control shell settings
+# 5. accountsservice is needed for GdmUserManager (0.6.14 needed for fast
+#    user switching with gdm-3.1.x)
+# 6. caribou needed for on-screen keyboard
+# 7. xdg-utils needed for xdg-open, used by extension tool
+# 8. gconf-python, imaging, lxml needed for cinnamon-settings
+# 9. gnome-icon-theme-symbolic needed for various icons
+# 10. pygobject needed for menu editor
+# 11. nemo - default file manager, tightly integrated with cinnamon
+# 12. timedated or DateTimeMechanism implementation for cinnamon-settings
+# TODO(lxnay): fix error: libgnome-desktop/gnome-rr-labeler.h: No such file or directory
+# 	=gnome-extra/cinnamon-control-center-1.8*
+RDEPEND="${COMMON_DEPEND}
+	>=gnome-base/dconf-0.4.1
+	>=gnome-base/libgnomekbd-2.91.4[introspection]
+	sys-power/upower[introspection]
+
+	>=gnome-base/gnome-session-3.8
+
+	>=gnome-base/gnome-settings-daemon-2.91
+
+	>=sys-apps/accountsservice-0.6.14[introspection]
+
+	>=app-accessibility/caribou-0.3
+
+	x11-misc/xdg-utils
+
+	dev-python/dbus-python[${PYTHON_USEDEP}]
+	dev-python/gconf-python:2
+	virtual/python-imaging
+	dev-python/lxml
+
+	x11-themes/gnome-icon-theme-symbolic
+
+	dev-python/pygobject:3[${PYTHON_USEDEP}]
+
+	gnome-extra/nemo
+	gnome-extra/gnome-screensaver
+
+	|| (
+		app-admin/openrc-settingsd
+		>=sys-apps/systemd-30
+		<gnome-base/gnome-settings-daemon-3.3.5 )
+
+	networkmanager? (
+		net-misc/mobile-broadband-provider-info
+		sys-libs/timezone-data )
+"
+# gnome-extra/gnome-screensaver due screensaver patch, otherwise it uses
+# cinnamon-screensaver
+
+DEPEND="${COMMON_DEPEND}
+	>=sys-devel/gettext-0.17
+	virtual/pkgconfig
+	>=dev-util/intltool-0.40
+	gnome-base/gnome-common
+	!!=dev-lang/spidermonkey-1.8.2*
+"
+# libmozjs.so is picked up from /usr/lib while compiling, so block at build-time
+# https://bugs.gentoo.org/show_bug.cgi?id=360413
+
+S="${WORKDIR}/Cinnamon-${PV}"
+
+pkg_setup() {
+	python-single-r1_pkg_setup
+}
+
+src_prepare() {
+	# Fix GNOME 3.8 support
+	epatch "${DISTDIR}/gnome-3.8.patch"
+	epatch "${FILESDIR}/background.patch"
+	epatch "${FILESDIR}/idle-dim.patch"
+	# https://github.com/linuxmint/Cinnamon/issues/1337
+	epatch "${FILESDIR}/keyboard_applet.patch"
+	epatch "${FILESDIR}/screensaver.patch"
+	epatch "${FILESDIR}/bluetooth_obex_transfer.patch"
+	epatch "${FILESDIR}/remove_GC.patch"
+	epatch "${FILESDIR}/menu_editor.patch"
+
+	# Fix automagic gnome-bluetooth dep, bug #398145
+	epatch "${FILESDIR}/${PN}-1.6.1-automagic-gnome-bluetooth.patch"
+
+	# Optional NetworkManager, bug #488684
+	epatch "${FILESDIR}/${PN}-1.8.8.1-optional-networkmanager.patch"
+
+	# mozjs17 build failure, bug #499980
+	epatch "${FILESDIR}/${P}-mozjs17.patch"
+
+	# Gentoo uses /usr/libexec
+	sed -e "s:/usr/lib/gnome-session/gnome-session-check-accelerated:${EPREFIX}/usr/libexec/gnome-session-check-accelerated:" \
+		-i "files/usr/share/gnome-session/sessions/cinnamon.session" || die "sed 1 failed"
+
+	# Gentoo uses /usr/$(get_libdir), not /usr/lib even for python
+	sed -e "s:/usr/lib/:/usr/$(get_libdir)/:" \
+		-e 's:"/usr/lib":"/usr/'"$(get_libdir)"'":' \
+		-i files/usr/bin/cinnamon-menu-editor \
+		-i files/usr/bin/cinnamon-settings \
+		-i files/usr/lib/cinnamon-menu-editor/cme/config.py \
+		-i files/usr/lib/cinnamon-menu-editor/cme/MainWindow.py \
+		-i files/usr/lib/cinnamon-settings/cinnamon-settings.py || die "sed 2 failed"
+	if [[ "$(get_libdir)" != lib ]]; then
+		mv files/usr/lib "files/usr/$(get_libdir)" || die "mv failed"
+	fi
+
+	if ! use bluetooth; then
+		rm -rv files/usr/share/cinnamon/applets/bluetooth@cinnamon.org || die
+	fi
+
+	if ! use networkmanager; then
+		rm -rv files/usr/share/cinnamon/applets/network@cinnamon.org || die
+	fi
+
+	eautoreconf
+	gnome2_src_prepare
+}
+
+src_configure() {
+	# Don't error out on warnings
+	gnome2_src_configure \
+		--disable-jhbuild-wrapper-script \
+		$(use_with bluetooth) \
+		$(use_enable networkmanager) \
+		--with-ca-certificates="${EPREFIX}/etc/ssl/certs/ca-certificates.crt" \
+		BROWSER_PLUGIN_DIR="${EPREFIX}/usr/$(get_libdir)/nsbrowser/plugins"
+}
+
+src_install() {
+	gnome2_src_install
+	python_optimize "${ED}usr/$(get_libdir)/cinnamon-"{settings,menu-editor}
+	# Fix broken shebangs
+	sed -e "s%#!.*python%#!${PYTHON}%" \
+		-i "${ED}usr/bin/cinnamon-"{launcher,menu-editor,settings} \
+		-i "${ED}usr/$(get_libdir)/cinnamon-settings/cinnamon-settings.py" || die
+
+	domenu\
+		"${FILESDIR}/cinnamon-screensaver.desktop" \
+		"${FILESDIR}/cinnamon2d-screensaver.desktop"
+
+	# Required for gnome-shell on hardened/PaX, bug #398941
+	pax-mark mr "${ED}usr/bin/cinnamon"
+
+	# Doesn't exist on Gentoo, causing this to be a dead symlink
+	rm -f "${ED}etc/xdg/menus/cinnamon-applications-merged" || die
+}
+
+pkg_postinst() {
+	gnome2_pkg_postinst
+
+	if ! has_version '>=media-libs/gst-plugins-good-0.10.23:0.10' || \
+	   ! has_version 'media-plugins/gst-plugins-vp8:0.10'; then
+		ewarn "To make use of Cinnamon's built-in screen recording utility,"
+		ewarn "you need to either install >=media-libs/gst-plugins-good-0.10.23:0.10"
+		ewarn "and media-plugins/gst-plugins-vp8:0.10, or use dconf-editor to change"
+		ewarn "org.cinnamon.recorder/pipeline to what you want to use."
+	fi
+
+	if ! has_version ">=x11-base/xorg-server-1.11"; then
+		ewarn "If you use multiple screens, it is highly recommended that you"
+		ewarn "upgrade to >=x11-base/xorg-server-1.11 to be able to make use of"
+		ewarn "pointer barriers which will make it easier to use hot corners."
+	fi
+
+	if has_version "<x11-drivers/ati-drivers-12"; then
+		ewarn "Cinnamon has been reported to show graphical corruption under"
+		ewarn "x11-drivers/ati-drivers-11.*; you may want to switch to"
+		ewarn "open-source drivers."
+	fi
+
+	if has_version "media-libs/mesa[video_cards_radeon]"; then
+		elog "Cinnamon is unstable under classic-mode r300/r600 mesa drivers."
+		elog "Make sure that gallium architecture for r300 and r600 drivers is"
+		elog "selected using 'eselect mesa'."
+		if ! has_version "media-libs/mesa[gallium]"; then
+			ewarn "You will need to emerge media-libs/mesa with USE=gallium."
+		fi
+	fi
+}
diff --git a/gnome-extra/cinnamon/files/cinnamon-1.8.8.1-mozjs17.patch b/gnome-extra/cinnamon/files/cinnamon-1.8.8.1-mozjs17.patch
new file mode 100644
index 000000000000..cd29462ef784
--- /dev/null
+++ b/gnome-extra/cinnamon/files/cinnamon-1.8.8.1-mozjs17.patch
@@ -0,0 +1,36 @@
+From 914d7da8baea24b1b31e2bcf982d12996f86694a Mon Sep 17 00:00:00 2001
+From: leigh123linux <leigh123linux@fedoraproject.org>
+Date: Tue, 4 Jun 2013 14:02:15 +0200
+Subject: [PATCH] Fix build error so cinnamon compiles with mozjs-17
+
+https://mail.gnome.org/archives/desktop-devel-list/2013-March/msg00135.html
+
+Fixes #2113
+---
+ src/cinnamon-global.c | 7 ++-----
+ 1 file changed, 2 insertions(+), 5 deletions(-)
+
+diff --git a/src/cinnamon-global.c b/src/cinnamon-global.c
+index ab5d5d4..69958d3 100644
+--- a/src/cinnamon-global.c
++++ b/src/cinnamon-global.c
+@@ -1237,14 +1237,11 @@ enum
+                          0,
+                          &target_object))
+     {
+-      char *message;
+-      gjs_log_exception(context,
+-                        &message);
++      gjs_log_exception(context);
+       g_set_error(error,
+                   G_IO_ERROR,
+                   G_IO_ERROR_FAILED,
+-                  "%s", message ? message : "(unknown)");
+-      g_free(message);
++                  "Unable to import %s", target_object_script);
+       goto out_error;
+     }
+ 
+-- 
+1.8.5.5
+