Version bump (thanks Christian Strahl, bug 534440).

(Portage version: 2.2.20/cvs/Linux x86_64, signed Manifest commit with key 62EEF090)

3 files changed, 182 insertions, 1 deletions

diff --git a/app-backup/backintime/ChangeLog b/app-backup/backintime/ChangeLog
index 0f20c9e1980c..bfe7d6108f0a 100644
--- a/app-backup/backintime/ChangeLog
+++ b/app-backup/backintime/ChangeLog
@@ -1,6 +1,13 @@
 # ChangeLog for app-backup/backintime
 # Copyright 1999-2015 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-backup/backintime/ChangeLog,v 1.29 2015/06/04 18:57:25 kensington Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-backup/backintime/ChangeLog,v 1.30 2015/06/08 10:27:57 xmw Exp $
+
+*backintime-1.0.40 (08 Jun 2015)
+*backintime-1.1.4 (08 Jun 2015)
+
+  08 Jun 2015; Michael Weber <xmw@gentoo.org> +backintime-1.0.40.ebuild,
+  +backintime-1.1.4.ebuild:
+  Version bump (thanks Christian Strahl, bug 534440).
 
   04 Jun 2015; Michael Palimaka <kensington@gentoo.org>
   backintime-1.0.24-r2.ebuild, backintime-1.0.36-r2.ebuild:
diff --git a/app-backup/backintime/backintime-1.0.40.ebuild b/app-backup/backintime/backintime-1.0.40.ebuild
new file mode 100644
index 000000000000..1a2a8fd87eea
--- /dev/null
+++ b/app-backup/backintime/backintime-1.0.40.ebuild
@@ -0,0 +1,98 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/app-backup/backintime/backintime-1.0.40.ebuild,v 1.1 2015/06/08 10:27:57 xmw Exp $
+
+EAPI=5
+
+PYTHON_COMPAT=( python2_7 )
+
+inherit eutils python-single-r1
+
+DESCRIPTION="A simple backup system inspired by TimeVault and FlyBack, with a GUI for GNOME and KDE4"
+HOMEPAGE="http://backintime.le-web.org/"
+SRC_URI="http://${PN}.le-web.org/download/${PN}/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="kde gnome"
+
+RDEPEND="${PYTHON_DEPS}
+	dev-python/dbus-python[${PYTHON_USEDEP}]
+	dev-python/keyring[${PYTHON_USEDEP}]
+	dev-python/notify-python[${PYTHON_USEDEP}]
+	net-misc/openssh
+	net-misc/rsync[xattr,acl]
+	kde? (
+		>=kde-base/kdelibs-4
+		kde-base/pykde4[${PYTHON_USEDEP}]
+		kde-apps/kompare:4
+		kde-apps/kdesu:4
+	)
+	gnome? (
+		gnome-base/libglade
+		dev-util/meld
+		gnome-base/gnome-session
+		dev-python/gnome-vfs-python
+		dev-python/libgnome-python
+		dev-python/pygobject:2[${PYTHON_USEDEP}]
+		dev-python/pygtk[${PYTHON_USEDEP}]
+		x11-libs/gksu
+	)"
+
+DEPEND="${RDEPEND}"
+
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+S=${WORKDIR}
+
+src_prepare() {
+	epatch "${FILESDIR}"/${PN}-1.0.24-dont-install-license.patch
+
+	#fix doc install location
+	sed -i "s:/doc/kde4/HTML/:/doc/HTML/:g" kde4/Makefile.template || die
+	sed -i "s:/doc/backintime:/doc/${PF}:g" common/Makefile.template || die
+
+	cp "${FILESDIR}"/backintime-1.0.4-kde4-root.desktop \
+		kde4/backintime-kde4-root.desktop || die
+
+	#bug 482106
+	epatch "${FILESDIR}"/${PN}-1.0.36-wrapper.patch
+	sed -e "s:^python2 :${PYTHON} :" \
+		-e "s:APP_PATH=\"/usr:APP_PATH=\"${EPREFIX}/usr:" \
+		-i kde4/backintime-kde4 gnome/backintime-gnome \
+			common/backintime || die
+
+	backintime_variants="common $(usex gnome gnome '') $(usex kde kde4 '')"
+	backintime_run() {
+		local variant
+		for variant in ${backintime_variants} ; do
+			einfo "$variant: run \"$@\""
+			pushd "${S}"/${variant} || die
+			"${@}" || die
+			popd
+		done
+	}
+
+	if [ -n ${LINGUAS+x} ] ; then
+		cd common/po || die
+		for po in *.po ; do
+			if ! has ${po/.po} ${LINGUAS} ; then
+				rm ${po} || die
+			fi
+		done
+	fi
+}
+
+src_configure() {
+	backintime_run econf
+}
+
+src_compile() {
+	backintime_run emake
+}
+
+src_install() {
+	backintime_run emake DESTDIR="${D}" install
+	python_optimize "${D}"
+}
diff --git a/app-backup/backintime/backintime-1.1.4.ebuild b/app-backup/backintime/backintime-1.1.4.ebuild
new file mode 100644
index 000000000000..3cafcceb2d36
--- /dev/null
+++ b/app-backup/backintime/backintime-1.1.4.ebuild
@@ -0,0 +1,76 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/app-backup/backintime/backintime-1.1.4.ebuild,v 1.1 2015/06/08 10:27:57 xmw Exp $
+
+EAPI=5
+
+PYTHON_COMPAT=( python3_2 python3_3 python3_4 )
+
+inherit eutils python-single-r1
+
+DESCRIPTION="A simple backup system inspired by TimeVault and FlyBack, with a GUI for GNOME and KDE4"
+HOMEPAGE="http://backintime.le-web.org/"
+SRC_URI="http://${PN}.le-web.org/download/${PN}/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="qt4"
+
+RDEPEND="${PYTHON_DEPS}
+	dev-python/dbus-python[${PYTHON_USEDEP}]
+	dev-python/keyring[${PYTHON_USEDEP}]
+	net-misc/openssh
+	net-misc/rsync[xattr,acl]"
+
+DEPEND="${RDEPEND}"
+
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+src_prepare() {
+	#fix doc install location
+	sed -e "s:/doc/${PN}-common:/doc/${PF}:g" \
+		-i common/Makefile.template || die
+	sed -e "s:/doc/${PN}-qt4:/doc/${PF}:g" \
+		-i qt4/Makefile.template || die
+	sed -e "/\/VERSION/d" -e "/\/LICENSE/d" -e "/\/copyright/d" \
+		-i {qt4,common}/Makefile.template || die
+
+	if [ -n ${LINGUAS+x} ] ; then
+		cd common/po || die
+		for po in *.po ; do
+			if ! has ${po/.po} ${LINGUAS} ; then
+				rm ${po} || die
+			fi
+		done
+	fi
+}
+
+src_configure() {
+	cd "${S}"/common || die
+	./configure --python3 --no-fuse-group || die
+	if use qt4 ; then
+		cd "${S}"/qt4 || die
+		./configure --python3 || die
+	fi
+}
+
+src_compile() {
+	cd "${S}"/common || die
+	emake
+	if use qt4 ; then
+		cd "${S}"/qt4 || die
+		emake
+	fi
+}
+
+src_install() {
+	cd "${S}"/common || die
+	emake DESTDIR="${D}" install
+	if use qt4 ; then
+		cd "${S}"/qt4 || die
+		emake DESTDIR="${D}" install
+	fi
+	
+	python_optimize "${D}"
+}