Version bump.

(Portage version: 2.2.0_alpha186/cvs/Linux x86_64, signed Manifest commit with key 17A85C72)

2 files changed, 124 insertions, 1 deletions

diff --git a/dev-qt/qt-creator/ChangeLog b/dev-qt/qt-creator/ChangeLog
index e0fbdddbc90c..4cdc88dfb0b7 100644
--- a/dev-qt/qt-creator/ChangeLog
+++ b/dev-qt/qt-creator/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for dev-qt/qt-creator
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-qt/qt-creator/ChangeLog,v 1.11 2013/06/29 18:30:59 ago Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-qt/qt-creator/ChangeLog,v 1.12 2013/06/30 23:47:43 pesa Exp $
+
+*qt-creator-2.8.0_rc (30 Jun 2013)
+
+  30 Jun 2013; Davide Pesavento <pesa@gentoo.org> +qt-creator-2.8.0_rc.ebuild:
+  Version bump.
 
   29 Jun 2013; Agostino Sarubbo <ago@gentoo.org> qt-creator-2.7.0.ebuild:
   Stable for ppc, wrt bug #472148
diff --git a/dev-qt/qt-creator/qt-creator-2.8.0_rc.ebuild b/dev-qt/qt-creator/qt-creator-2.8.0_rc.ebuild
new file mode 100644
index 000000000000..e134d35324a4
--- /dev/null
+++ b/dev-qt/qt-creator/qt-creator-2.8.0_rc.ebuild
@@ -0,0 +1,118 @@
+# Copyright 1999-2013 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-qt/qt-creator/qt-creator-2.8.0_rc.ebuild,v 1.1 2013/06/30 23:47:43 pesa Exp $
+
+EAPI=5
+
+PLOCALES="cs de es fr it ja pl ru sl uk zh_CN zh_TW"
+
+inherit eutils l10n multilib qt4-r2
+
+DESCRIPTION="Lightweight IDE for C++/QML development centering around Qt"
+HOMEPAGE="http://qt-project.org/wiki/Category:Tools::QtCreator"
+LICENSE="LGPL-2.1"
+
+if [[ ${PV} == *9999* ]]; then
+	inherit git-2
+	EGIT_REPO_URI="git://gitorious.org/${PN}/${PN}.git
+		https://git.gitorious.org/${PN}/${PN}.git"
+else
+	MY_PV=${PV/_/-}
+	MY_P=${PN}-${MY_PV}-src
+	[[ ${MY_PV} == ${PV} ]] && MY_REL=official || MY_REL=development
+	SRC_URI="http://download.qt-project.org/${MY_REL}_releases/${PN/-}/${PV%.*}/${MY_PV}/${MY_P}.tar.gz"
+	S=${WORKDIR}/${MY_P}
+fi
+
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~ppc ~x86"
+
+QTC_PLUGINS=(android autotools:autotoolsprojectmanager bazaar
+	clearcase cmake:cmakeprojectmanager cvs fakevim git
+	madde mercurial perforce qnx subversion valgrind)
+IUSE="debug doc examples test ${QTC_PLUGINS[@]%:*}"
+
+# minimum Qt version required
+QT_PV="4.8.0:4"
+
+CDEPEND="
+	=dev-libs/botan-1.10*
+	>=dev-qt/qtcore-${QT_PV}[ssl]
+	>=dev-qt/qtdeclarative-${QT_PV}
+	>=dev-qt/qtgui-${QT_PV}
+	>=dev-qt/qthelp-${QT_PV}[doc?]
+	>=dev-qt/qtscript-${QT_PV}
+	>=dev-qt/qtsql-${QT_PV}
+	>=dev-qt/qtsvg-${QT_PV}
+"
+DEPEND="${CDEPEND}
+	virtual/pkgconfig
+	test? ( >=dev-qt/qttest-${QT_PV} )
+"
+RDEPEND="${CDEPEND}
+	>=sys-devel/gdb-7.2[python]
+	examples? ( >=dev-qt/qtdemo-${QT_PV} )
+"
+PDEPEND="
+	autotools? ( sys-devel/autoconf )
+	bazaar? ( dev-vcs/bzr )
+	cmake? ( dev-util/cmake )
+	cvs? ( dev-vcs/cvs )
+	git? ( dev-vcs/git )
+	mercurial? ( dev-vcs/mercurial )
+	subversion? ( dev-vcs/subversion )
+	valgrind? ( dev-util/valgrind )
+"
+
+src_prepare() {
+	qt4-r2_src_prepare
+
+	# disable unwanted plugins
+	for plugin in "${QTC_PLUGINS[@]#[+-]}"; do
+		if ! use ${plugin%:*}; then
+			einfo "Disabling ${plugin%:*} plugin"
+			sed -i -re "/^\s+${plugin#*:}\>/d" src/plugins/plugins.pro \
+				|| die "failed to disable ${plugin%:*} plugin"
+		fi
+	done
+
+	# fix translations
+	sed -i -e "/^LANGUAGES =/ s:=.*:= $(l10n_get_locales):" \
+		share/qtcreator/translations/translations.pro || die
+}
+
+src_configure() {
+	EQMAKE4_EXCLUDE="share/qtcreator/templates/*
+			tests/*"
+	eqmake4 IDE_LIBRARY_BASENAME="$(get_libdir)" \
+		IDE_PACKAGE_MODE=1 \
+		TEST=$(use test && echo 1 || echo 0) \
+		USE_SYSTEM_BOTAN=1
+}
+
+src_test() {
+	echo ">>> Test phase [QTest]: ${CATEGORY}/${PF}"
+	cd tests/auto || die
+
+	EQMAKE4_EXCLUDE="valgrind/*"
+	eqmake4 IDE_LIBRARY_BASENAME="$(get_libdir)"
+
+	emake check
+}
+
+src_install() {
+	emake INSTALL_ROOT="${ED}usr" install
+
+	dodoc dist/{changes-*,known-issues}
+
+	# install documentation
+	if use doc; then
+		emake docs
+		insinto /usr/share/doc/${PF}
+		doins share/doc/qtcreator/qtcreator{,-dev}.qch
+		docompress -x /usr/share/doc/${PF}/qtcreator{,-dev}.qch
+	fi
+
+	# install desktop file
+	make_desktop_entry qtcreator 'Qt Creator' QtProject-qtcreator 'Qt;Development;IDE'
+}