apply Debian patch for bug #303399

(Portage version: 2.1.7.17/cvs/Linux i686)

2 files changed, 80 insertions, 2 deletions

diff --git a/games-board/eboard/ChangeLog b/games-board/eboard/ChangeLog
index fbbd8517d2c4..b5cd07964c98 100644
--- a/games-board/eboard/ChangeLog
+++ b/games-board/eboard/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for games-board/eboard
-# Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/games-board/eboard/ChangeLog,v 1.25 2009/06/18 01:48:47 nyhm Exp $
+# Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/games-board/eboard/ChangeLog,v 1.26 2010/03/23 17:27:37 mr_bones_ Exp $
+
+*eboard-1.1.1-r1 (23 Mar 2010)
+
+  23 Mar 2010; Michael Sterrett <mr_bones_@gentoo.org>
+  +eboard-1.1.1-r1.ebuild:
+  apply Debian patch for bug #303399
 
   18 Jun 2009; Tristan Heaven <nyhm@gentoo.org> eboard-1.1.1.ebuild,
   +files/eboard-1.1.1-gcc44.patch:
diff --git a/games-board/eboard/eboard-1.1.1-r1.ebuild b/games-board/eboard/eboard-1.1.1-r1.ebuild
new file mode 100644
index 000000000000..f09c770cb131
--- /dev/null
+++ b/games-board/eboard/eboard-1.1.1-r1.ebuild
@@ -0,0 +1,72 @@
+# Copyright 1999-2010 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/games-board/eboard/eboard-1.1.1-r1.ebuild,v 1.1 2010/03/23 17:27:37 mr_bones_ Exp $
+
+EAPI=2
+inherit eutils games
+
+DEB_V=${PV}-4.1
+EXTRAS1="eboard-extras-1pl2"
+EXTRAS2="eboard-extras-2"
+DESCRIPTION="chess interface for POSIX systems"
+HOMEPAGE="http://www.bergo.eng.br/eboard/"
+SRC_URI="mirror://sourceforge/${PN}/${P}.tar.bz2
+	mirror://sourceforge/${PN}/${EXTRAS1}.tar.gz
+	mirror://sourceforge/${PN}/${EXTRAS2}.tar.gz
+	mirror://debian/pool/main/e/eboard/${PN}_${DEB_V}.diff.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~sparc ~x86"
+IUSE="nls"
+
+RDEPEND="x11-libs/gtk+:2
+	media-libs/libpng
+	dev-lang/perl
+	nls? ( virtual/libintl )"
+DEPEND="${RDEPEND}
+	dev-util/pkgconfig
+	nls? ( sys-devel/gettext )"
+
+src_prepare() {
+	epatch \
+		"${WORKDIR}"/${PN}_${DEB_V}.diff \
+		"${FILESDIR}"/${P}-as-needed.patch \
+		"${FILESDIR}"/${P}-gcc44.patch
+	sed -i \
+		-e "s:(\"-O6\"):split(' ', \"${CXXFLAGS}\"):" \
+		configure \
+		|| die "sed configure failed"
+}
+
+src_configure() {
+	# not an autoconf script
+	./configure \
+		--compiler="${CXX}" \
+		--prefix="${GAMES_PREFIX}" \
+		--data-prefix="${GAMES_DATADIR}" \
+		--man-prefix="/usr/share/man" \
+		$(use_enable nls) || die
+}
+
+src_install() {
+	emake DESTDIR="${D}" install || die "emake install failed"
+	dodoc README AUTHORS ChangeLog TODO Documentation/*.txt
+
+	newicon icon-eboard.xpm ${PN}.xpm
+	make_desktop_entry ${PN} ${PN} ${PN}
+
+	cd "${WORKDIR}"/${EXTRAS1}
+	insinto "${GAMES_DATADIR}"/${PN}
+	doins *.png *.wav || die "doins failed (extra1)"
+	newins extras1.conf themeconf.extras1 || die "newins failed (extra1)"
+	newdoc ChangeLog Changelog.extras
+	newdoc README README.extras
+	dodoc CREDITS
+
+	cd "${WORKDIR}"/${EXTRAS2}
+	doins *.png *.wav || die "doins failed (extra2)"
+	newins extras2.conf themeconf.extras2 || die "newins failed (extra2)"
+
+	prepgamesdirs
+}