Version bump.

(Portage version: 2.2.0_alpha191/cvs/Linux x86_64, signed Manifest commit with key C6085806)

2 files changed, 79 insertions, 1 deletions

diff --git a/app-accessibility/orca/ChangeLog b/app-accessibility/orca/ChangeLog
index 9a7b3bf5e00e..2a3ac35be628 100644
--- a/app-accessibility/orca/ChangeLog
+++ b/app-accessibility/orca/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for app-accessibility/orca
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-accessibility/orca/ChangeLog,v 1.120 2013/06/08 23:03:14 zmedico Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-accessibility/orca/ChangeLog,v 1.121 2013/08/02 20:49:29 eva Exp $
+
+*orca-3.8.2 (02 Aug 2013)
+
+  02 Aug 2013; Gilles Dartiguelongue <eva@gentoo.org> +orca-3.8.2.ebuild:
+  Version bump.
 
   08 Jun 2013; Zac Medico <zmedico@gentoo.org> orca-3.6.3-r1.ebuild,
   orca-3.8.1.ebuild:
diff --git a/app-accessibility/orca/orca-3.8.2.ebuild b/app-accessibility/orca/orca-3.8.2.ebuild
new file mode 100644
index 000000000000..8da3e739a2de
--- /dev/null
+++ b/app-accessibility/orca/orca-3.8.2.ebuild
@@ -0,0 +1,73 @@
+# Copyright 1999-2013 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/app-accessibility/orca/orca-3.8.2.ebuild,v 1.1 2013/08/02 20:49:29 eva Exp $
+
+EAPI="5"
+GCONF_DEBUG="no"
+GNOME2_LA_PUNT="yes"
+PYTHON_COMPAT=( python3_3 )
+PYTHON_REQ_USE="threads"
+
+inherit gnome2 python-r1
+
+DESCRIPTION="Extensible screen reader that provides access to the desktop"
+HOMEPAGE="http://projects.gnome.org/orca/"
+
+LICENSE="LGPL-2.1+ CC-BY-SA-3.0"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd"
+IUSE=""
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+# liblouis is not in portage yet
+# it is used to provide contracted braille support
+# XXX: Check deps for correctness
+COMMON_DEPEND="
+	>=app-accessibility/at-spi2-atk-2.5.91:2
+	>=app-accessibility/at-spi2-core-2.5.91:2
+	>=dev-libs/atk-2.5.91
+	>=dev-libs/glib-2.28:2
+	>=dev-python/pygobject-3.2.2:3[${PYTHON_USEDEP}]
+	>=x11-libs/gtk+-3.5.16:3[introspection]
+	${PYTHON_DEPS}
+"
+RDEPEND="${COMMON_DEPEND}
+	>=app-accessibility/speech-dispatcher-0.8[python,${PYTHON_USEDEP}]
+	dev-libs/atk[introspection]
+	dev-python/pyatspi[${PYTHON_USEDEP}]
+	dev-python/pycairo[${PYTHON_USEDEP}]
+	dev-python/setproctitle[${PYTHON_USEDEP}]
+	x11-libs/libwnck:3[introspection]
+	x11-libs/pango[introspection]
+"
+DEPEND="${COMMON_DEPEND}
+	app-text/yelp-tools
+	>=dev-util/intltool-0.40
+	virtual/pkgconfig
+"
+
+src_prepare() {
+	gnome2_src_prepare
+
+	python_copy_sources
+}
+
+src_configure() {
+	python_foreach_impl run_in_build_dir gnome2_src_configure
+}
+
+src_compile() {
+	python_foreach_impl run_in_build_dir gnome2_src_compile
+}
+
+src_install() {
+	DOCS="AUTHORS ChangeLog MAINTAINERS NEWS README TODO"
+	installing() {
+		gnome2_src_install
+		# Massage shebang to make python_doscript happy
+		sed -e 's:#!'"${PYTHON}:#!/usr/bin/python:" \
+			-i src/orca/orca || die
+		python_doscript src/orca/orca
+	}
+	python_foreach_impl run_in_build_dir installing
+}
\ No newline at end of file