games-util/lutris: build with meson instead of distutils

This is recommended upstream and ensures localization is installed

Closes: https://bugs.gentoo.org/913507
Signed-off-by: Andrew Ammerlaan <andrewammerlaan@gentoo.org>

2 files changed, 112 insertions, 8 deletions

diff --git a/games-util/lutris/lutris-0.5.13-r3.ebuild b/games-util/lutris/lutris-0.5.13-r3.ebuild
new file mode 100644
index 000000000000..602a81d8f9fa
--- /dev/null
+++ b/games-util/lutris/lutris-0.5.13-r3.ebuild
@@ -0,0 +1,98 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{10..11} )
+PYTHON_REQ_USE="sqlite,threads(+)"
+
+inherit meson python-single-r1 optfeature virtualx xdg
+
+DESCRIPTION="An open source gaming platform for GNU/Linux"
+HOMEPAGE="https://lutris.net/"
+
+if [[ ${PV} == *9999* ]] ; then
+	EGIT_REPO_URI="https://github.com/lutris/lutris.git"
+	inherit git-r3
+else
+	if [[ ${PV} == *_beta* ]] ; then
+		SRC_URI="https://github.com/lutris/lutris/archive/refs/tags/v${PV/_/-}.tar.gz -> ${P}.tar.gz"
+		S="${WORKDIR}"/${P/_/-}
+	else
+		SRC_URI="https://lutris.net/releases/${P/-/_}.tar.xz"
+		S="${WORKDIR}/${PN}"
+		KEYWORDS="~amd64 ~x86"
+	fi
+fi
+
+LICENSE="GPL-3+ CC0-1.0"
+SLOT="0"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+RDEPEND="
+	${PYTHON_DEPS}
+	app-arch/cabextract
+	app-arch/p7zip
+	app-arch/unzip
+	$(python_gen_cond_dep '
+		dev-python/certifi[${PYTHON_USEDEP}]
+		dev-python/dbus-python[${PYTHON_USEDEP}]
+		dev-python/distro[${PYTHON_USEDEP}]
+		dev-python/lxml[${PYTHON_USEDEP}]
+		dev-python/pillow[${PYTHON_USEDEP}]
+		dev-python/pygobject:3[cairo,${PYTHON_USEDEP}]
+		dev-python/pypresence[${PYTHON_USEDEP}]
+		dev-python/python-evdev[${PYTHON_USEDEP}]
+		dev-python/pyyaml[${PYTHON_USEDEP}]
+		dev-python/requests[${PYTHON_USEDEP}]
+		dev-python/protobuf-python[${PYTHON_USEDEP}]
+		dev-python/moddb[${PYTHON_USEDEP}]
+	')
+	media-sound/fluid-soundfont
+	|| (
+		net-libs/webkit-gtk:4[introspection]
+		net-libs/webkit-gtk:4.1[introspection]
+	)
+	sys-apps/xdg-desktop-portal
+	x11-apps/mesa-progs
+	x11-apps/xgamma
+	x11-apps/xrandr
+	x11-libs/gtk+:3[introspection]
+	x11-libs/gdk-pixbuf[jpeg]
+"
+
+BDEPEND="
+	test? (
+		$(python_gen_cond_dep '
+			dev-python/pytest[${PYTHON_USEDEP}]
+		')
+	)
+"
+
+DOCS=( AUTHORS README.rst docs/installers.rst docs/steam.rst )
+
+PATCHES=(
+	"${FILESDIR}/${P}-find-eselected-wine.patch"
+)
+
+src_test() {
+	virtx epytest
+}
+
+src_install() {
+	meson_src_install
+	python_fix_shebang "${ED}/usr/share/lutris/bin/lutris-wrapper" #740048
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+
+	optfeature "running MS Windows games through wine+DXVK/proton or other Vulkan games (plus ICD for your hardware)" "media-libs/vulkan-loader dev-util/vulkan-tools"
+
+	# Quote README.rst
+	elog ""
+	elog "Lutris installations are fully automated through scripts, which can"
+	elog "be written in either JSON or YAML. The scripting syntax is described"
+	elog "in ${EROOT}/usr/share/doc/${PF}/installers.rst.bz2, and is also"
+	elog "available online at lutris.net."
+}
diff --git a/games-util/lutris/lutris-9999.ebuild b/games-util/lutris/lutris-9999.ebuild
index 62930e73e736..175f3cb7cc7e 100644
--- a/games-util/lutris/lutris-9999.ebuild
+++ b/games-util/lutris/lutris-9999.ebuild
@@ -3,12 +3,10 @@
 
 EAPI=8
 
-PYTHON_COMPAT=( python3_{9..11} )
+PYTHON_COMPAT=( python3_{10..11} )
 PYTHON_REQ_USE="sqlite,threads(+)"
-DISTUTILS_SINGLE_IMPL=1
-DISTUTILS_USE_PEP517=setuptools
 
-inherit distutils-r1 optfeature virtualx xdg
+inherit meson python-single-r1 optfeature virtualx xdg
 
 DESCRIPTION="An open source gaming platform for GNU/Linux"
 HOMEPAGE="https://lutris.net/"
@@ -29,8 +27,10 @@ fi
 
 LICENSE="GPL-3+ CC0-1.0"
 SLOT="0"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
 
 RDEPEND="
+	${PYTHON_DEPS}
 	app-arch/cabextract
 	app-arch/p7zip
 	app-arch/unzip
@@ -61,16 +61,22 @@ RDEPEND="
 	x11-libs/gdk-pixbuf[jpeg]
 "
 
-distutils_enable_tests pytest
+BDEPEND="
+	test? (
+		$(python_gen_cond_dep '
+			dev-python/pytest[${PYTHON_USEDEP}]
+		')
+	)
+"
 
 DOCS=( AUTHORS README.rst docs/installers.rst docs/steam.rst )
 
-python_test() {
+src_test() {
 	virtx epytest
 }
 
-python_install_all() {
-	distutils-r1_python_install_all
+src_install() {
+	meson_src_install
 	python_fix_shebang "${ED}/usr/share/lutris/bin/lutris-wrapper" #740048
 }