Link against the right version of the boost python library (bug #536734 by Justin Keogh).

(Portage version: 2.2.15/cvs/Linux x86_64, signed Manifest commit with key 4AB3E85B4F064CA3)

3 files changed, 109 insertions, 5 deletions

diff --git a/dev-python/graph-tool/ChangeLog b/dev-python/graph-tool/ChangeLog
index ef5e0e19b329..90de9e6cb5cc 100644
--- a/dev-python/graph-tool/ChangeLog
+++ b/dev-python/graph-tool/ChangeLog
@@ -1,6 +1,13 @@
 # ChangeLog for dev-python/graph-tool
 # Copyright 1999-2015 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-python/graph-tool/ChangeLog,v 1.21 2015/01/17 14:03:07 radhermit Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-python/graph-tool/ChangeLog,v 1.22 2015/01/21 16:35:09 radhermit Exp $
+
+*graph-tool-2.2.36-r1 (21 Jan 2015)
+
+  21 Jan 2015; Tim Harder <radhermit@gentoo.org> +graph-tool-2.2.36-r1.ebuild,
+  graph-tool-9999.ebuild:
+  Link against the right version of the boost python library (bug #536734 by
+  Justin Keogh).
 
   17 Jan 2015; Tim Harder <radhermit@gentoo.org> graph-tool-2.2.36.ebuild,
   graph-tool-9999.ebuild:
diff --git a/dev-python/graph-tool/graph-tool-2.2.36-r1.ebuild b/dev-python/graph-tool/graph-tool-2.2.36-r1.ebuild
new file mode 100644
index 000000000000..ffea16f23b88
--- /dev/null
+++ b/dev-python/graph-tool/graph-tool-2.2.36-r1.ebuild
@@ -0,0 +1,91 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-python/graph-tool/graph-tool-2.2.36-r1.ebuild,v 1.1 2015/01/21 16:35:09 radhermit Exp $
+
+EAPI=5
+PYTHON_COMPAT=( python{2_7,3_3,3_4} )
+
+inherit check-reqs toolchain-funcs python-r1 eutils
+
+if [[ ${PV} == "9999" ]] ; then
+	EGIT_REPO_URI="https://github.com/count0/graph-tool.git"
+	inherit autotools git-r3
+else
+	SRC_URI="http://downloads.skewed.de/${PN}/${P}.tar.bz2"
+	KEYWORDS="~amd64 ~x86"
+fi
+
+DESCRIPTION="An efficient python module for manipulation and statistical analysis of graphs"
+HOMEPAGE="http://graph-tool.skewed.de/"
+
+LICENSE="GPL-3"
+SLOT="0"
+IUSE="+cairo openmp"
+
+CDEPEND="${PYTHON_DEPS}
+	>=dev-libs/boost-1.54.0[python,${PYTHON_USEDEP}]
+	dev-libs/expat
+	dev-python/numpy[${PYTHON_USEDEP}]
+	sci-libs/scipy[${PYTHON_USEDEP}]
+	>=sci-mathematics/cgal-3.5
+	cairo? (
+		dev-cpp/cairomm
+		dev-python/pycairo[${PYTHON_USEDEP}]
+	)"
+RDEPEND="${CDEPEND}
+	dev-python/matplotlib[${PYTHON_USEDEP}]"
+DEPEND="${CDEPEND}
+	dev-cpp/sparsehash
+	virtual/pkgconfig"
+
+# most machines don't have enough ram for parallel builds
+MAKEOPTS="${MAKEOPTS} -j1"
+
+# bug 453544
+CHECKREQS_DISK_BUILD="6G"
+
+pkg_pretend() {
+	if use openmp ; then
+		tc-has-openmp || die "Please switch to an openmp compatible compiler"
+	fi
+	check-reqs_pkg_pretend
+}
+
+src_prepare() {
+	[[ ${PV} == "9999" ]] && eautoreconf
+	>py-compile
+	python_copy_sources
+}
+
+src_configure() {
+	local threads
+	built_with_use dev-libs/boost threads && threads="-mt"
+
+	configure() {
+		econf \
+			--disable-static \
+			--disable-optimization \
+			$(use_enable openmp) \
+			$(use_enable cairo) \
+			--with-boost-python="${EPYTHON: -3}${threads}"
+	}
+	python_foreach_impl run_in_build_dir configure
+}
+
+src_compile() {
+	python_foreach_impl run_in_build_dir default
+}
+
+src_install() {
+	python_foreach_impl run_in_build_dir default
+	prune_libtool_files --modules
+
+	# remove unwanted extra docs
+	rm -r "${ED}"/usr/share/doc/${PN} || die
+}
+
+run_in_build_dir() {
+	pushd "${BUILD_DIR}" > /dev/null
+	"$@"
+	popd > /dev/null
+}
diff --git a/dev-python/graph-tool/graph-tool-9999.ebuild b/dev-python/graph-tool/graph-tool-9999.ebuild
index 9f020f3f47a4..fffecc570553 100644
--- a/dev-python/graph-tool/graph-tool-9999.ebuild
+++ b/dev-python/graph-tool/graph-tool-9999.ebuild
@@ -1,11 +1,11 @@
 # Copyright 1999-2015 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/dev-python/graph-tool/graph-tool-9999.ebuild,v 1.10 2015/01/17 14:03:07 radhermit Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-python/graph-tool/graph-tool-9999.ebuild,v 1.11 2015/01/21 16:35:09 radhermit Exp $
 
 EAPI=5
 PYTHON_COMPAT=( python{2_7,3_3,3_4} )
 
-inherit check-reqs toolchain-funcs python-r1
+inherit check-reqs toolchain-funcs python-r1 eutils
 
 if [[ ${PV} == "9999" ]] ; then
 	EGIT_REPO_URI="https://github.com/count0/graph-tool.git"
@@ -58,12 +58,18 @@ src_prepare() {
 }
 
 src_configure() {
-	python_foreach_impl run_in_build_dir \
+	local threads
+	built_with_use dev-libs/boost threads && threads="-mt"
+
+	configure() {
 		econf \
 			--disable-static \
 			--disable-optimization \
 			$(use_enable openmp) \
-			$(use_enable cairo)
+			$(use_enable cairo) \
+			--with-boost-python="${EPYTHON: -3}${threads}"
+	}
+	python_foreach_impl run_in_build_dir configure
 }
 
 src_compile() {