dev-python/sphinx: Bump to 7.0.1

Signed-off-by: Michał Górny <mgorny@gentoo.org>

2 files changed, 132 insertions, 0 deletions

diff --git a/dev-python/sphinx/Manifest b/dev-python/sphinx/Manifest
index 255aea00c5e7..038580b6ef4a 100644
--- a/dev-python/sphinx/Manifest
+++ b/dev-python/sphinx/Manifest
@@ -4,3 +4,4 @@ DIST sphinx-6.1.3.gh.tar.gz 6720056 BLAKE2B 8d8753a7735df1d2e86dfc1c6347ea6fd550
 DIST sphinx-6.2.0.gh.tar.gz 6729874 BLAKE2B 6bfa538d01687ebc72a29ea89061362175f5807fe0aa71d5332e2a257ef562a8bf520b1f8696ceeddd5647a515a02fc4b9cb4a6ebf104f1d104f8198f8186a9b SHA512 e2c2931d4984a7a41aa7cbfc72e099b3df01646c87f16a6a7950945a6768bc0af9d49a776e164590c2e80b83127bfd2338a7d9a119d0ce6023ab4960ded741f5
 DIST sphinx-6.2.1.gh.tar.gz 6729925 BLAKE2B 621ead516dc17cc632e9e752b56b5432547b6a051ede353d690dca0769664fc1c1335ec948f4035cb8c4307a563b4928d2587de3f3ec8d89dacf829a8fd5b95f SHA512 ba56fb9672dc2e156b6cfd0fc2252a989d44b199946a371ec5f1cda5840836b3a58e267ac0973f522479b472dbb07c6c2d7ae6b0c63c9adfbe82d36bd59a9465
 DIST sphinx-7.0.0.gh.tar.gz 6712995 BLAKE2B ad60fba88a25491c4d545767edbcf2aca31c2b11181904bbcd10fea3cb27dc983add3d72e6fab9b0eb68e4fc0eb62d2e7d3f126d2fd8ca70d496921f1149d3a5 SHA512 35fb03b11b9a9f7fabe6d774b6fdb2290d80f8bfdf2b474d8adae92345e29bad0d8506c3e274a3c1e249a1690ebac3135e99ecabaac8531923d5fdbfc296e1c3
+DIST sphinx-7.0.1.gh.tar.gz 6712916 BLAKE2B 7e30804eb5c24559c8ca30e5d8943ad78b426f94c3008ec74de6a541a71a7835d4e83dd69d84df04778f6246840209847ce103863b4dd4109e01bc3a5a50fd84 SHA512 6489778c4953b2c2d9972fa3f07fdb3b361b441e2c9f47282ec9c47f70446e3df66e434690ba816cc6f98838056001d2518f9bd1235e8b07ddba3c1d03a57b76
diff --git a/dev-python/sphinx/sphinx-7.0.1.ebuild b/dev-python/sphinx/sphinx-7.0.1.ebuild
new file mode 100644
index 000000000000..5b23550bab3d
--- /dev/null
+++ b/dev-python/sphinx/sphinx-7.0.1.ebuild
@@ -0,0 +1,131 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=flit
+PYTHON_COMPAT=( python3_{9..11} pypy3 )
+PYTHON_REQ_USE="threads(+)"
+
+inherit distutils-r1
+
+DESCRIPTION="Python documentation generator"
+HOMEPAGE="
+	https://www.sphinx-doc.org/
+	https://github.com/sphinx-doc/sphinx/
+	https://pypi.org/project/Sphinx/
+"
+SRC_URI="
+	https://github.com/sphinx-doc/sphinx/archive/v${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="BSD-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x64-solaris"
+IUSE="doc latex"
+
+RDEPEND="
+	<dev-python/alabaster-0.8[${PYTHON_USEDEP}]
+	>=dev-python/Babel-2.9[${PYTHON_USEDEP}]
+	<dev-python/docutils-0.21[${PYTHON_USEDEP}]
+	>=dev-python/docutils-0.18.1[${PYTHON_USEDEP}]
+	>=dev-python/imagesize-1.3[${PYTHON_USEDEP}]
+	>=dev-python/jinja-3.0[${PYTHON_USEDEP}]
+	>=dev-python/pygments-2.13[${PYTHON_USEDEP}]
+	>=dev-python/requests-2.25.0[${PYTHON_USEDEP}]
+	>=dev-python/snowballstemmer-2.0[${PYTHON_USEDEP}]
+	dev-python/sphinxcontrib-applehelp[${PYTHON_USEDEP}]
+	dev-python/sphinxcontrib-devhelp[${PYTHON_USEDEP}]
+	dev-python/sphinxcontrib-jsmath[${PYTHON_USEDEP}]
+	>=dev-python/sphinxcontrib-htmlhelp-2.0.0[${PYTHON_USEDEP}]
+	>=dev-python/sphinxcontrib-serializinghtml-1.1.5[${PYTHON_USEDEP}]
+	dev-python/sphinxcontrib-qthelp[${PYTHON_USEDEP}]
+	>=dev-python/packaging-21.0[${PYTHON_USEDEP}]
+	$(python_gen_cond_dep '
+		>=dev-python/importlib-metadata-4.8[${PYTHON_USEDEP}]
+	' 3.8 3.9)
+	latex? (
+		dev-texlive/texlive-latexextra
+		dev-texlive/texlive-luatex
+		app-text/dvipng
+	)
+	!dev-python/namespace-sphinxcontrib
+"
+BDEPEND="
+	doc? (
+		dev-python/sphinxcontrib-websupport[${PYTHON_USEDEP}]
+		media-gfx/graphviz
+	)
+	test? (
+		app-text/dvipng
+		dev-python/cython[${PYTHON_USEDEP}]
+		dev-python/filelock[${PYTHON_USEDEP}]
+		dev-python/html5lib[${PYTHON_USEDEP}]
+		dev-texlive/texlive-fontsextra
+		dev-texlive/texlive-latexextra
+		dev-texlive/texlive-luatex
+		virtual/imagemagick-tools[jpeg,png,svg]
+	)
+"
+
+PATCHES=(
+	"${FILESDIR}/sphinx-3.2.1-doc-link.patch"
+	"${FILESDIR}/sphinx-4.3.2-doc-link.patch"
+)
+
+distutils_enable_tests pytest
+
+python_prepare_all() {
+	# disable internet access
+	sed -i -e 's:^intersphinx_mapping:disabled_&:' \
+		doc/conf.py || die
+
+	distutils-r1_python_prepare_all
+}
+
+python_compile_all() {
+	# we can't use distutils_enable_sphinx because it would
+	# introduce a dep on itself
+	use doc && build_sphinx doc
+}
+
+python_test() {
+	mkdir -p "${BUILD_DIR}/sphinx_tempdir" || die
+	local -x SPHINX_TEST_TEMPDIR="${BUILD_DIR}/sphinx_tempdir"
+
+	local EPYTEST_DESELECT=(
+		# these tests require Internet access
+		tests/test_build_latex.py::test_latex_images
+		tests/test_build_linkcheck.py::test_defaults
+		tests/test_build_linkcheck.py::test_defaults_json
+		tests/test_build_linkcheck.py::test_anchors_ignored
+		# TODO
+		tests/test_ext_autodoc.py::test_cython
+		tests/test_ext_autodoc_autoclass.py::test_classes
+		tests/test_ext_autodoc_autofunction.py::test_classes
+		tests/test_ext_inheritance_diagram.py::test_import_classes
+		# looks like a bug in lualatex
+		"tests/test_build_latex.py::test_build_latex_doc[lualatex-howto]"
+		"tests/test_build_latex.py::test_build_latex_doc[lualatex-manual]"
+	)
+	[[ ${EPYTHON} == pypy3 ]] && EPYTEST_DESELECT+=(
+		tests/test_ext_autodoc.py::test_autodoc_inherited_members_None
+		tests/test_ext_autodoc.py::test_automethod_for_builtin
+		tests/test_ext_autodoc.py::test_cython
+		tests/test_ext_autodoc.py::test_partialfunction
+		tests/test_ext_autodoc_autoclass.py::test_autodoc_process_bases
+		tests/test_ext_autodoc_autoclass.py::test_show_inheritance_for_decendants_of_generic_type
+		tests/test_ext_autodoc_autoclass.py::test_show_inheritance_for_subclass_of_generic_type
+		tests/test_ext_autodoc_autofunction.py::test_builtin_function
+		tests/test_ext_autodoc_autofunction.py::test_methoddescriptor
+		tests/test_ext_autodoc_automodule.py::test_automodule_inherited_members
+		tests/test_ext_autosummary.py::test_autosummary_generate_content_for_module
+		tests/test_ext_autosummary.py::test_autosummary_generate_content_for_module_skipped
+		tests/test_util_inspect.py::test_isattributedescriptor
+		tests/test_util_typing.py::test_stringify_type_hints_pep_585
+	)
+
+	# note: pytest-xdist causes random test failures
+	epytest
+}