Bump for gnome-3.6; update to EAPI5 and python-r1.eclass. Drop old.

(Portage version: 2.2.0_alpha148/cvs/Linux x86_64, signed Manifest commit with key CF0ADD61)

3 files changed, 79 insertions, 64 deletions

diff --git a/app-accessibility/accerciser/ChangeLog b/app-accessibility/accerciser/ChangeLog
index 3da7f524d90a..4c8bd6d2c3ff 100644
--- a/app-accessibility/accerciser/ChangeLog
+++ b/app-accessibility/accerciser/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for app-accessibility/accerciser
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-accessibility/accerciser/ChangeLog,v 1.27 2012/05/20 08:41:00 tetromino Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-accessibility/accerciser/ChangeLog,v 1.28 2012/12/16 07:21:16 tetromino Exp $
+
+*accerciser-3.6.2-r1 (16 Dec 2012)
+
+  16 Dec 2012; Alexandre Rostovtsev <tetromino@gentoo.org>
+  -accerciser-3.2.1.ebuild, +accerciser-3.6.2-r1.ebuild:
+  Bump for gnome-3.6; update to EAPI5 and python-r1.eclass. Drop old.
 
 *accerciser-3.4.1 (20 May 2012)
 
diff --git a/app-accessibility/accerciser/accerciser-3.2.1.ebuild b/app-accessibility/accerciser/accerciser-3.2.1.ebuild
deleted file mode 100644
index 9da87110e37d..000000000000
--- a/app-accessibility/accerciser/accerciser-3.2.1.ebuild
+++ /dev/null
@@ -1,63 +0,0 @@
-# Copyright 1999-2012 Gentoo Foundation
-# Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/app-accessibility/accerciser/accerciser-3.2.1.ebuild,v 1.4 2012/02/10 04:04:50 patrick Exp $
-
-EAPI="4"
-GCONF_DEBUG="no"
-PYTHON_DEPEND="2:2.5"
-PYTHON_USE_WITH="xml"
-
-inherit gnome2 python
-
-DESCRIPTION="Interactive Python accessibility explorer"
-HOMEPAGE="http://live.gnome.org/Accerciser"
-
-LICENSE="BSD"
-SLOT="0"
-KEYWORDS="~amd64 ~x86"
-IUSE=""
-
-RDEPEND=">=app-accessibility/at-spi2-core-2.1.5:2
-	>=dev-python/pygobject-2.90.3:3
-	>=x11-libs/gtk+-3.1.13:3[introspection]
-
-	dev-libs/atk[introspection]
-	>=dev-libs/glib-2.28:2
-	dev-libs/gobject-introspection
-	dev-python/ipython
-	>=dev-python/pyatspi-2.1.5
-	dev-python/pycairo
-	x11-libs/gdk-pixbuf[introspection]
-	x11-libs/libwnck:3[introspection]
-	x11-libs/pango[introspection]"
-DEPEND="${RDEPEND}
-	sys-devel/gettext
-	>=dev-util/intltool-0.35
-	app-text/scrollkeeper
-	>=app-text/gnome-doc-utils-0.17.3"
-
-pkg_setup() {
-	DOCS="AUTHORS ChangeLog NEWS README"
-	python_set_active_version 2
-	python_pkg_setup
-}
-
-src_prepare() {
-	gnome2_src_prepare
-
-	# disable pyc compiling
-	echo '#!/bin/sh' > py-compile
-
-	python_convert_shebangs -r 2 .
-}
-
-pkg_postinst() {
-	gnome2_pkg_postinst
-	python_need_rebuild
-	python_mod_optimize "${PN}" /usr/share/${PN}
-}
-
-pkg_postrm() {
-	gnome2_pkg_postrm
-	python_mod_cleanup "${PN}" /usr/share/${PN}
-}
diff --git a/app-accessibility/accerciser/accerciser-3.6.2-r1.ebuild b/app-accessibility/accerciser/accerciser-3.6.2-r1.ebuild
new file mode 100644
index 000000000000..0a491fd1847b
--- /dev/null
+++ b/app-accessibility/accerciser/accerciser-3.6.2-r1.ebuild
@@ -0,0 +1,72 @@
+# Copyright 1999-2012 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/app-accessibility/accerciser/accerciser-3.6.2-r1.ebuild,v 1.1 2012/12/16 07:21:16 tetromino Exp $
+
+EAPI="5"
+GCONF_DEBUG="no"
+PYTHON_COMPAT=( python2_7 )
+PYTHON_REQ_USE="xml"
+
+inherit gnome2 python-r1
+
+DESCRIPTION="Interactive Python accessibility explorer"
+HOMEPAGE="http://live.gnome.org/Accerciser"
+
+LICENSE="BSD CCPL-Attribution-ShareAlike-3.0"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE=""
+
+RDEPEND="
+	>=app-accessibility/at-spi2-core-2.1.5:2
+	>=dev-python/pygobject-2.90.3:3[${PYTHON_USEDEP}]
+	>=x11-libs/gtk+-3.1.13:3[introspection]
+
+	dev-libs/atk[introspection]
+	>=dev-libs/glib-2.28:2
+	dev-libs/gobject-introspection
+	>=dev-python/ipython-0.11
+	>=dev-python/pyatspi-2.1.5[${PYTHON_USEDEP}]
+	dev-python/pycairo
+	x11-libs/gdk-pixbuf[introspection]
+	x11-libs/libwnck:3[introspection]
+	x11-libs/pango[introspection]
+	${PYTHON_DEPS}
+"
+DEPEND="${RDEPEND}
+	app-text/yelp-tools
+	>=dev-util/intltool-0.35
+	sys-devel/gettext
+	virtual/pkgconfig
+"
+
+src_prepare() {
+	DOCS="AUTHORS ChangeLog NEWS README"
+	G2CONF="${G2CONF} ITSTOOL=$(type -P true)"
+
+	gnome2_src_prepare
+
+	python_copy_sources
+}
+
+src_configure() {
+	python_foreach_impl run_in_build_dir gnome2_src_configure
+}
+
+src_compile() {
+	python_foreach_impl run_in_build_dir gnome2_src_compile
+}
+
+src_install() {
+	installing() {
+		gnome2_src_install
+		python_doscript src/accerciser
+	}
+	python_foreach_impl run_in_build_dir installing
+}
+
+run_in_build_dir() {
+	pushd "${BUILD_DIR}" > /dev/null || die
+	"$@"
+	popd > /dev/null
+}