Drop unnecessary usage of autotools-utils and add support for

static-libs use flag.

(Portage version: 2.2.0_alpha171/cvs/Linux i686, signed Manifest commit with key 0x30C46538)

2 files changed, 112 insertions, 1 deletions

diff --git a/app-accessibility/speech-dispatcher/ChangeLog b/app-accessibility/speech-dispatcher/ChangeLog
index e22f479e3a9c..16fceec0aecd 100644
--- a/app-accessibility/speech-dispatcher/ChangeLog
+++ b/app-accessibility/speech-dispatcher/ChangeLog
@@ -1,6 +1,13 @@
 # ChangeLog for app-accessibility/speech-dispatcher
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-accessibility/speech-dispatcher/ChangeLog,v 1.85 2013/03/28 12:34:56 jlec Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-accessibility/speech-dispatcher/ChangeLog,v 1.86 2013/04/04 16:09:31 williamh Exp $
+
+*speech-dispatcher-0.8-r2 (04 Apr 2013)
+
+  04 Apr 2013; William Hubbs <williamh@gentoo.org>
+  +speech-dispatcher-0.8-r2.ebuild:
+  Drop unnecessary usage of autotools-utils and add support for
+  static-libs use flag, thanks to Samuli Suominen.
 
 *speech-dispatcher-0.8-r1 (28 Mar 2013)
 
diff --git a/app-accessibility/speech-dispatcher/speech-dispatcher-0.8-r2.ebuild b/app-accessibility/speech-dispatcher/speech-dispatcher-0.8-r2.ebuild
new file mode 100644
index 000000000000..2a204713f86b
--- /dev/null
+++ b/app-accessibility/speech-dispatcher/speech-dispatcher-0.8-r2.ebuild
@@ -0,0 +1,104 @@
+# Copyright 1999-2013 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/app-accessibility/speech-dispatcher/speech-dispatcher-0.8-r2.ebuild,v 1.1 2013/04/04 16:09:31 williamh Exp $
+
+EAPI=5
+
+PYTHON_COMPAT=( python3_2 )
+
+inherit eutils python-r1
+
+DESCRIPTION="Speech synthesis interface"
+HOMEPAGE="http://www.freebsoft.org/speechd"
+SRC_URI="http://www.freebsoft.org/pub/projects/speechd/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~amd64-linux ~x86-linux"
+IUSE="alsa ao +espeak flite nas pulseaudio python static-libs"
+
+RDEPEND=">=dev-libs/glib-2.28:2
+	>=media-libs/libsndfile-1.0.2
+	alsa? ( media-libs/alsa-lib )
+	ao? ( media-libs/libao )
+	espeak? ( app-accessibility/espeak )
+	flite? ( app-accessibility/flite )
+	nas? ( media-libs/nas )
+	pulseaudio? ( media-sound/pulseaudio )"
+DEPEND="${RDEPEND}
+	>=dev-libs/dotconf-1.3
+	>=dev-util/intltool-0.40.0
+	virtual/pkgconfig"
+
+src_configure() {
+	local myeconfargs=(
+		--disable-python
+		$(use_enable static-libs static)
+		$(use_with alsa)
+		$(use_with ao libao)
+		$(use_with espeak)
+		$(use_with flite)
+		$(use_with pulseaudio pulse)
+		$(use_with nas)
+	)
+	econf ${myeconfargs[@]}
+}
+
+src_compile() {
+	use python && python_copy_sources
+
+	emake
+
+	if use python; then
+		building() {
+			cd src/api/python || die
+			emake \
+				pyexecdir="$(python_get_sitedir)" \
+				pythondir="$(python_get_sitedir)"
+		}
+		python_foreach_impl run_in_build_dir building
+	fi
+}
+
+src_install() {
+	emake DESTDIR="${D}" install
+	dodoc ANNOUNCE AUTHORS BUGS ChangeLog FAQ NEWS README*
+
+	prune_libtool_files --all
+
+	if use python; then
+		installation() {
+			cd src/api/python || die
+			emake \
+				DESTDIR="${D}" \
+				pyexecdir="$(python_get_sitedir)" \
+				pythondir="$(python_get_sitedir)" \
+				install
+		}
+		python_foreach_impl run_in_build_dir installation
+		python_replicate_script "${ED}"/usr/bin/spd-conf
+	fi
+}
+
+pkg_postinst() {
+	local editconfig="n"
+	if ! use espeak; then
+		ewarn "You have disabled espeak, which is speech-dispatcher's"
+		ewarn "default speech synthesizer."
+		ewarn
+		editconfig="y"
+	fi
+	if ! use pulseaudio; then
+		ewarn "You have disabled pulseaudio support."
+		ewarn "pulseaudio is speech-dispatcher's default audio subsystem."
+		ewarn
+		editconfig="y"
+	fi
+	if [[ "${editconfig}" == "y" ]]; then
+		ewarn "You must edit ${EROOT}etc/speech-dispatcher/speechd.conf"
+		ewarn "and make sure the settings there match your system."
+		ewarn
+	fi
+	elog "For festival support, you need to"
+	elog "install app-accessibility/festival-freebsoft-utils."
+}