blob: 35619ad3a6064a2860d21b1137edb4a770eaff37 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
|
# Copyright 1999-2021 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=7
inherit flag-o-matic multilib-minimal
DESCRIPTION="Library of simple functions that are optimized for various CPUs"
HOMEPAGE="https://liboil.freedesktop.org/"
SRC_URI="https://liboil.freedesktop.org/download/${P}.tar.gz"
LICENSE="BSD-2"
SLOT="0.3"
KEYWORDS="~alpha amd64 arm ~hppa ~ia64 ~mips ppc ppc64 sparc x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~sparc-solaris ~x64-solaris ~x86-solaris"
IUSE="+examples test"
RESTRICT="!test? ( test )"
RDEPEND="examples? ( dev-libs/glib:2 )"
DEPEND="${RDEPEND}"
BDEPEND="
dev-util/gtk-doc-am
virtual/pkgconfig"
PATCHES=( "${FILESDIR}"/${P}-amd64-cpuid.patch )
src_prepare() {
has x32 $(get_all_abis) && PATCHES+=( "${FILESDIR}"/${PN}-0.3.17-x32.patch )
default
if ! use examples; then
sed "s/^\(SUBDIRS =.*\)examples\(.*\)$/\1\2/" \
-i Makefile.in || die
fi
if ! use test; then
sed "s/^\(SUBDIRS =.*\)testsuite\(.*\)$/\1\2/" \
-i Makefile.in || die
fi
}
src_configure() {
strip-flags
filter-flags -O?
append-flags -O2
# For use with Clang, which is the only compiler on OSX, bug #576646
[[ ${CHOST} == *-darwin* ]] && append-flags -fheinous-gnu-extensions
multilib_src_configure() {
ECONF_SOURCE="${S}" econf --disable-static
}
multilib-minimal_src_configure
}
multilib_src_install_all() {
einstalldocs
dodoc BUG-REPORTING HACKING
# no static archives
find "${ED}" -name '*.la' -delete || die
}
pkg_postinst() {
if ! use examples; then
ewarn "You have disabled examples USE flag. Beware that upstream might"
ewarn "want the output of some utilities that are only built with"
ewarn "USE='examples' if you report bugs to them."
fi
}
|
GitWeb
