Version bump wrt #505576 by Anton Bolshakov for iOS7 support wrt #498342 by Peter Volkov

(Portage version: 2.2.8-r1/cvs/Linux x86_64, signed Manifest commit with key 4868F14D)

2 files changed, 69 insertions, 1 deletions

diff --git a/app-pda/libimobiledevice/ChangeLog b/app-pda/libimobiledevice/ChangeLog
index fb5d53b5249f..8845aa97f154 100644
--- a/app-pda/libimobiledevice/ChangeLog
+++ b/app-pda/libimobiledevice/ChangeLog
@@ -1,6 +1,13 @@
 # ChangeLog for app-pda/libimobiledevice
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-pda/libimobiledevice/ChangeLog,v 1.50 2014/03/01 22:19:35 mgorny Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-pda/libimobiledevice/ChangeLog,v 1.51 2014/04/06 08:52:53 ssuominen Exp $
+
+*libimobiledevice-1.1.6 (06 Apr 2014)
+
+  06 Apr 2014; Samuli Suominen <ssuominen@gentoo.org>
+  +libimobiledevice-1.1.6.ebuild:
+  Version bump wrt #505576 by Anton Bolshakov for iOS7 support wrt #498342 by
+  Peter Volkov
 
   01 Mar 2014; Michał Górny <mgorny@gentoo.org>
   libimobiledevice-1.1.4-r4.ebuild, libimobiledevice-1.1.5.ebuild:
diff --git a/app-pda/libimobiledevice/libimobiledevice-1.1.6.ebuild b/app-pda/libimobiledevice/libimobiledevice-1.1.6.ebuild
new file mode 100644
index 000000000000..73bb9157bcd5
--- /dev/null
+++ b/app-pda/libimobiledevice/libimobiledevice-1.1.6.ebuild
@@ -0,0 +1,61 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/app-pda/libimobiledevice/libimobiledevice-1.1.6.ebuild,v 1.1 2014/04/06 08:52:53 ssuominen Exp $
+
+EAPI=5
+PYTHON_COMPAT=( python{2_7,3_2,3_3} )
+AUTOTOOLS_PRUNE_LIBTOOL_FILES=all
+inherit autotools-utils multilib python-r1
+
+DESCRIPTION="Support library to communicate with Apple iPhone/iPod Touch devices"
+HOMEPAGE="http://www.libimobiledevice.org/"
+SRC_URI="http://www.libimobiledevice.org/downloads/${P}.tar.bz2"
+
+# While COPYING* doesn't mention 'or any later version', all the headers do, hence use +
+LICENSE="GPL-2+ LGPL-2.1+"
+SLOT="0/4" # based on SONAME of libimobiledevice.so
+KEYWORDS="~amd64 ~arm ~ppc ~ppc64 ~x86"
+IUSE="gnutls python static-libs"
+
+RDEPEND=">=app-pda/libplist-1.11:=[python?,${PYTHON_USEDEP}]
+	>=app-pda/usbmuxd-1.0.9:=
+	gnutls? (
+		dev-libs/libgcrypt:0
+		>=dev-libs/libtasn1-1.1
+		>=net-libs/gnutls-2.2.0
+		)
+	!gnutls? ( dev-libs/openssl:0 )"
+DEPEND="${RDEPEND}
+	virtual/pkgconfig
+	python? (
+		${PYTHON_DEPS}
+		>=dev-python/cython-0.17[${PYTHON_USEDEP}]
+		)"
+
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+DOCS=( AUTHORS NEWS README )
+
+pkg_setup() {
+	# Prevent linking to the installed copy
+	if has_version "<${CATEGORY}/${P}"; then
+		rm -f "${EROOT}"/usr/$(get_libdir)/${PN}$(get_libname)
+	fi
+}
+
+src_configure() {
+	local myeconfargs=( $(use_enable static-libs static) )
+	use gnutls && myeconfargs+=( --disable-openssl )
+	use python || myeconfargs+=( --without-cython )
+
+	python_foreach_impl autotools-utils_src_configure
+}
+
+src_compile() {
+	python_foreach_impl autotools-utils_src_compile
+}
+
+src_install() {
+	python_foreach_impl autotools-utils_src_install
+	dohtml docs/html/*
+}