www-client/opera: Version 68.0.3618.173

Package-Manager: Portage-2.3.101, Repoman-2.3.22
Signed-off-by: Jeroen Roovers <jer@gentoo.org>

2 files changed, 111 insertions, 0 deletions

diff --git a/www-client/opera/Manifest b/www-client/opera/Manifest
index 356ec15ea307..714471e3f563 100644
--- a/www-client/opera/Manifest
+++ b/www-client/opera/Manifest
@@ -1 +1,2 @@
 DIST opera-stable_68.0.3618.165_amd64.deb 67448160 BLAKE2B 8f0c70011898ccbbbf9badbf8ba2c792d6f6150af073e033bb2131e21cf3237d85d9c7ca7ebee0adaae7a587957be8d9cfc82cacfe9cc188e42c75574f2199c4 SHA512 7d62438f42df88593be51b60625045ef1b398ade01ee33cdefa780d96505e2b469609b684741f3f0884dce7068faeb38fb6887cb89a580e113bea528734620dc
+DIST opera-stable_68.0.3618.173_amd64.deb 67459012 BLAKE2B fcb37a6491f0174710a8bd22351ec01431b292039d2671cc91243cee406d0171d05ff1e9296746bc484507163c7d167deeb2852783a62464421b2c9714668924 SHA512 149f666465b13f3fd776c4889339e19face710101b134d69b8ab30c370f155692d0ee85593127dc3e72236b7956fc5dce4971afa1a65d9c9e8f5e5c73931906f
diff --git a/www-client/opera/opera-68.0.3618.173.ebuild b/www-client/opera/opera-68.0.3618.173.ebuild
new file mode 100644
index 000000000000..58c0be89c0ab
--- /dev/null
+++ b/www-client/opera/opera-68.0.3618.173.ebuild
@@ -0,0 +1,110 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+CHROMIUM_LANGS="
+	be bg bn ca cs da de el en-GB en-US es-419 es fil fi fr-CA fr hi hr hu id
+	it ja ko lt lv ms nb nl pl pt-BR pt-PT ro ru sk sr sv sw ta te th tr uk vi
+	zh-CN zh-TW
+
+"
+inherit chromium-2 multilib unpacker xdg-utils
+
+DESCRIPTION="A fast and secure web browser"
+HOMEPAGE="https://www.opera.com/"
+LICENSE="OPERA-2014"
+SLOT="0"
+SRC_URI_BASE="
+	https://download1.operacdn.com/pub/
+	https://download2.operacdn.com/pub/
+	https://download3.operacdn.com/pub/
+	https://download4.operacdn.com/pub/
+"
+for uri in ${SRC_URI_BASE}; do
+SRC_URI+="
+	"${uri}${PN}/desktop/${PV}/linux/${PN}-stable_${PV}_amd64.deb"
+"
+done
+KEYWORDS="~amd64"
+
+RDEPEND="
+	dev-libs/expat
+	dev-libs/glib:2
+	dev-libs/nspr
+	dev-libs/nss
+	media-libs/alsa-lib
+	media-libs/fontconfig
+	media-libs/freetype
+	net-misc/curl
+	net-print/cups
+	sys-apps/dbus
+	x11-libs/cairo
+	x11-libs/gdk-pixbuf
+	x11-libs/gtk+:3
+	x11-libs/libX11
+	x11-libs/libXScrnSaver
+	x11-libs/libXcomposite
+	x11-libs/libXcursor
+	x11-libs/libXdamage
+	x11-libs/libXext
+	x11-libs/libXfixes
+	x11-libs/libXi
+	x11-libs/libXrandr
+	x11-libs/libXrender
+	x11-libs/libXtst
+	x11-libs/libnotify
+	x11-libs/pango[X]
+"
+
+QA_PREBUILT="*"
+S=${WORKDIR}
+
+src_unpack() {
+	unpack_deb ${A}
+}
+
+src_prepare() {
+	default
+
+	OPERA_HOME="usr/$(get_libdir)/${PN}"
+
+	case ${ARCH} in
+		amd64)
+			mv usr/lib/x86_64-linux-gnu usr/$(get_libdir) || die
+			rm -r usr/lib || die
+			;;
+	esac
+
+	rm usr/bin/${PN} || die
+
+	rm usr/share/doc/${PN}-stable/copyright || die
+	mv usr/share/doc/${PN}-stable usr/share/doc/${PF} || die
+	gunzip usr/share/doc/${PF}/changelog.gz || die
+
+	pushd "${OPERA_HOME}"/localization > /dev/null || die
+	chromium_remove_language_paks
+	popd > /dev/null || die
+
+	sed -i \
+		-e 's|^TargetEnvironment|X-&|g' \
+		usr/share/applications/${PN}.desktop || die
+}
+
+src_install() {
+	rm "${OPERA_HOME}"/${PN}_autoupdate || die
+	mv * "${D}" || die
+	dosym ../$(get_libdir)/${PN}/${PN} /usr/bin/${PN}
+	fperms 4711 /"${OPERA_HOME}"/opera_sandbox
+}
+
+pkg_postrm() {
+	xdg_desktop_database_update
+	xdg_icon_cache_update
+	xdg_mimeinfo_database_update
+}
+
+pkg_postinst() {
+	xdg_desktop_database_update
+	xdg_icon_cache_update
+	xdg_mimeinfo_database_update
+}