Version bump. Re-add tracker support, bug fixes and translation updates.

(Portage version: 2.2_rc58/cvs/Linux x86_64)

3 files changed, 113 insertions, 5 deletions

diff --git a/gnome-base/nautilus/ChangeLog b/gnome-base/nautilus/ChangeLog
index 03ab9852836f..cc70654b86c1 100644
--- a/gnome-base/nautilus/ChangeLog
+++ b/gnome-base/nautilus/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for gnome-base/nautilus
 # Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/gnome-base/nautilus/ChangeLog,v 1.327 2009/12/03 17:11:09 ranger Exp $
+# $Header: /var/cvsroot/gentoo-x86/gnome-base/nautilus/ChangeLog,v 1.328 2009/12/13 22:32:39 eva Exp $
+
+*nautilus-2.28.2 (13 Dec 2009)
+
+  13 Dec 2009; Gilles Dartiguelongue <eva@gentoo.org>
+  nautilus-2.28.1.ebuild, +nautilus-2.28.2.ebuild:
+  Version bump. Re-add tracker support, bug fixes and translation updates.
 
   03 Dec 2009; Brent Baude <ranger@gentoo.org> nautilus-2.26.4.ebuild:
   Marking nautilus-2.26.4 ppc64 stable for bug 281427
diff --git a/gnome-base/nautilus/nautilus-2.28.1.ebuild b/gnome-base/nautilus/nautilus-2.28.1.ebuild
index 0a40798ef5f3..c6bc2840e900 100644
--- a/gnome-base/nautilus/nautilus-2.28.1.ebuild
+++ b/gnome-base/nautilus/nautilus-2.28.1.ebuild
@@ -1,6 +1,6 @@
 # Copyright 1999-2009 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/gnome-base/nautilus/nautilus-2.28.1.ebuild,v 1.2 2009/11/05 23:40:12 volkmar Exp $
+# $Header: /var/cvsroot/gentoo-x86/gnome-base/nautilus/nautilus-2.28.1.ebuild,v 1.3 2009/12/13 22:32:39 eva Exp $
 
 EAPI="2"
 GCONF_DEBUG="no"
@@ -13,10 +13,9 @@ HOMEPAGE="http://www.gnome.org/projects/nautilus/"
 LICENSE="GPL-2 LGPL-2 FDL-1.1"
 SLOT="0"
 KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~ppc ~ppc64 ~sh ~sparc ~x86 ~x86-fbsd"
-IUSE="beagle doc gnome xmp" # tracker
+IUSE="beagle doc gnome xmp"
 
 # not adding gnome-base/gail because it is in >=gtk+-2.13
-# to be bumped: tracker? ( >=app-misc/tracker-0.7 )
 RDEPEND=">=dev-libs/glib-2.21.3
 	>=gnome-base/gnome-desktop-2.25.5
 	>=x11-libs/pango-1.1.2
@@ -52,8 +51,8 @@ pkg_setup() {
 	G2CONF="${G2CONF}
 		--disable-update-mimedb
 		--disable-packagekit
+		--disable-tracker
 		$(use_enable beagle)
-		$(use_enable tracker)
 		$(use_enable xmp)"
 }
 
diff --git a/gnome-base/nautilus/nautilus-2.28.2.ebuild b/gnome-base/nautilus/nautilus-2.28.2.ebuild
new file mode 100644
index 000000000000..1a8201881e17
--- /dev/null
+++ b/gnome-base/nautilus/nautilus-2.28.2.ebuild
@@ -0,0 +1,103 @@
+# Copyright 1999-2009 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/gnome-base/nautilus/nautilus-2.28.2.ebuild,v 1.1 2009/12/13 22:32:39 eva Exp $
+
+EAPI="2"
+GCONF_DEBUG="no"
+
+inherit eutils gnome2 virtualx
+
+DESCRIPTION="A file manager for the GNOME desktop"
+HOMEPAGE="http://www.gnome.org/projects/nautilus/"
+
+LICENSE="GPL-2 LGPL-2 FDL-1.1"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="beagle doc gnome tracker xmp"
+
+# not adding gnome-base/gail because it is in >=gtk+-2.13
+RDEPEND=">=dev-libs/glib-2.21.3
+	>=gnome-base/gnome-desktop-2.25.5
+	>=x11-libs/pango-1.1.2
+	>=x11-libs/gtk+-2.16.0
+	>=dev-libs/libxml2-2.4.7
+	>=media-libs/libexif-0.5.12
+	>=gnome-base/gconf-2.0
+	>=gnome-base/gvfs-0.1.2
+	dev-libs/libunique
+	dev-libs/dbus-glib
+	x11-libs/libXft
+	x11-libs/libXrender
+	beagle? ( || (
+		dev-libs/libbeagle
+		=app-misc/beagle-0.2* ) )
+	tracker? ( >=app-misc/tracker-0.7 )
+	xmp? ( >=media-libs/exempi-2 )"
+
+DEPEND="${RDEPEND}
+	>=dev-lang/perl-5
+	sys-devel/gettext
+	>=dev-util/pkgconfig-0.9
+	>=dev-util/intltool-0.40.1
+	doc? ( >=dev-util/gtk-doc-1.4 )"
+# For eautoreconf
+#	gnome-base/gnome-common
+#	dev-util/gtk-doc-am"
+
+PDEPEND="gnome? ( >=x11-themes/gnome-icon-theme-1.1.91 )"
+
+DOCS="AUTHORS ChangeLog* HACKING MAINTAINERS NEWS README THANKS TODO"
+
+pkg_setup() {
+	G2CONF="${G2CONF}
+		--disable-update-mimedb
+		--disable-packagekit
+		$(use_enable beagle)
+		$(use_enable tracker)
+		$(use_enable xmp)"
+}
+
+src_prepare() {
+	gnome2_src_prepare
+
+	# FIXME: tarball generated with broken gtk-doc, revisit me.
+	if use doc; then
+		sed "/^TARGET_DIR/i \GTKDOC_REBASE=/usr/bin/gtkdoc-rebase" \
+			-i gtk-doc.make || die "sed 1 failed"
+	else
+		sed "/^TARGET_DIR/i \GTKDOC_REBASE=/bin/true" \
+			-i gtk-doc.make || die "sed 2 failed"
+	fi
+
+	# Fix intltoolize broken file, see upstream #577133
+	sed "s:'\^\$\$lang\$\$':\^\$\$lang\$\$:g" -i po/Makefile.in.in \
+		|| die "sed 3 failed"
+
+	# Remove crazy CFLAGS
+	sed 's:-DG.*DISABLE_DEPRECATED::g' -i configure.in configure \
+		|| die "sed 4 failed"
+
+	# Fix nautilus flipping-out with --no-desktop -- bug 266398
+	epatch "${FILESDIR}/${PN}-2.27.4-change-reg-desktop-file-with-no-desktop.patch"
+}
+
+src_test() {
+	addwrite "/root/.gnome2_private"
+	unset SESSION_MANAGER
+	unset ORBIT_SOCKETDIR
+	unset DBUS_SESSION_BUS_ADDRESS
+	Xemake check || die "Test phase failed"
+}
+
+src_install() {
+	gnome2_src_install
+	find "${D}" -name "*.la" -delete || die "remove of la files failed"
+}
+
+pkg_postinst() {
+	gnome2_pkg_postinst
+
+	elog "nautilus can use gstreamer to preview audio files. Just make sure"
+	elog "to have the necessary plugins available to play the media type you"
+	elog "want to preview"
+}