sci-libs/profnet/profnet-1.0.22.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41

# Copyright 1999-2022 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=7

inherit flag-o-matic fortran-2 toolchain-funcs

DESCRIPTION="Neural network architecture for profacc"
HOMEPAGE="https://rostlab.org/"
SRC_URI="ftp://rostlab.org/profnet/${P}.tar.gz"

LICENSE="GPL-3"
SLOT="0"
KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux"

RDEPEND="sys-libs/libunwind"
DEPEND="${RDEPEND}"

src_prepare() {
	default
	sed \
		-e '/$@/s:-o:$(LDFLAGS) -o:g' \
		-i src-phd/Makefile || die
}

src_compile() {
	append-fflags $(test-flags-FC -fallow-argument-mismatch)
	emake \
		F77="$(tc-getF77)" \
		FFLAGS="${FFLAGS}"
}

src_install() {
	emake \
		DESTDIR="${D}" \
		prefix="${EPREFIX}/usr" \
		install

	# Don't install compressed man pages
	find "${ED}"/usr/share/man -type f -name '*.gz' -exec gzip -d {} \; || die
}