Bump

(Portage version: 2.2.20/cvs/Linux x86_64, unsigned Manifest commit)

2 files changed, 65 insertions, 1 deletions

diff --git a/dev-python/wsgiintercept/ChangeLog b/dev-python/wsgiintercept/ChangeLog
index e9f17c301f12..4b2dac438edc 100644
--- a/dev-python/wsgiintercept/ChangeLog
+++ b/dev-python/wsgiintercept/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for dev-python/wsgiintercept
 # Copyright 1999-2015 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-python/wsgiintercept/ChangeLog,v 1.19 2015/07/28 07:57:11 idella4 Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-python/wsgiintercept/ChangeLog,v 1.20 2015/08/04 01:51:54 patrick Exp $
+
+*wsgiintercept-0.10.2 (04 Aug 2015)
+
+  04 Aug 2015; Patrick Lauer <patrick@gentoo.org> +wsgiintercept-0.10.2.ebuild:
+  Bump
 
   28 Jul 2015; Ian Delaney <idella4@gentoo.org> wsgiintercept-0.10.0.ebuild:
   set removal of test folder, fixes bug #555842 by the tinderbox
diff --git a/dev-python/wsgiintercept/wsgiintercept-0.10.2.ebuild b/dev-python/wsgiintercept/wsgiintercept-0.10.2.ebuild
new file mode 100644
index 000000000000..c8b6dc87f834
--- /dev/null
+++ b/dev-python/wsgiintercept/wsgiintercept-0.10.2.ebuild
@@ -0,0 +1,59 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-python/wsgiintercept/wsgiintercept-0.10.2.ebuild,v 1.1 2015/08/04 01:51:54 patrick Exp $
+
+EAPI=5
+
+PYTHON_COMPAT=( python2_7 python3_{3,4} pypy )
+
+inherit distutils-r1
+
+MY_PN="wsgi_intercept"
+MY_P="${MY_PN}-${PV}"
+
+DESCRIPTION="WSGI application in place of a real URI for testing"
+HOMEPAGE="https://github.com/cdent/python3-wsgi-intercept"
+SRC_URI="mirror://pypi/${MY_PN:0:1}/${MY_PN}/${MY_P}.tar.gz"
+
+SLOT="0"
+LICENSE="MIT"
+KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux"
+IUSE="doc test"
+RDEPEND=""
+DEPEND="
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	test? (
+		dev-python/httplib2[${PYTHON_USEDEP}]
+		>=dev-python/pytest-2.4[${PYTHON_USEDEP}]
+		>=dev-python/requests-2.0.1[${PYTHON_USEDEP}]
+		$(python_gen_cond_dep 'dev-python/mechanize[${PYTHON_USEDEP}]' python2_7 pypy)
+	)"
+S="${WORKDIR}/${MY_P}"
+
+python_prepare_all() {
+	# .pyc files cause failure of tests
+	rm -rf test/__pycache__/ || die
+
+	# Req'd to avoid file collisions
+	sed -e s":find_packages():find_packages(exclude=['test']):" \
+		-i setup.py || die
+
+	# Disable tests connecting to the network; Bug #550710
+	sed -e 's:test_http_not_intercepted:_&:' \
+		-e 's:test_https_not_intercepted:_&:' \
+		-i test/{test_urllib.py,test_http_client.py,test_requests.py} || die
+	distutils-r1_python_prepare_all
+}
+
+python_compile_all() {
+	use doc && emake -C docs html
+}
+
+python_test() {
+	py.test || die "Tests failed under ${EPYTHON}"
+}
+
+python_install_all() {
+	use doc && local HTML_DOCS=( docs/_build/html//. )
+	distutils-r1_python_install_all
+}