Bump to latest release away from snapshot

(Portage version: 2.2.8-r2/cvs/Linux x86_64, unsigned Manifest commit)

3 files changed, 112 insertions, 3 deletions

diff --git a/games-board/gnubg/ChangeLog b/games-board/gnubg/ChangeLog
index 577516467514..c448acdf378b 100644
--- a/games-board/gnubg/ChangeLog
+++ b/games-board/gnubg/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for games-board/gnubg
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/games-board/gnubg/ChangeLog,v 1.77 2014/03/18 01:18:13 mr_bones_ Exp $
+# $Header: /var/cvsroot/gentoo-x86/games-board/gnubg/ChangeLog,v 1.78 2014/11/14 09:00:27 mr_bones_ Exp $
+
+*gnubg-1.04.000 (14 Nov 2014)
+
+  14 Nov 2014; Michael Sterrett <mr_bones_@gentoo.org> +gnubg-1.04.000.ebuild,
+  gnubg-20130203.ebuild:
+  Bump to latest release away from snapshot
 
   18 Mar 2014; Michael Sterrett <mr_bones_@gentoo.org>
   -files/gnubg-20121201-build.patch, -gnubg-20121201.ebuild:
diff --git a/games-board/gnubg/gnubg-1.04.000.ebuild b/games-board/gnubg/gnubg-1.04.000.ebuild
new file mode 100644
index 000000000000..88e26624dd3e
--- /dev/null
+++ b/games-board/gnubg/gnubg-1.04.000.ebuild
@@ -0,0 +1,103 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/games-board/gnubg/gnubg-1.04.000.ebuild,v 1.1 2014/11/14 09:00:27 mr_bones_ Exp $
+
+EAPI=5
+PYTHON_COMPAT=( python2_6 python2_7 )
+inherit autotools eutils python-single-r1 gnome2-utils games
+
+DESCRIPTION="GNU BackGammon"
+HOMEPAGE="http://www.gnubg.org/"
+SRC_URI="http://gnubg.org/media/sources/${PN}-release-${PV}-sources.tar.gz"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~ppc ~ppc64 ~x86 ~x86-fbsd"
+IUSE="avx gtk opengl python sqlite3 sse sse2 threads"
+
+RDEPEND="dev-libs/glib:2
+	media-libs/freetype:2
+	media-libs/libpng:0
+	x11-libs/cairo
+	x11-libs/pango
+	dev-db/sqlite:3
+	media-libs/libcanberra
+	dev-libs/libxml2
+	dev-libs/gmp:0
+	gtk? ( x11-libs/gtk+:2 )
+	opengl? (
+		x11-libs/gtk+:2
+		x11-libs/gtkglext
+		virtual/glu
+	)
+	sys-libs/readline
+	python? ( ${PYTHON_DEPS} )
+	media-fonts/ttf-bitstream-vera
+	virtual/libintl"
+DEPEND="${RDEPEND}
+	virtual/pkgconfig
+	sys-devel/gettext"
+
+pkg_setup() {
+	games_pkg_setup
+	python-single-r1_pkg_setup
+}
+
+src_prepare() {
+	# use ${T} instead of /tmp for constructing credits (bug #298275)
+	sed -i -e 's:/tmp:${T}:' credits.sh || die
+	sed -i \
+		-e '/^localedir / s#=.*$#= @localedir@#' \
+		-e '/^gnulocaledir / s#=.*$#= @localedir@#' \
+		po/Makefile.in.in || die
+	sed -i \
+		-e '/^gnubgiconsdir / s#=.*#= /usr/share#' \
+		-e '/^gnubgpixmapsdir / s#=.*#= /usr/share/pixmaps#' \
+		pixmaps/Makefile.in || die
+}
+
+src_configure() {
+	local simd=no
+	local gtk_arg=--without-gtk
+
+	if use gtk || use opengl ; then
+		gtk_arg=--with-gtk
+	fi
+	use sse  && simd=sse
+	use sse2 && simd=sse2
+	use avx  && simd=avx
+	egamesconf \
+		--localedir=/usr/share/locale \
+		--docdir=/usr/share/doc/${PF}/html \
+		--disable-cputest \
+		--enable-simd=${simd} \
+		${gtk_arg} \
+		$(use_enable threads) \
+		$(use_with python) \
+		$(use_with sqlite3 sqlite) \
+		$(use_with opengl board3d)
+}
+
+src_install() {
+	default
+	insinto "${GAMES_DATADIR}/${PN}"
+	doins ${PN}.weights *bd
+	rm -rf "${D}${GAMES_DATADIR}/${PN}/fonts"
+	dosym /usr/share/fonts/ttf-bitstream-vera "${GAMES_DATADIR}"/${PN}/fonts
+	make_desktop_entry "gnubg -w" "GNU Backgammon"
+	prepgamesdirs
+}
+
+pkg_preinst() {
+	games_pkg_preinst
+	gnome2_icon_savelist
+}
+
+pkg_postinst() {
+	games_pkg_postinst
+	gnome2_icon_cache_update
+}
+
+pkg_postrm() {
+	gnome2_icon_cache_update
+}
diff --git a/games-board/gnubg/gnubg-20130203.ebuild b/games-board/gnubg/gnubg-20130203.ebuild
index 4e950e685618..dc26dd6250b4 100644
--- a/games-board/gnubg/gnubg-20130203.ebuild
+++ b/games-board/gnubg/gnubg-20130203.ebuild
@@ -1,6 +1,6 @@
-# Copyright 1999-2013 Gentoo Foundation
+# Copyright 1999-2014 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/games-board/gnubg/gnubg-20130203.ebuild,v 1.7 2013/12/24 12:52:37 ago Exp $
+# $Header: /var/cvsroot/gentoo-x86/games-board/gnubg/gnubg-20130203.ebuild,v 1.8 2014/11/14 09:00:27 mr_bones_ Exp $
 
 EAPI=5
 PYTHON_COMPAT=( python2_6 python2_7 )