2 files changed, 53 insertions, 0 deletions
diff --git a/dev-tex/pythontex/Manifest b/dev-tex/pythontex/Manifest
index df4fd95cc1ce..16f191082be1 100644
--- a/dev-tex/pythontex/Manifest
+++ b/dev-tex/pythontex/Manifest
@@ -1 +1,2 @@
 DIST pythontex-0.17.tar.gz 1800631 BLAKE2B 5c4ab31ccd890ca708142e83d047a46d704d2eaead611521a9f272f7a63cfb4016b991741c0338b1874d8cd2949c83b9c5ab59c3004e26540c171666a4f05e63 SHA512 ac248579f8645c225839ca9698b6193d2a7d8360a50e9a8406fae5616f54418a173635d1c2e8c47b18e85cdd1fa1e81c9435169c44f06fb19505c280f9bbaee5
+DIST pythontex-0.18.tar.gz 1807531 BLAKE2B 0f3293043780e93290fb9b3988513f919983a1a19c18344c6d5b1223dea40310581c0b5938da695485516648db3b23dbbef3eb40091f2ccd8f5a7576179043a7 SHA512 ad7dcb91d7df3eb37cdfaab870001f70976a55ca300c029ae931ade53103cbd71f7c3a4fa5d1360fdd1d9fc092f39c0427f13d2328033197057dcbc490d4ca7b
diff --git a/dev-tex/pythontex/pythontex-0.18.ebuild b/dev-tex/pythontex/pythontex-0.18.ebuild
new file mode 100644
index 000000000000..9c876cfd094a
--- /dev/null
+++ b/dev-tex/pythontex/pythontex-0.18.ebuild
@@ -0,0 +1,52 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{8..10} )
+
+inherit latex-package python-r1
+
+DESCRIPTION="Fast Access to Python from within LaTeX"
+HOMEPAGE="https://github.com/gpoore/pythontex"
+SRC_URI="https://github.com/gpoore/pythontex/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+SLOT="0"
+LICENSE="LPPL-1.3 BSD"
+KEYWORDS="~amd64 ~ppc ~riscv ~x86"
+IUSE="doc highlighting"
+
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+DEPEND="${PYTHON_DEPS}
+	>=dev-texlive/texlive-latexextra-2016
+	dev-tex/pgf
+"
+RDEPEND="${DEPEND}
+	dev-python/pygments[${PYTHON_USEDEP}]
+"
+
+TEXMF=/usr/share/texmf-site
+
+src_compile() {
+	cd ${PN} || die
+	rm ${PN}.sty || die
+	VARTEXFONTS="${T}/fonts" latex ${PN}.ins extra || die
+}
+
+src_install() {
+	dodoc *rst
+	use doc && dodoc ${PN}_quickstart/*pdf ${PN}/*pdf
+
+	cd ${PN} || die
+
+	installation() {
+		python_domodule {de,}${PN}3.py
+		python_domodule ${PN}_{engines,utils}.py
+		python_doscript {de,}${PN}.py syncpdb.py
+		python_optimize
+	}
+	python_foreach_impl installation
+
+	latex-package_src_doinstall sty
+}