2 files changed, 70 insertions, 0 deletions
diff --git a/dev-libs/libcbor/Manifest b/dev-libs/libcbor/Manifest
index 1c0df0767ddc..fcb60a3759e7 100644
--- a/dev-libs/libcbor/Manifest
+++ b/dev-libs/libcbor/Manifest
@@ -1 +1,2 @@
+DIST libcbor-0.10.1.tar.gz 284393 BLAKE2B 49b224493b4743fab0352e139ed9e85873238beb25e23555cd31f2ef720f6eb9ac136f26a92be56778f703f240dab2b6e0beddbb88c5cbf7edf084db7e96df76 SHA512 fd662d59127cd86a7e13eeb87ba0b4a9280f367b77fe85f579e5c230503ad39a323a8b9dfb8c6a49f8a05d5b81460ca4526dc130c7e1d403fd0839c0f37f5548
 DIST libcbor-0.9.0.tar.gz 275405 BLAKE2B 7e78722650c702552dda4844615c454989281abe8c45ba3c9168af16e9d440a1b7e4e0c9afd89faa48e74ba85dcbe0c7733eec3e44fdafc0ca340e97574fe274 SHA512 710239f69d770212a82e933e59df1aba0fb3ec516ef6666a366f30a950565a52981b0d46ca7e0eea739f5785d79cc21fc19acd857a4a0b135f4f6aa3ef5fd3b0
diff --git a/dev-libs/libcbor/libcbor-0.10.1.ebuild b/dev-libs/libcbor/libcbor-0.10.1.ebuild
new file mode 100644
index 000000000000..eaf307fe3736
--- /dev/null
+++ b/dev-libs/libcbor/libcbor-0.10.1.ebuild
@@ -0,0 +1,69 @@
+# Copyright 2020-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{8..11} )
+inherit python-any-r1 cmake
+
+DESCRIPTION="CBOR protocol implementation for C and others"
+HOMEPAGE="https://github.com/pjk/libcbor"
+SRC_URI="https://github.com/PJK/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0/$(ver_cut 1-2)"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+IUSE="+custom-alloc doc test"
+
+BDEPEND="
+	doc? (
+		$(python_gen_any_dep '
+			dev-python/sphinx[${PYTHON_USEDEP}]
+			dev-python/sphinx_rtd_theme[${PYTHON_USEDEP}]
+			dev-python/breathe[${PYTHON_USEDEP}]
+		')
+	)
+	test? ( dev-util/cmocka )
+"
+
+RESTRICT="!test? ( test )"
+
+python_check_deps() {
+	python_has_version \
+		"dev-python/sphinx[${PYTHON_USEDEP}]" \
+		"dev-python/sphinx_rtd_theme[${PYTHON_USEDEP}]" \
+		"dev-python/breathe[${PYTHON_USEDEP}]"
+}
+
+pkg_setup() {
+	use doc && python-any-r1_pkg_setup
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DCMAKE_BUILD_TYPE=Release
+		-DCBOR_CUSTOM_ALLOC=$(usex custom-alloc 'ON' 'OFF')
+		-DWITH_TESTS=$(usex test 'ON' 'OFF')
+	)
+
+	cmake_src_configure
+}
+
+src_compile() {
+	cmake_src_compile
+
+	if use doc; then
+		pushd doc >/dev/null || die
+		emake html man
+		popd >/dev/null || die
+	fi
+}
+
+src_install() {
+	cmake_src_install
+
+	if use doc; then
+		dodoc -r doc/build/html
+		doman doc/build/man/*
+	fi
+}