sys-libs/openipmi: add 2.0.32, tidy up a little bit

Signed-off-by: Sam James <sam@gentoo.org>

3 files changed, 107 insertions, 5 deletions

diff --git a/sys-libs/openipmi/Manifest b/sys-libs/openipmi/Manifest
index 027683c7970a..7c7f6311fa00 100644
--- a/sys-libs/openipmi/Manifest
+++ b/sys-libs/openipmi/Manifest
@@ -1,2 +1,3 @@
 DIST OpenIPMI-2.0.29.tar.gz 3119530 BLAKE2B 5c60b04e828699c396cb7ce29dca7665109d7b39c3d64535fafdca328c01eab0af9cc4d7fd1a30aa254836f6ce10a16e491fb7239777dc4d57edc65c20998504 SHA512 ff23aadfe4b9002574d1f06dda3d61f7a03ef1df2c61855516b7d67bd6d3272c53af74e3412e1045242dcb845f50b7c542083e918805c0efac424dd86e720a10
 DIST OpenIPMI-2.0.31.tar.gz 3129097 BLAKE2B 477d3c7abe0d04b3aa949b36c78ca149d92f4cea379e5be22a2718367f2fb3edac4d8487dd95bdf25b54b9c8c8d8d4ba1582b7bc65e416a8f1745b2790f405d7 SHA512 de1b364315e97daffb4c601bcf3bf33591795449d71690496ae368bd0730a117c1716508ecaddef5d55498f56e73481a32f509791185e80e2475667d7abd73e7
+DIST OpenIPMI-2.0.32.tar.gz 3140147 BLAKE2B 7f5d3f9e4a5a8388413d1cfb7d1b8bb1a46abce8404b408d4e505bb389e6f871b6f6d67560bcba9a5716dfcf95c5d3c27bbaf4a5fd7b924a629aa4546efde0c1 SHA512 e409f32e6bbf26756338ada386fa394d48d734b4d6ba4beca700ce60bc3af3d0f41e972a328c4e076ae014f4fbd8598d05d3f879f9c6d76198e6ae1a2ba03e95
diff --git a/sys-libs/openipmi/openipmi-2.0.31.ebuild b/sys-libs/openipmi/openipmi-2.0.31.ebuild
index c0f0d7d5c089..c8b61d3259f7 100644
--- a/sys-libs/openipmi/openipmi-2.0.31.ebuild
+++ b/sys-libs/openipmi/openipmi-2.0.31.ebuild
@@ -3,22 +3,22 @@
 
 EAPI=7
 
-PYTHON_COMPAT=( python3_{7..9} )
+PYTHON_COMPAT=( python3_{8..10} )
 
 inherit autotools python-single-r1
 
-DESCRIPTION="Library interface to IPMI"
-HOMEPAGE="https://sourceforge.net/projects/openipmi/"
 MY_PN="OpenIPMI"
 MY_P="${MY_PN}-${PV/_/-}"
+DESCRIPTION="Library interface to IPMI"
+HOMEPAGE="https://sourceforge.net/projects/openipmi/"
 SRC_URI="mirror://sourceforge/${PN}/${MY_P}.tar.gz"
+S="${WORKDIR}/${MY_P}"
 
 LICENSE="LGPL-2.1 GPL-2"
 SLOT="0"
 KEYWORDS="~amd64 ~arm64 ~hppa ~ia64 ~ppc ~ppc64 ~x86"
 IUSE="crypt snmp perl python static-libs tcl"
-S="${WORKDIR}/${MY_P}"
-RESTRICT='test'
+RESTRICT="test"
 
 RDEPEND="
 	dev-libs/glib:2
diff --git a/sys-libs/openipmi/openipmi-2.0.32.ebuild b/sys-libs/openipmi/openipmi-2.0.32.ebuild
new file mode 100644
index 000000000000..c8b61d3259f7
--- /dev/null
+++ b/sys-libs/openipmi/openipmi-2.0.32.ebuild
@@ -0,0 +1,101 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{8..10} )
+
+inherit autotools python-single-r1
+
+MY_PN="OpenIPMI"
+MY_P="${MY_PN}-${PV/_/-}"
+DESCRIPTION="Library interface to IPMI"
+HOMEPAGE="https://sourceforge.net/projects/openipmi/"
+SRC_URI="mirror://sourceforge/${PN}/${MY_P}.tar.gz"
+S="${WORKDIR}/${MY_P}"
+
+LICENSE="LGPL-2.1 GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~hppa ~ia64 ~ppc ~ppc64 ~x86"
+IUSE="crypt snmp perl python static-libs tcl"
+RESTRICT="test"
+
+RDEPEND="
+	dev-libs/glib:2
+	sys-libs/gdbm:=
+	sys-libs/ncurses:0=
+	sys-libs/readline:0=
+	crypt? ( dev-libs/openssl:0= )
+	snmp? ( net-analyzer/net-snmp )
+	perl? ( dev-lang/perl:= )
+	python? ( ${PYTHON_DEPS} )
+	tcl? ( dev-lang/tcl:0= )"
+DEPEND="${RDEPEND}
+	>=dev-lang/swig-1.3.21"
+BDEPEND="virtual/pkgconfig"
+
+# Gui is broken!
+#		python? ( tcl? ( tk? ( dev-lang/tk dev-tcltk/tix ) ) )"
+
+REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"
+
+PATCHES=(
+	"${FILESDIR}/${PN}-2.0.26-tinfo.patch" #501510
+)
+
+pkg_setup() {
+	use python && python-single-r1_pkg_setup
+}
+
+src_prepare() {
+	default
+
+	# Bug #298250: parallel install fix.
+	sed -r -i \
+		-e '/^install-data-local:/s,$, install-exec-am,g' \
+		cmdlang/Makefile.{am,in} || die
+
+	# We touch the .in and .am above because if we use the below, the Perl stuff
+	# is very fragile, and often fails to link.
+	eautoreconf
+}
+
+src_configure() {
+	local myconf=(
+		# these binaries are for root!
+		--bindir="${EPREFIX}"/usr/sbin
+		--with-glib
+		--with-glibver=2.0
+		--with-swig
+		--without-tkinter
+		$(use_with snmp ucdsnmp yes)
+		$(use_with crypt openssl yes)
+		$(use_with perl perl yes)
+		$(use_with tcl tcl yes)
+		$(use_with python python yes)
+	)
+
+	# GUI is broken
+	#use tk && use python && use !tcl && \
+	#	ewarn "Not building Tk GUI because it needs both Python AND Tcl"
+	#if use python && use tcl; then
+	#	myconf+=( $(use_with tk tkinter) )
+	#else
+	#	myconf+=( --without-tkinter )
+	#fi
+
+	econf "${myconf[@]}"
+}
+
+src_install() {
+	emake DESTDIR="${D}" install
+	dodoc README* FAQ ChangeLog TODO doc/IPMI.pdf lanserv/README.vm
+	newdoc cmdlang/README README.cmdlang
+
+	use python && python_optimize
+
+	find "${ED}" -name "*.la" -delete || die
+	if ! use static-libs ; then
+		find "${ED}" -name "*.a" -delete || die
+	fi
+}