www-apps/jellyfin: add 10.8.3

Signed-off-by: Craig Andrews <candrews@gentoo.org>

2 files changed, 59 insertions, 0 deletions

diff --git a/www-apps/jellyfin/Manifest b/www-apps/jellyfin/Manifest
index 6a6ad79f795f..cc3807d0cb67 100644
--- a/www-apps/jellyfin/Manifest
+++ b/www-apps/jellyfin/Manifest
@@ -1,2 +1,4 @@
 DIST jellyfin_10.8.1_amd64.tar.gz 99055788 BLAKE2B 1e4be154cfa4982e4f2a9f33b17e23dae3ed888b49c993a0f9dded2267904e41195c0dd0d9b2a47ac8bc10d7d4f45a52141d922e8a1b3348e29cba7e60a9d64c SHA512 ac755137c1859b7b322ff2369d92ebe98757a53c58fa49b9fd178a0b703d829d6c254f4e94a27a7b36b44b92e8b003d86a97cf55e620cd58008f89775f7e4cb4
 DIST jellyfin_10.8.1_arm64.tar.gz 95977557 BLAKE2B ecaee96df0e8f01cb31b08b7e3c55d4d906e9dbdada28353ea6653d1f365fa41d68ccc87e26b528d6b25c60b9ae3fc1a31823f7b6f661d12609c7e01bac8eff7 SHA512 4ed2748d5efd9fc18a2a4a0c4da24c24e33eb7962441c2864117d31ac1a952639dcc7968f3ff492015f7f1d9d054e93716f745527ca48778f6fdf91cef79e95f
+DIST jellyfin_10.8.3_amd64.tar.gz 99057856 BLAKE2B 5ec1a2ddeedeb7ef0f6c275501ff17e5e11e2c22b66b6a5fc6c07c3ed5d59ef9c9f43e5b6b235a2ec3185bc6c6a31d2378d34c309705c27125088079fdf82486 SHA512 c09cc8ccce37bea3795243f7481f3cd4585285137c7cc170cf44e5ab1a9b6481115e43dbd5db839236ff02265c35c79fff7a0ea5580039e75a7f6b5f8c5aa921
+DIST jellyfin_10.8.3_arm64.tar.gz 62111744 BLAKE2B b5affe419caf8ce5bce6939926296d9c5d06c45a8e8bacf6a6315adc2549ba921659a8b1c11c0bb3d0b034db97d8b4d943c0690489ce6b28d41debe92a13d1d8 SHA512 3923829902363fb48a056b451ac143e5380b1ae5c74a88e3b40a430e019e299bab1f9fb9e86ae9eb5a72f8deb9d0c7c6f4d16610b249ef66c501b02fc3c16416
diff --git a/www-apps/jellyfin/jellyfin-10.8.3.ebuild b/www-apps/jellyfin/jellyfin-10.8.3.ebuild
new file mode 100644
index 000000000000..dd242eb3b144
--- /dev/null
+++ b/www-apps/jellyfin/jellyfin-10.8.3.ebuild
@@ -0,0 +1,57 @@
+# Copyright 2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit systemd
+
+DESCRIPTION="Jellyfin puts you in control of managing and streaming your media"
+HOMEPAGE="https://jellyfin.readthedocs.io/en/latest/"
+
+SRC_URI="
+	arm64? (
+		https://repo.jellyfin.org/releases/server/linux/versions/stable/combined/${PV}/${PN}_${PV}_arm64.tar.gz
+		https://repo.jellyfin.org/archive/linux/stable/${PV}/combined/${PN}_${PV}_arm64.tar.gz
+	)
+	amd64? (
+		https://repo.jellyfin.org/releases/server/linux/versions/stable/combined/${PV}/${PN}_${PV}_amd64.tar.gz
+		https://repo.jellyfin.org/archive/linux/stable/${PV}/combined/${PN}_${PV}_amd64.tar.gz
+	)"
+
+RESTRICT="mirror test"
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64"
+DEPEND="acct-user/jellyfin"
+RDEPEND="${DEPEND}
+	media-video/ffmpeg[vpx,x264]"
+BDEPEND="acct-user/jellyfin"
+INST_DIR="/opt/${PN}"
+QA_PREBUILT="${INST_DIR#/}/*.so ${INST_DIR#/}/jellyfin ${INST_DIR#/}/createdump"
+
+src_unpack() {
+	unpack ${A}
+	mv ${PN}_${PV} ${P} || die
+}
+
+src_prepare() {
+	default
+
+	# https://github.com/jellyfin/jellyfin/issues/7471
+	# https://github.com/dotnet/runtime/issues/57784
+	rm libcoreclrtraceptprovider.so || die
+}
+
+src_install() {
+	keepdir /var/log/jellyfin
+	fowners jellyfin:jellyfin /var/log/jellyfin
+	keepdir /etc/jellyfin
+	fowners jellyfin:jellyfin /etc/jellyfin
+	insinto ${INST_DIR}
+	dodir ${INST_DIR}
+	doins -r "${S}"/*
+	chmod 755 "${D}${INST_DIR}/jellyfin"
+	newinitd "${FILESDIR}/${PN}.init-r1" "${PN}"
+	newconfd "${FILESDIR}"/${PN}.confd "${PN}"
+	systemd_dounit "${FILESDIR}/${PN}.service"
+}