Version Bump

(Portage version: 2.2.8-r1/cvs/Linux x86_64, signed Manifest commit with key B9D4F231BD1558AB!)

2 files changed, 81 insertions, 2 deletions

diff --git a/dev-libs/libdbusmenu/ChangeLog b/dev-libs/libdbusmenu/ChangeLog
index 683332196bd2..853ff0e43bf0 100644
--- a/dev-libs/libdbusmenu/ChangeLog
+++ b/dev-libs/libdbusmenu/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for dev-libs/libdbusmenu
-# Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-libs/libdbusmenu/ChangeLog,v 1.27 2013/07/06 22:30:23 xmw Exp $
+# Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/dev-libs/libdbusmenu/ChangeLog,v 1.28 2014/02/12 10:04:56 jlec Exp $
+
+*libdbusmenu-12.10.2 (12 Feb 2014)
+
+  12 Feb 2014; Justin Lecher <jlec@gentoo.org> +libdbusmenu-12.10.2.ebuild:
+  Version Bump
 
   06 Jul 2013; Michael Weber <xmw@gentoo.org> libdbusmenu-0.6.2.ebuild:
   Depend on gtk+ introspection (bug 475938).
diff --git a/dev-libs/libdbusmenu/libdbusmenu-12.10.2.ebuild b/dev-libs/libdbusmenu/libdbusmenu-12.10.2.ebuild
new file mode 100644
index 000000000000..5c6c72e75ee9
--- /dev/null
+++ b/dev-libs/libdbusmenu/libdbusmenu-12.10.2.ebuild
@@ -0,0 +1,74 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-libs/libdbusmenu/libdbusmenu-12.10.2.ebuild,v 1.1 2014/02/12 10:04:56 jlec Exp $
+
+EAPI=5
+
+VALA_MIN_API_VERSION=0.16
+VALA_USE_DEPEND=vapigen
+PYTHON_COMPAT=( python{2_6,2_7} )
+
+inherit eutils flag-o-matic python-single-r1 vala
+
+DESCRIPTION="Library to pass menu structure across DBus"
+HOMEPAGE="http://launchpad.net/dbusmenu"
+SRC_URI="http://launchpad.net/${PN/lib}/${PV%.*}/${PV}/+download/${P}.tar.gz"
+
+LICENSE="LGPL-2.1 LGPL-3"
+SLOT="3"
+KEYWORDS="~amd64 ~arm ~hppa ~mips ~x86"
+IUSE="debug gtk +introspection"
+
+RDEPEND="
+	>=dev-libs/glib-2.32
+	>=dev-libs/dbus-glib-0.100
+	dev-libs/libxml2
+	gtk? ( >=x11-libs/gtk+-3.2:3[introspection?] )
+	introspection? ( >=dev-libs/gobject-introspection-1 )
+	!<${CATEGORY}/${PN}-0.5.1-r200"
+DEPEND="${RDEPEND}
+	app-text/gnome-doc-utils
+	dev-util/intltool
+	virtual/pkgconfig
+	introspection? ( $(vala_depend) )"
+
+src_prepare() {
+	if use introspection; then
+		vala_src_prepare
+		export VALA_API_GEN="${VAPIGEN}"
+	fi
+	python_fix_shebang tools
+}
+
+src_configure() {
+	append-flags -Wno-error #414323
+
+	# dumper extra tool is only for GTK+-2.x, tests use valgrind which is stupid
+	econf \
+		--docdir=/usr/share/doc/${PF} \
+		--disable-static \
+		--disable-silent-rules \
+		--disable-scrollkeeper \
+		$(use_enable gtk) \
+		--disable-dumper \
+		$(use_enable introspection) \
+		$(use_enable introspection vala) \
+		$(use_enable debug massivedebugging) \
+		--with-html-dir=/usr/share/doc/${PF}/html \
+		--with-gtk=3
+}
+
+src_test() { :; } #440192
+
+src_install() {
+	MAKEOPTS+=" -j1"
+	default
+
+	local a b
+	for a in ${PN}-{glib,gtk}; do
+		b=/usr/share/doc/${PF}/html/${a}
+		[[ -d ${ED}/${b} ]] && dosym ${b} /usr/share/gtk-doc/html/${a}
+	done
+
+	prune_libtool_files
+}