Migrate to distutils-r1.

(Portage version: 2.2.0_alpha149/cvs/Linux x86_64, signed Manifest commit with key 42B9401D)

2 files changed, 65 insertions, 2 deletions

diff --git a/dev-python/python-dateutil/ChangeLog b/dev-python/python-dateutil/ChangeLog
index bf7783024382..b2a8e139d304 100644
--- a/dev-python/python-dateutil/ChangeLog
+++ b/dev-python/python-dateutil/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for dev-python/python-dateutil
-# Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-python/python-dateutil/ChangeLog,v 1.42 2012/12/17 17:53:41 ago Exp $
+# Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/dev-python/python-dateutil/ChangeLog,v 1.43 2013/01/01 15:31:49 mgorny Exp $
+
+*python-dateutil-2.1-r1 (01 Jan 2013)
+
+  01 Jan 2013; Michał Górny <mgorny@gentoo.org> +python-dateutil-2.1-r1.ebuild:
+  Migrate to distutils-r1.
 
   17 Dec 2012; Agostino Sarubbo <ago@gentoo.org> python-dateutil-2.1.ebuild:
   Stable for ia64, wrt bug #426466
diff --git a/dev-python/python-dateutil/python-dateutil-2.1-r1.ebuild b/dev-python/python-dateutil/python-dateutil-2.1-r1.ebuild
new file mode 100644
index 000000000000..1f926163d2e7
--- /dev/null
+++ b/dev-python/python-dateutil/python-dateutil-2.1-r1.ebuild
@@ -0,0 +1,58 @@
+# Copyright 1999-2013 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-python/python-dateutil/python-dateutil-2.1-r1.ebuild,v 1.1 2013/01/01 15:31:49 mgorny Exp $
+
+EAPI=5
+PYTHON_COMPAT=( python{2_6,2_7,3_1,3_2,3_3} )
+
+inherit distutils-r1
+
+DESCRIPTION="Extensions to the standard Python datetime module"
+HOMEPAGE="https://launchpad.net/dateutil http://pypi.python.org/pypi/python-dateutil"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~ia64 ~ppc ~ppc64 ~x86 ~x86-fbsd ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos"
+IUSE="examples"
+
+RDEPEND="dev-python/six[${PYTHON_USEDEP}]
+	sys-libs/timezone-data
+	!<dev-python/python-dateutil-2.1"
+DEPEND="${RDEPEND}
+	dev-python/setuptools[${PYTHON_USEDEP}]"
+
+PATCHES=(
+	# Bug 410725.
+	"${FILESDIR}/${P}-open-utf-8.patch"
+)
+
+python_prepare_all() {
+	# Use zoneinfo in /usr/share/zoneinfo.
+	sed -i -e "s/zoneinfo.gettz/gettz/g" test.py || die
+
+	# Fix parsing of date in non-English locales.
+	sed -e 's/subprocess.getoutput("date")/subprocess.getoutput("LC_ALL=C date")/' \
+		-i example.py || die
+
+	distutils-r1_python_prepare_all
+}
+
+python_test() {
+	"${PYTHON}" test.py || die
+}
+
+python_install() {
+	distutils-r1_python_install
+
+	rm -f "${D}$(python_get_sitedir)/dateutil/zoneinfo"/*.tar.*
+}
+
+python_install_all() {
+	distutils-r1_python_install_all
+
+	if use examples; then
+		docinto examples
+		dodoc example.py sandbox/*.py
+	fi
+}