Version bump from Pavel; rename old version to 6. so that the upgrade path is clear.

(Portage version: 2.2_rc96/cvs/Linux x86_64)

3 files changed, 181 insertions, 5 deletions

diff --git a/dev-db/drizzle/ChangeLog b/dev-db/drizzle/ChangeLog
index 7a0a6a6eb844..5e53b691879d 100644
--- a/dev-db/drizzle/ChangeLog
+++ b/dev-db/drizzle/ChangeLog
@@ -1,6 +1,15 @@
 # ChangeLog for dev-db/drizzle
 # Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-db/drizzle/ChangeLog,v 1.15 2010/09/06 20:21:39 flameeyes Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-db/drizzle/ChangeLog,v 1.16 2010/10/14 20:23:18 flameeyes Exp $
+
+*drizzle-7.2010.10.01 (14 Oct 2010)
+*drizzle-6.2010.08.1742 (14 Oct 2010)
+
+  14 Oct 2010; Diego E. Pettenò <flameeyes@gentoo.org>
+  +drizzle-6.2010.08.1742.ebuild, +drizzle-7.2010.10.01.ebuild,
+  -drizzle-2010.08.1742.ebuild:
+  Version bump from Pavel; rename old version to 6. so that the upgrade path
+  is clear.
 
   06 Sep 2010; Diego E. Pettenò <flameeyes@gentoo.org>
   drizzle-2010.08.1742.ebuild:
diff --git a/dev-db/drizzle/drizzle-2010.08.1742.ebuild b/dev-db/drizzle/drizzle-6.2010.08.1742.ebuild
index b5594682f851..b5d65deea390 100644
--- a/dev-db/drizzle/drizzle-2010.08.1742.ebuild
+++ b/dev-db/drizzle/drizzle-6.2010.08.1742.ebuild
@@ -1,14 +1,18 @@
 # Copyright 1999-2010 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/dev-db/drizzle/drizzle-2010.08.1742.ebuild,v 1.2 2010/09/06 20:21:39 flameeyes Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-db/drizzle/drizzle-6.2010.08.1742.ebuild,v 1.1 2010/10/14 20:23:18 flameeyes Exp $
 
 EAPI=2
 
-inherit flag-o-matic libtool autotools eutils pam
+inherit flag-o-matic libtool autotools eutils pam versionator
+
+MY_P="${PN}-$(get_version_component_range 2-)"
+S="${WORKDIR}/${MY_P}"
 
 DESCRIPTION="Database optimized for Cloud and Net applications"
 HOMEPAGE="http://drizzle.org"
-SRC_URI="http://launchpad.net/drizzle/dexter/2010-08-30/+download/${P}.tar.gz"
+SRC_URI="http://launchpad.net/drizzle/dexter/2010-08-30/+download/${MY_P}.tar.gz"
+
 LICENSE="GPL-2"
 SLOT="0"
 KEYWORDS="~amd64 ~x86"
@@ -45,7 +49,7 @@ pkg_setup() {
 
 src_prepare() {
 	epatch "${FILESDIR}/${PN}-2009.12.1240-nolint.patch"
-	epatch "${FILESDIR}/${P}-pcre.patch"
+	epatch "${FILESDIR}/${PN}-2010.08.1742-pcre.patch"
 
 	AT_M4DIR="m4" eautoreconf
 	elibtoolize
diff --git a/dev-db/drizzle/drizzle-7.2010.10.01.ebuild b/dev-db/drizzle/drizzle-7.2010.10.01.ebuild
new file mode 100644
index 000000000000..5b4a7f310314
--- /dev/null
+++ b/dev-db/drizzle/drizzle-7.2010.10.01.ebuild
@@ -0,0 +1,163 @@
+# Copyright 1999-2010 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-db/drizzle/drizzle-7.2010.10.01.ebuild,v 1.1 2010/10/14 20:23:18 flameeyes Exp $
+
+EAPI=2
+
+inherit flag-o-matic libtool autotools eutils pam versionator
+
+MY_P="${PN}$(replace_version_separator 1 -)"
+S="${WORKDIR}/${MY_P}"
+
+DESCRIPTION="Database optimized for Cloud and Net applications"
+HOMEPAGE="http://drizzle.org"
+SRC_URI="http://launchpad.net/drizzle/elliott/2010-10-11/+download/${MY_P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="debug tcmalloc doc memcache curl pam gearman +md5 ldap"
+
+# upstream bug #499911
+#RESTRICT="memcache? ( test ) !curl? ( test )"
+
+# for libdrizzle version, check m4/pandora*, PANDORA_LIBDRIZZLE_RECENT
+RDEPEND="tcmalloc? ( dev-util/google-perftools )
+		sys-libs/readline
+		sys-apps/util-linux
+		dev-libs/libpcre
+		sys-devel/flex
+		>=dev-libs/libevent-1.4
+		>=dev-libs/protobuf-2.1.0
+		gearman? ( >=sys-cluster/gearmand-0.12 )
+		pam? ( sys-libs/pam )
+		curl? ( net-misc/curl )
+		memcache? ( >=dev-libs/libmemcached-0.39 )
+		md5? ( >=dev-libs/libgcrypt-1.4.2 )
+		>=dev-libs/boost-1.32
+		ldap? ( net-nds/openldap )
+		!dev-db/libdrizzle"
+
+DEPEND="${RDEPEND}
+		dev-util/intltool
+		dev-util/gperf
+		doc? ( app-doc/doxygen )
+		>=dev-util/boost-build-1.32"
+
+
+pkg_setup() {
+	enewuser drizzle -1 -1 /dev/null nogroup
+}
+
+src_prepare() {
+	epatch "${FILESDIR}/${PN}-2009.12.1240-nolint.patch"
+	epatch "${FILESDIR}/${PN}-2010.08.1742-pcre.patch"
+
+	AT_M4DIR="m4" eautoreconf
+	elibtoolize
+}
+
+src_configure() {
+	local myconf=
+
+	if use debug; then
+		append-flags -DDEBUG
+	fi
+
+	# while I applaud upstreams goal of 0 compiler warnings
+	# the 1412 release didn't achieve it.
+	append-flags -Wno-error
+
+	# NOTE disable-all and without-all no longer recognized options
+	# NOTE using --enable on some plugins can cause test failures.
+	# --with should be used instead. A discussion about this here:
+	# https://bugs.launchpad.net/drizzle/+bug/598659
+	# TODO (upstream)
+	# $(use_with memcache memcached-stats-plugin) \
+	# $(use_with memcache memcached-functions-plugin) \
+
+	econf \
+		--disable-static \
+		--disable-dependency-tracking \
+		--disable-mtmalloc \
+		$(use_enable tcmalloc) \
+		$(use_enable memcache libmemcached) \
+		$(use_enable gearman libgearman) \
+		$(use_enable ldap libldap) \
+		$(use_with curl auth-http-plugin) \
+		$(use_with pam auth-pam-plugin) \
+		$(use_with md5 md5-plugin) \
+		$(use_with gearman gearman-udf-plugin) \
+		$(use_with gearman logging-gearman-plugin) \
+		$(use_with ldap auth-ldap-plugin) \
+		--without-hello-world-plugin \
+		--disable-pbxt-plugin --without-pbxt-plugin \
+		--disable-rabbitmq-plugin --without-rabbitmq-plugin \
+		--without-haildb-plugin --disable-haildb-plugin \
+		--with-auth-test-plugin \
+		--with-auth-file-plugin \
+		--with-simple-user-policy-plugin \
+		--enable-logging-stats-plugin \
+		--with-logging-stats-plugin \
+		--enable-console-plugin \
+		--enable-archive-plugin \
+		${myconf}
+
+}
+
+src_compile() {
+	emake || die "build failed"
+
+	if use doc; then
+		emake doxygen || die "doxygen failed"
+	fi
+}
+
+# 5-10 min eta
+src_test() {
+	# If you want to turn off a test, rename to suffix of .DISABLED
+	# Explicitly allow parallel make check
+	emake check || die "tests failed"
+}
+
+src_install() {
+	emake DESTDIR="${D}" install || die "install failed"
+	dodoc AUTHORS NEWS README || die
+
+	find "${D}" -name '*.la' -delete || die
+
+	if use doc; then
+		docinto apidoc
+		pushd docs/html
+		dohtml -r .
+		popd
+	fi
+
+	newinitd "${FILESDIR}"/drizzle.init.d drizzled || die
+	newconfd "${FILESDIR}"/drizzle.conf.d drizzled || die
+
+	if ! use gearman; then
+		sed -i -e '/need gearmand/d' "${D}"/etc/init.d/drizzled \
+			|| die "unable to sed init script (gearman)"
+	fi
+
+	if ! use memcache; then
+		sed -i -e '/need memcached/d' "${D}"/etc/init.d/drizzled \
+			|| die "unable to sed init script (memcache)"
+	fi
+
+	keepdir /var/run/drizzle || die
+	keepdir /var/log/drizzle || die
+	keepdir /var/lib/drizzle/drizzled || die
+	keepdir /etc/drizzle || die
+
+	fperms 0755 /var/run/drizzle || die
+	fperms 0755 /var/log/drizzle || die
+	fperms -R 0700 /var/lib/drizzle || die
+
+	fowners drizzle:nogroup /var/run/drizzle || die
+	fowners drizzle:nogroup /var/log/drizzle || die
+	fowners -R drizzle:nogroup /var/lib/drizzle || die
+
+	pamd_mimic system-auth drizzle auth account session
+}