lxqt-base/lxqt-panel: add 2.0.1

Closes: https://bugs.gentoo.org/927907
Signed-off-by: Jimi Huotari <chiitoo@gentoo.org>

2 files changed, 118 insertions, 0 deletions

diff --git a/lxqt-base/lxqt-panel/Manifest b/lxqt-base/lxqt-panel/Manifest
index 72625eaef479..cfa1a0964a5a 100644
--- a/lxqt-base/lxqt-panel/Manifest
+++ b/lxqt-base/lxqt-panel/Manifest
@@ -1,2 +1,3 @@
 DIST lxqt-panel-1.3.0.tar.xz 610764 BLAKE2B 96d4f0368a5071badec0c7dfbcb1f5c9592723fa2ca3be81fe47e0cdccd3108451f204c6de95c154d2ca03f7554fe639afd257f72d554682fabc2bd493ab896d SHA512 1bf66db90e4fbd1ec38688b3a27c9dc5ab2e0a71ace74555580c379e9e12211ded61d01fa46484e8a600bb9b30cb3203ec38697ade0a9cb81cb2cd8043af8b97
 DIST lxqt-panel-1.4.0.tar.xz 612012 BLAKE2B 4ab12d5aa005269374044de9e2ca027ea72491f6079544bfd35fad7fd59f8e465fca4ff8e0e7274caf2bb272a8d7c6f36d34d74c27551a0ac799e112bb88ce99 SHA512 87d5c89cfc4f5253dbb4048da89a531a99f664fd424eebb535a688934bdb63856edf07276a5ccba826a4658228801ed4cc036aea6664e67c57599990d7e4b997
+DIST lxqt-panel-2.0.1.tar.xz 662616 BLAKE2B d27f99e5ba301ad1d03a8e8e4dad939c4f5ba8e7825fe0ac93d8a3b1649f21bd6614d144322b5355112f44f8b8eebf5f9ed3f8e5b4bac85d27530ba02abe0d31 SHA512 df2cef5f03f65eb20eaf58cf8dc2f390bc4daa67638e301e0df15c82b8332f842d8e1ee9f1f5bc2240a25ce4b2f404aa7aa69a415a41f5cbb17592f8c77a414e
diff --git a/lxqt-base/lxqt-panel/lxqt-panel-2.0.1.ebuild b/lxqt-base/lxqt-panel/lxqt-panel-2.0.1.ebuild
new file mode 100644
index 000000000000..07f2ef0ec331
--- /dev/null
+++ b/lxqt-base/lxqt-panel/lxqt-panel-2.0.1.ebuild
@@ -0,0 +1,117 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake
+
+DESCRIPTION="LXQt desktop panel and plugins"
+HOMEPAGE="https://lxqt-project.org/"
+
+MY_PV="$(ver_cut 1-2)"
+
+if [[ ${PV} == 9999 ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/lxqt/${PN}.git"
+else
+	SRC_URI="https://github.com/lxqt/${PN}/releases/download/${PV}/${P}.tar.xz"
+	KEYWORDS="~amd64"
+fi
+
+LICENSE="LGPL-2.1 LGPL-2.1+"
+SLOT="0"
+IUSE="
+	+alsa colorpicker cpuload +desktopswitch +directorymenu dom +kbindicator
+	+mainmenu +mount networkmonitor pulseaudio +quicklaunch lm-sensors +showdesktop
+	+spacer +statusnotifier sysstat +taskbar tray +volume +worldclock
+"
+
+# Work around a missing header issue: https://bugs.gentoo.org/666278
+REQUIRED_USE="
+	|| ( desktopswitch mainmenu showdesktop taskbar )
+	volume? ( || ( alsa pulseaudio ) )
+"
+
+BDEPEND="
+	>=dev-qt/qttools-6.6:6[linguist]
+	>=dev-util/lxqt-build-tools-2.0.0
+	virtual/pkgconfig
+"
+DEPEND="
+	>=dev-libs/libqtxdg-4.0.0
+	>=dev-qt/qtbase-6.6:6[dbus,gui,widgets,xml]
+	>=dev-qt/qtsvg-6.6:6
+	kde-frameworks/kwindowsystem:6[X]
+	kde-plasma/layer-shell-qt:6
+	>=lxde-base/menu-cache-1.1.0
+	=lxqt-base/liblxqt-${MY_PV}*:=
+	=lxqt-base/lxqt-globalkeys-${MY_PV}*
+	=lxqt-base/lxqt-menu-data-${MY_PV}*
+	x11-libs/libX11
+	cpuload? ( sys-libs/libstatgrab )
+	kbindicator? ( x11-libs/libxkbcommon )
+	lm-sensors? ( sys-apps/lm-sensors:= )
+	mount? ( kde-frameworks/solid:6 )
+	networkmonitor? ( sys-libs/libstatgrab )
+	statusnotifier? (
+		dev-libs/libdbusmenu-lxqt
+		>=dev-qt/qtbase-6.6:6[concurrent]
+	)
+	sysstat? ( >=lxqt-base/libsysstat-1.0.0 )
+	tray? (
+		x11-libs/libxcb:=
+		x11-libs/libXcomposite
+		x11-libs/libXdamage
+		x11-libs/libXrender
+		x11-libs/libXtst
+		x11-libs/xcb-util
+		x11-libs/xcb-util-image
+	)
+	volume? (
+		alsa? ( media-libs/alsa-lib )
+		pulseaudio? (
+			media-libs/libpulse
+			media-sound/pavucontrol-qt
+		)
+	)
+"
+RDEPEND="${DEPEND}"
+
+src_configure() {
+	local mycmakeargs=(
+		# Plugins
+		-DCOLORPICKER_PLUGIN=$(usex colorpicker)
+		-DCPULOAD_PLUGIN=$(usex cpuload)
+		-DDESKTOPSWITCH_PLUGIN=$(usex desktopswitch)
+		-DDIRECTORYMENU_PLUGIN=$(usex directorymenu)
+		-DDOM_PLUGIN=$(usex dom)
+		-DKBINDICATOR_PLUGIN=$(usex kbindicator)
+		-DMAINMENU_PLUGIN=$(usex mainmenu)
+		-DMOUNT_PLUGIN=$(usex mount)
+		-DNETWORKMONITOR_PLUGIN=$(usex networkmonitor)
+		-DQUICKLAUNCH_PLUGIN=$(usex quicklaunch)
+		-DSENSORS_PLUGIN=$(usex lm-sensors)
+		-DSHOWDESKTOP_PLUGIN=$(usex showdesktop)
+		-DSPACER_PLUGIN=$(usex spacer)
+		-DSTATUSNOTIFIER_PLUGIN=$(usex statusnotifier)
+		-DSYSSTAT_PLUGIN=$(usex sysstat)
+		-DTASKBAR_PLUGIN=$(usex taskbar)
+		-DTRAY_PLUGIN=$(usex tray)
+		-DVOLUME_PLUGIN=$(usex volume)
+		-DWORLDCLOCK_PLUGIN=$(usex worldclock)
+	)
+
+	if use volume; then
+		mycmakeargs+=(
+			-DVOLUME_USE_ALSA=$(usex alsa)
+			-DVOLUME_USE_PULSEAUDIO=$(usex pulseaudio)
+		)
+	fi
+
+	cmake_src_configure
+}
+
+src_install() {
+	cmake_src_install
+	doman panel/man/*.1
+}