dev-python/sphinx: add 5.2.3

Signed-off-by: Arthur Zamarin <arthurzam@gentoo.org>

2 files changed, 126 insertions, 0 deletions

diff --git a/dev-python/sphinx/Manifest b/dev-python/sphinx/Manifest
index ddd21aa5b93f..64e8422584d8 100644
--- a/dev-python/sphinx/Manifest
+++ b/dev-python/sphinx/Manifest
@@ -3,3 +3,4 @@ DIST sphinx-5.1.1.gh.tar.gz 6766329 BLAKE2B ff385abe35d4a700cbb3cd8acc72313f7c92
 DIST sphinx-5.2.0.gh.tar.gz 6777631 BLAKE2B 53514f0561a53e656f15f434f79a2e2a6c0b41989bbc98f8c7e3e0548ab180339d2908827a933124576dacbed76db7e519ee1e626597a3f50900a90cb8b1c23b SHA512 480c288cd9bf3c1bc61aa97fc4549dd6f0c3d23c2fb5cc5f15a20780984c518f50638a42a87b9c2c0b4eb24ef57e6cfbd812a82a9227ae439028a0fdd5f165a7
 DIST sphinx-5.2.1.gh.tar.gz 6777833 BLAKE2B 128c8bbeb1609eef353da88a6d7dc561839b9e60abc46325b96e668a2babc39695f65d7e9539ab8faaae7ba27f558e6ec300579f94f1a62da9ef0d9804eda893 SHA512 bb51a91f7eb9643cf30be732cd0d9d45a90a1358d8379d89ac3ec0a46dcb0724a57ec4d5062375b6a98bfbb5d688d709ca9a1ed65d7825f4402cacf01cc9e034
 DIST sphinx-5.2.2.gh.tar.gz 6777525 BLAKE2B a6b5ff51072407be6e9bc7ae4d287826b8ce391c1ed712595d99c35af6279ea5404e28c48f8694620f246001824bb7cf2b0ac18d90f859874740d54a12ff9c33 SHA512 290ccea3ddf8dd73679976064fde6130213085c352972da0db4aba1a8f2fcb2e69ed52f2bb2469661bdfd90a1bf75255075e133e08cfcc301f28116415bad080
+DIST sphinx-5.2.3.gh.tar.gz 6778166 BLAKE2B 0ba15fb7d558ee4d2d2ead5e04aa65d32dbda3b711d43723f8267dcd88ebf18711081aecdaa607e4bcac1198bd3f55409379f5f912e3a6a672508b941ed72891 SHA512 8a78beb63bdfafe4808c12e3d09adf1e222f0555171eb177f578c4434a454c0527171b1fc751e5df654c7a5f78b2b5709be5b32edaeb98f5f6ae71719efec327
diff --git a/dev-python/sphinx/sphinx-5.2.3.ebuild b/dev-python/sphinx/sphinx-5.2.3.ebuild
new file mode 100644
index 000000000000..46163127e936
--- /dev/null
+++ b/dev-python/sphinx/sphinx-5.2.3.ebuild
@@ -0,0 +1,125 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=flit
+PYTHON_COMPAT=( python3_{8..11} pypy3 )
+PYTHON_REQ_USE="threads(+)"
+
+inherit distutils-r1
+
+DESCRIPTION="Python documentation generator"
+HOMEPAGE="
+	https://www.sphinx-doc.org/
+	https://github.com/sphinx-doc/sphinx/
+	https://pypi.org/project/Sphinx/
+"
+SRC_URI="
+	https://github.com/sphinx-doc/sphinx/archive/v${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x64-solaris"
+IUSE="doc latex"
+
+RDEPEND="
+	<dev-python/alabaster-0.8[${PYTHON_USEDEP}]
+	>=dev-python/Babel-2.9[${PYTHON_USEDEP}]
+	<dev-python/docutils-0.20[${PYTHON_USEDEP}]
+	>=dev-python/imagesize-1.3[${PYTHON_USEDEP}]
+	>=dev-python/jinja-3.0[${PYTHON_USEDEP}]
+	>=dev-python/pygments-2.12[${PYTHON_USEDEP}]
+	>=dev-python/requests-2.5.0[${PYTHON_USEDEP}]
+	>=dev-python/snowballstemmer-2.0[${PYTHON_USEDEP}]
+	dev-python/sphinxcontrib-applehelp[${PYTHON_USEDEP}]
+	dev-python/sphinxcontrib-devhelp[${PYTHON_USEDEP}]
+	dev-python/sphinxcontrib-jsmath[${PYTHON_USEDEP}]
+	>=dev-python/sphinxcontrib-htmlhelp-2.0.0[${PYTHON_USEDEP}]
+	>=dev-python/sphinxcontrib-serializinghtml-1.1.5[${PYTHON_USEDEP}]
+	dev-python/sphinxcontrib-qthelp[${PYTHON_USEDEP}]
+	>=dev-python/packaging-21.0[${PYTHON_USEDEP}]
+	$(python_gen_cond_dep '
+		>=dev-python/importlib_metadata-4.8[${PYTHON_USEDEP}]
+	' 3.8 3.9)
+	latex? (
+		dev-texlive/texlive-latexextra
+		dev-texlive/texlive-luatex
+		app-text/dvipng
+	)
+	!dev-python/namespace-sphinxcontrib
+"
+BDEPEND="
+	doc? (
+		dev-python/sphinxcontrib-websupport[${PYTHON_USEDEP}]
+		media-gfx/graphviz
+	)
+	test? (
+		app-text/dvipng
+		dev-python/cython[${PYTHON_USEDEP}]
+		dev-python/html5lib[${PYTHON_USEDEP}]
+		dev-texlive/texlive-fontsextra
+		dev-texlive/texlive-latexextra
+		dev-texlive/texlive-luatex
+		virtual/imagemagick-tools[jpeg,png,svg]
+	)
+"
+
+PATCHES=(
+	"${FILESDIR}/sphinx-3.2.1-doc-link.patch"
+	"${FILESDIR}/sphinx-4.3.2-doc-link.patch"
+)
+
+distutils_enable_tests pytest
+
+python_prepare_all() {
+	# disable internet access
+	sed -i -e 's:^intersphinx_mapping:disabled_&:' \
+		doc/conf.py || die
+
+	distutils-r1_python_prepare_all
+}
+
+python_compile_all() {
+	if use doc; then
+		esetup.py build_sphinx
+		HTML_DOCS=( "${BUILD_DIR}"/sphinx/html/. )
+	fi
+}
+
+python_test() {
+	mkdir -p "${BUILD_DIR}/sphinx_tempdir" || die
+	local -x SPHINX_TEST_TEMPDIR="${BUILD_DIR}/sphinx_tempdir"
+
+	local EPYTEST_DESELECT=(
+		# these tests require Internet access
+		tests/test_build_latex.py::test_latex_images
+		tests/test_build_linkcheck.py::test_defaults
+		tests/test_build_linkcheck.py::test_defaults_json
+		tests/test_build_linkcheck.py::test_anchors_ignored
+		# TODO
+		tests/test_ext_autodoc_autoclass.py::test_classes
+		tests/test_ext_autodoc_autofunction.py::test_classes
+		tests/test_ext_inheritance_diagram.py::test_import_classes
+	)
+	[[ ${EPYTHON} == pypy3 ]] && EPYTEST_DESELECT+=(
+		tests/test_ext_autodoc.py::test_autodoc_inherited_members_None
+		tests/test_ext_autodoc.py::test_automethod_for_builtin
+		tests/test_ext_autodoc.py::test_cython
+		tests/test_ext_autodoc.py::test_partialfunction
+		tests/test_ext_autodoc_autoclass.py::test_autodoc_process_bases
+		tests/test_ext_autodoc_autoclass.py::test_show_inheritance_for_decendants_of_generic_type
+		tests/test_ext_autodoc_autoclass.py::test_show_inheritance_for_subclass_of_generic_type
+		tests/test_ext_autodoc_autofunction.py::test_builtin_function
+		tests/test_ext_autodoc_autofunction.py::test_methoddescriptor
+		tests/test_ext_autodoc_automodule.py::test_automodule_inherited_members
+		tests/test_ext_autosummary.py::test_autosummary_generate_content_for_module
+		tests/test_ext_autosummary.py::test_autosummary_generate_content_for_module_skipped
+		tests/test_util_inspect.py::test_isattributedescriptor
+		tests/test_util_typing.py::test_stringify_type_hints_pep_585
+	)
+
+	epytest
+}