Version bump. Fix examples documentation install location.

(Portage version: 2.2.0_alpha38/cvs/Linux x86_64)

2 files changed, 64 insertions, 2 deletions

diff --git a/dev-python/python-musicbrainz/ChangeLog b/dev-python/python-musicbrainz/ChangeLog
index 029df822172c..ae049f452d19 100644
--- a/dev-python/python-musicbrainz/ChangeLog
+++ b/dev-python/python-musicbrainz/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for dev-python/python-musicbrainz
-# Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-python/python-musicbrainz/ChangeLog,v 1.9 2010/12/25 17:40:30 arfrever Exp $
+# Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/dev-python/python-musicbrainz/ChangeLog,v 1.10 2011/06/09 08:28:44 radhermit Exp $
+
+*python-musicbrainz-0.7.3 (09 Jun 2011)
+
+  09 Jun 2011; Tim Harder <radhermit@gentoo.org>
+  +python-musicbrainz-0.7.3.ebuild:
+  Version bump. Fix examples documentation install location.
 
 *python-musicbrainz-0.7.2 (25 Dec 2010)
 
diff --git a/dev-python/python-musicbrainz/python-musicbrainz-0.7.3.ebuild b/dev-python/python-musicbrainz/python-musicbrainz-0.7.3.ebuild
new file mode 100644
index 000000000000..4ac8dfc9fb41
--- /dev/null
+++ b/dev-python/python-musicbrainz/python-musicbrainz-0.7.3.ebuild
@@ -0,0 +1,56 @@
+# Copyright 1999-2011 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-python/python-musicbrainz/python-musicbrainz-0.7.3.ebuild,v 1.1 2011/06/09 08:28:44 radhermit Exp $
+
+EAPI="3"
+PYTHON_DEPEND="2:2.5"
+SUPPORT_PYTHON_ABIS="1"
+# ctypes module required.
+RESTRICT_PYTHON_ABIS="2.4 3.* *-jython"
+
+inherit distutils
+
+MY_PN="${PN}2"
+MY_P="${MY_PN}-${PV}"
+
+DESCRIPTION="Python Bindings for the MusicBrainz XML Web Service"
+HOMEPAGE="http://musicbrainz.org"
+SRC_URI="http://ftp.musicbrainz.org/pub/musicbrainz/${MY_PN}/${MY_P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~hppa ~ppc ~ppc64 ~x86"
+IUSE="doc examples"
+
+RDEPEND="media-libs/libdiscid"
+DEPEND="${RDEPEND}
+	doc? ( dev-python/epydoc )"
+
+S="${WORKDIR}/${MY_P}"
+
+DOCS="AUTHORS.txt CHANGES.txt README.txt"
+PYTHON_MODNAME="musicbrainz2"
+
+src_compile() {
+	distutils_src_compile
+
+	if use doc; then
+		einfo "Generation of documentation"
+		"$(PYTHON -f)" setup.py docs || die "Generation of documentation failed"
+	fi
+}
+
+src_install() {
+	distutils_src_install
+
+	if use doc; then
+		dohtml html/* || die "Installation of documentation failed"
+	fi
+
+	if use examples; then
+		docinto examples
+		dodoc examples/*.txt || die "dodoc failed"
+		insinto /usr/share/doc/${PF}/examples
+		doins examples/*.py || die "doins failed"
+	fi
+}