2 files changed, 59 insertions, 0 deletions
diff --git a/app-containers/containers-storage/Manifest b/app-containers/containers-storage/Manifest
index c530dfe9b542..014d6c57d5df 100644
--- a/app-containers/containers-storage/Manifest
+++ b/app-containers/containers-storage/Manifest
@@ -1 +1,2 @@
 DIST containers-storage-1.37.0.tar.gz 3557198 BLAKE2B ebe5c8e562149a9d007ac87d7fc615d29ad7decbfd6b1b8d919b14684a6341575d8f65080a808ba52674664d187a18bb47e88f10e1a02a2975898862873dadf9 SHA512 3a65a50946e1eed1c79ea77b65feb1c6c8cf58a0b7b81932acb8891b6daa25e007582eb7f70ef7e7f2a6d8262be5db7757ead2fe079e47c99114b47917d81084
+DIST containers-storage-1.38.0.tar.gz 3656468 BLAKE2B b33342dd6c55d69c3c71ce17ceeb4fd4c442291b700a9a601f9b273337bda70b9f353adbac55019d3ab0a20a8b142816255af106b77127f371ee0f80fbea488b SHA512 c9be760d088ac2bf1fa7ee7b6742c9f0f54b4878ae85059bbdb059b48eb5a2cf2c217b774944b23ff175d7126351d324ed96febb77c7a6b78b6cffb51f271f13
diff --git a/app-containers/containers-storage/containers-storage-1.38.0.ebuild b/app-containers/containers-storage/containers-storage-1.38.0.ebuild
new file mode 100644
index 000000000000..c01863fdb218
--- /dev/null
+++ b/app-containers/containers-storage/containers-storage-1.38.0.ebuild
@@ -0,0 +1,58 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit go-module
+
+KEYWORDS="~amd64"
+DESCRIPTION="containers/storage library"
+HOMEPAGE="https://github.com/containers/storage"
+LICENSE="Apache-2.0 BSD BSD-2 CC-BY-SA-4.0 ISC MIT"
+SLOT="0"
+IUSE="btrfs +device-mapper test"
+SRC_URI="https://github.com/containers/storage/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+RDEPEND="
+	btrfs? ( sys-fs/btrfs-progs )
+	device-mapper? ( sys-fs/lvm2:= )"
+DEPEND="${RDEPEND}
+	dev-go/go-md2man
+	test? (
+		sys-fs/btrfs-progs
+		sys-fs/lvm2
+		sys-apps/util-linux
+	)"
+RESTRICT="test"
+
+S=${WORKDIR}/${P#containers-}
+
+src_prepare() {
+	default
+
+	sed -e 's|: install\.tools|:|' -i Makefile || die
+
+	[[ -f hack/btrfs_tag.sh ]] || die
+	use btrfs || { echo -e "#!/bin/sh\necho exclude_graphdriver_btrfs" > \
+		"hack/btrfs_tag.sh" || die; }
+
+	[[ -f hack/libdm_tag.sh ]] || die
+	use device-mapper || { echo -e "#!/bin/sh\necho btrfs_noversion exclude_graphdriver_devicemapper" > \
+		"hack/libdm_tag.sh" || die; }
+}
+
+src_compile() {
+	export -n GOCACHE GOPATH XDG_CACHE_HOME #678856
+	emake GOMD2MAN=go-md2man FFJSON= containers-storage docs
+}
+
+src_install() {
+	dobin "${PN}"
+	while read -r -d ''; do
+		mv "${REPLY}" "${REPLY%.1}" || die
+	done < <(find "${S}/docs" -name '*.[[:digit:]].1' -print0)
+	find "${S}/docs" -name '*.[[:digit:]]' -exec doman '{}' + || die
+}
+
+src_test() {
+	env -u GOFLAGS unshare -m emake local-test-unit || die
+}