add new version which has the X use flag, disable to only get mzscheme and not drscheme

(Portage version: 2.1.2.7)

3 files changed, 100 insertions, 1 deletions

diff --git a/dev-scheme/drscheme/ChangeLog b/dev-scheme/drscheme/ChangeLog
index ee7f2e2c6a48..aba6595597c9 100644
--- a/dev-scheme/drscheme/ChangeLog
+++ b/dev-scheme/drscheme/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for dev-scheme/drscheme
 # Copyright 2002-2007 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-scheme/drscheme/ChangeLog,v 1.45 2007/03/18 23:35:58 beandog Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-scheme/drscheme/ChangeLog,v 1.46 2007/05/15 13:23:53 hkbst Exp $
+
+*drscheme-360-r2 (15 May 2007)
+
+  15 May 2007; Marijn Schouten <hkBst@gentoo.org> +drscheme-360-r2.ebuild:
+  add new version which has the X use flag, disable to only get mzscheme and
+  not drscheme
 
   18 Mar 2007; Steve Dibb <beandog@gentoo.org> drscheme-360-r1.ebuild:
   amd64 stable, bug 170813
diff --git a/dev-scheme/drscheme/drscheme-360-r2.ebuild b/dev-scheme/drscheme/drscheme-360-r2.ebuild
new file mode 100644
index 000000000000..974b7e5896fe
--- /dev/null
+++ b/dev-scheme/drscheme/drscheme-360-r2.ebuild
@@ -0,0 +1,90 @@
+# Copyright 1999-2007 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-scheme/drscheme/drscheme-360-r2.ebuild,v 1.1 2007/05/15 13:23:53 hkbst Exp $
+
+inherit eutils multilib flag-o-matic libtool
+
+DESCRIPTION="DrScheme programming environment.	Includes mzscheme."
+HOMEPAGE="http://www.plt-scheme.org/software/drscheme/"
+SRC_URI="http://download.plt-scheme.org/bundles/${PV}/plt/plt-${PV}-src-unix.tgz"
+
+LICENSE="LGPL-2.1"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~x86"
+IUSE="3m backtrace cairo jpeg opengl perl png X"
+
+RDEPEND="X? ( x11-libs/libICE
+			  x11-libs/libSM
+			  x11-libs/libXaw
+			  >=x11-libs/libXft-2.1.12
+			  media-libs/freetype
+			  media-libs/fontconfig )
+	cairo? ( >=x11-libs/cairo-1.2.3 )
+	jpeg? ( media-libs/jpeg )
+	opengl? ( virtual/opengl )
+	png? ( media-libs/libpng )"
+
+DEPEND="${RDEPEND}"
+
+S="${WORKDIR}/plt-${PV}/src"
+
+src_unpack() {
+	unpack ${A}
+	cd "${S}/.."
+
+	epatch "${FILESDIR}/${PN}-350-fPIC.patch"
+	epatch "${FILESDIR}/${P}-DESTDIR-3m.patch"
+
+	cd "${S}/mzscheme/gc"
+	elibtoolize
+	cd "${S}"
+
+	# lib dir fixups
+	sed -ie 's:-rpath ${absprefix}/lib:-rpath ${absprefix}/'$(get_libdir)':g' configure
+}
+
+src_compile() {
+	# -O3 seems to cause some miscompiles, this should fix #141925 and #133888
+	replace-flags -O? -O2
+
+	econf $(use_enable X mred) \
+		--enable-shared \
+		--enable-lt=/usr/bin/libtool \
+		$(use_enable backtrace) \
+		$(use_enable cairo) \
+		$(use_enable jpeg libjpeg) \
+		$(use_enable opengl gl) \
+		$(use_enable perl) \
+		$(use_enable png libpng) \
+		|| die "econf failed"
+
+	emake || die "emake failed"
+
+	if use 3m; then
+		emake -j1 3m || die "emake 3m failed"
+	fi
+}
+
+src_install() {
+	export MZSCHEME_DYNEXT_LINKER_FLAGS=$(raw-ldflags)
+
+	make DESTDIR="${D}" install || die "make install failed"
+
+	if use 3m; then
+		make DESTDIR="${D}" install-3m || die "make install-m3 failed"
+	fi
+
+	dodoc ${WORKDIR}/plt/{readme.txt,src/README}
+
+	mv -f "${D}"/usr/share/plt/doc/* "${D}/usr/share/doc/${PF}/"
+	rm -rf "${D}/usr/share/plt/doc"
+
+	# needed so online help works
+	keepdir /usr/share/plt
+	dosym "/usr/share/doc/${PF}" "/usr/share/plt/doc"
+
+	if use X; then
+		newicon "${WORKDIR}/plt-${PV}/collects/icons/PLT-206.png" drscheme.png
+		make_desktop_entry drscheme "DrScheme" drscheme.png "Development"
+	fi
+}
diff --git a/dev-scheme/drscheme/files/digest-drscheme-360-r2 b/dev-scheme/drscheme/files/digest-drscheme-360-r2
new file mode 100644
index 000000000000..d327f48d3562
--- /dev/null
+++ b/dev-scheme/drscheme/files/digest-drscheme-360-r2
@@ -0,0 +1,3 @@
+MD5 84bcab3ff30c333ae3c6b732518bdf27 plt-360-src-unix.tgz 14106005
+RMD160 cbe045f26f429d7df85540f09135c90bde45f84c plt-360-src-unix.tgz 14106005
+SHA256 014cd5c91231a5b6dd67c90ca9d2c26a7466abe0d072a37a40a605b29870f3bd plt-360-src-unix.tgz 14106005