Version bump. Add ruby20. Drop ppc64, bug 465948.

(Portage version: 2.2.7/cvs/Linux x86_64, signed Manifest commit with key 0x8883FA56A308A8D7!)

2 files changed, 58 insertions, 1 deletions

diff --git a/dev-ruby/msgpack/ChangeLog b/dev-ruby/msgpack/ChangeLog
index 27985b9b50d0..2a40101f0898 100644
--- a/dev-ruby/msgpack/ChangeLog
+++ b/dev-ruby/msgpack/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for dev-ruby/msgpack
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-ruby/msgpack/ChangeLog,v 1.19 2013/08/19 20:43:42 mrueg Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-ruby/msgpack/ChangeLog,v 1.20 2013/11/19 19:35:11 graaff Exp $
+
+*msgpack-0.5.7 (19 Nov 2013)
+
+  19 Nov 2013; Hans de Graaff <graaff@gentoo.org> +msgpack-0.5.7.ebuild:
+  Version bump. Add ruby20. Drop ppc64, bug 465948.
 
 *msgpack-0.5.5 (19 Aug 2013)
 
diff --git a/dev-ruby/msgpack/msgpack-0.5.7.ebuild b/dev-ruby/msgpack/msgpack-0.5.7.ebuild
new file mode 100644
index 000000000000..daed3dd92aeb
--- /dev/null
+++ b/dev-ruby/msgpack/msgpack-0.5.7.ebuild
@@ -0,0 +1,52 @@
+# Copyright 1999-2013 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-ruby/msgpack/msgpack-0.5.7.ebuild,v 1.1 2013/11/19 19:35:11 graaff Exp $
+
+EAPI=5
+
+# jruby → uses a binary extension
+USE_RUBY="ruby18 ruby19 ruby20"
+
+RUBY_FAKEGEM_TASK_DOC="doc"
+RUBY_FAKEGEM_RECIPE_TEST="rspec"
+RUBY_FAKEGEM_EXTRADOC="README.rdoc"
+
+inherit multilib ruby-fakegem
+
+DESCRIPTION="Binary-based efficient data interchange format for ruby binding"
+HOMEPAGE="http://msgpack.sourceforge.jp/"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~ppc ~x86 ~x86-fbsd"
+IUSE="doc"
+
+ruby_add_bdepend "doc? ( dev-ruby/yard )"
+
+all_ruby_prepare() {
+	sed -i -e '/bundler/I s:^:#:' Rakefile || die
+}
+
+each_ruby_prepare() {
+	case "${RUBY}" in
+		*ruby18)
+			# Fix tests as .clear is not available in ruby18
+			# Tests are working, but are very slow on ruby18
+			sed -i -e 's/s.clear/s.replace ""/' spec/buffer_spec.rb || die
+			# Avoid tests requiring ruby 1.9+
+			sed -i -e '/frozen short strings/,/end/ s:^:#:' \
+				-e '/frozen long strings/,/end/ s:^:#:' spec/unpacker_spec.rb || die
+			;;
+		*)
+			;;
+	esac
+}
+
+each_ruby_configure() {
+	${RUBY} -Cext/${PN} extconf.rb || die "Configuration of extension failed."
+}
+
+each_ruby_compile() {
+	emake V=1 -Cext/${PN}
+	cp ext/${PN}/msgpack$(get_modname) lib/${PN} || die "Unable to install msgpack library."
+}