Version bump.

(Portage version: 2.2.0_alpha13/cvs/Linux x86_64)

2 files changed, 68 insertions, 2 deletions

diff --git a/dev-libs/libgdata/ChangeLog b/dev-libs/libgdata/ChangeLog
index 3b9fb1d69f03..586913a53ef2 100644
--- a/dev-libs/libgdata/ChangeLog
+++ b/dev-libs/libgdata/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for dev-libs/libgdata
-# Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-libs/libgdata/ChangeLog,v 1.19 2010/12/15 22:16:19 eva Exp $
+# Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/dev-libs/libgdata/ChangeLog,v 1.20 2011/01/13 16:08:49 eva Exp $
+
+*libgdata-0.8.0 (13 Jan 2011)
+
+  13 Jan 2011; Gilles Dartiguelongue <eva@gentoo.org> +libgdata-0.8.0.ebuild:
+  Version bump.
 
 *libgdata-0.6.6 (15 Dec 2010)
 
diff --git a/dev-libs/libgdata/libgdata-0.8.0.ebuild b/dev-libs/libgdata/libgdata-0.8.0.ebuild
new file mode 100644
index 000000000000..322f119ed869
--- /dev/null
+++ b/dev-libs/libgdata/libgdata-0.8.0.ebuild
@@ -0,0 +1,61 @@
+# Copyright 1999-2011 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-libs/libgdata/libgdata-0.8.0.ebuild,v 1.1 2011/01/13 16:08:49 eva Exp $
+
+EAPI="3"
+GCONF_DEBUG="yes"
+
+inherit eutils gnome2
+
+DESCRIPTION="GLib-based library for accessing online service APIs using the GData protocol"
+HOMEPAGE="http://live.gnome.org/libgdata"
+
+LICENSE="LGPL-2.1"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~ia64 ~ppc ~ppc64 ~sparc ~x86"
+IUSE="doc gnome +introspection"
+
+# gtk+ is needed for gdk
+RDEPEND=">=dev-libs/glib-2.19:2
+	|| (
+		>=x11-libs/gdk-pixbuf-2.14:2
+		>=x11-libs/gtk+-2.14:2 )
+	>=dev-libs/libxml2-2
+	>=net-libs/libsoup-2.26.1:2.4
+	gnome? ( >=net-libs/libsoup-gnome-2.26.1:2.4 )
+	introspection? ( >=dev-libs/gobject-introspection-0.9.7 )"
+DEPEND="${RDEPEND}
+	>=dev-util/intltool-0.40
+	doc? ( >=dev-util/gtk-doc-1.14 )"
+
+pkg_setup() {
+	DOCS="AUTHORS ChangeLog HACKING NEWS README"
+	G2CONF="${G2CONF}
+		--disable-static
+		$(use_enable gnome)
+		$(use_enable introspection)"
+}
+
+src_prepare() {
+	gnome2_src_prepare
+
+	# Disable tests requiring network access, bug #307725
+	sed -e '/^TEST_PROGS = / s:\(.*\):TEST_PROGS = general perf\nOLD_\1:' \
+		-i gdata/tests/Makefile.in || die "network test disable failed"
+}
+
+src_test() {
+	unset ORBIT_SOCKETDIR
+	unset DBUS_SESSION_BUS_ADDRESS
+	dbus-launch emake check || die "emake check failed"
+}
+
+pkg_preinst() {
+	gnome2_pkg_preinst
+	preserve_old_lib /usr/$(get_libdir)/libgdata.so.7
+}
+
+pkg_postinst() {
+	gnome2_pkg_postinst
+	preserve_old_lib_notify /usr/$(get_libdir)/libgdata.so.7
+}