Convert to distutils-r1.

(Portage version: 2.2.1_p5/cvs/Linux x86_64, signed Manifest commit with key EFB4464E!)

2 files changed, 61 insertions, 1 deletions

diff --git a/dev-python/colander/ChangeLog b/dev-python/colander/ChangeLog
index 1a8787ecc05a..f8b0b7dac976 100644
--- a/dev-python/colander/ChangeLog
+++ b/dev-python/colander/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for dev-python/colander
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-python/colander/ChangeLog,v 1.9 2013/01/22 07:01:30 patrick Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-python/colander/ChangeLog,v 1.10 2013/08/26 07:59:47 mgorny Exp $
+
+*colander-1.0_alpha1-r1 (26 Aug 2013)
+
+  26 Aug 2013; Michał Górny <mgorny@gentoo.org> +colander-1.0_alpha1-r1.ebuild:
+  Convert to distutils-r1.
 
 *colander-1.0_alpha1 (22 Jan 2013)
 
diff --git a/dev-python/colander/colander-1.0_alpha1-r1.ebuild b/dev-python/colander/colander-1.0_alpha1-r1.ebuild
new file mode 100644
index 000000000000..72fec6e116ee
--- /dev/null
+++ b/dev-python/colander/colander-1.0_alpha1-r1.ebuild
@@ -0,0 +1,55 @@
+# Copyright 1999-2013 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-python/colander/colander-1.0_alpha1-r1.ebuild,v 1.1 2013/08/26 07:59:47 mgorny Exp $
+
+EAPI=5
+
+PYTHON_COMPAT=( python{2_6,2_7,3_2,3_3} pypy2_0 )
+
+inherit distutils-r1
+
+DESCRIPTION="A simple schema-based serialization and deserialization library"
+HOMEPAGE="http://docs.pylonsproject.org/projects/colander/en/latest/ http://pypi.python.org/pypi/colander"
+MY_P=${P/_alpha1/a1}
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${MY_P}.tar.gz"
+
+S="${WORKDIR}/${MY_P}"
+
+# MIT license is used by included (modified) iso8601.py code.
+LICENSE="repoze MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="doc"
+
+# Depend on an ebuild of translationstring with Python 3 support.
+RDEPEND=">=dev-python/translationstring-1.1[${PYTHON_USEDEP}]"
+
+DEPEND="${RDEPEND}
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	doc? ( dev-python/sphinx[${PYTHON_USEDEP}] )"
+
+# Include COPYRIGHT.txt because the license seems to require it.
+DOCS=( CHANGES.txt COPYRIGHT.txt README.txt )
+
+python_prepare_all() {
+	# Remove pylons theme since it's not included in source
+	sed -e "/# Add and use Pylons theme/,+37d" -i docs/conf.py || die
+
+	distutils-r1_python_prepare_all
+}
+
+python_compile_all() {
+	if use doc; then
+		# https://github.com/Pylons/colander/issues/38
+		emake -C docs html SPHINXOPTS=""
+	fi
+}
+
+python_test() {
+	nosetests || die "Tests fail with ${EPYTHON}"
+}
+
+python_install_all() {
+	use doc && local HTML_DOCS=( docs/_build/html/. )
+	distutils-r1_python_install_all
+}