Version bump. Fixes bug 336237. Thanks to Diego for the report.

(Portage version: 2.1.9/cvs/Linux x86_64)

1 files changed, 39 insertions, 0 deletions

diff --git a/app-text/bibutils/bibutils-4.10.ebuild b/app-text/bibutils/bibutils-4.10.ebuild
new file mode 100644
index 000000000000..4bc6d3562bd3
--- /dev/null
+++ b/app-text/bibutils/bibutils-4.10.ebuild
@@ -0,0 +1,39 @@
+# Copyright 1999-2010 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/app-text/bibutils/bibutils-4.10.ebuild,v 1.1 2010/09/06 16:53:59 xarthisius Exp $
+
+EAPI=2
+inherit toolchain-funcs
+
+MY_P="${PN}_${PV}"
+DESCRIPTION="Interconverts between various bibliography formats using a common XML intermediate"
+HOMEPAGE="http://www.scripps.edu/~cdputnam/software/bibutils"
+SRC_URI="http://www.scripps.edu/~cdputnam/software/bibutils/${MY_P}_src.tgz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~x86"
+IUSE=""
+
+S=${WORKDIR}/${MY_P}
+
+src_prepare() {
+	# The custom configure script sucks, so we'll just do its
+	# job ourselves
+	rm -f Makefile configure || die "Failed to purge old Makefile"
+	sed \
+		-e "s:REPLACE_CC:CC=\"$(tc-getCC) ${CFLAGS}\":g" \
+		-e "s:REPLACE_RANLIB:RANLIB=\"$(tc-getRANLIB)\":g" \
+		-e "s:REPLACE_INSTALLDIR:\"${D}/usr/bin\":g" \
+		-e 's:REPLACE_POSTFIX::g' \
+		-e 's:make:$(MAKE):g' \
+		Makefile_start > Makefile \
+		|| die "Failed to set up Makefile"
+	sed -e '/$(CC) $^ -o $@/d' -i bin/Makefile || die #336237
+}
+
+src_install() {
+	dodir /usr/bin
+	emake install || die
+	dodoc ChangeLog || die
+}