dev-python/sphinx: add 5.1.1

Signed-off-by: Arthur Zamarin <arthurzam@gentoo.org>

2 files changed, 125 insertions, 0 deletions

diff --git a/dev-python/sphinx/Manifest b/dev-python/sphinx/Manifest
index 73c06f7708ae..a993fd2cfc5e 100644
--- a/dev-python/sphinx/Manifest
+++ b/dev-python/sphinx/Manifest
@@ -1,3 +1,4 @@
 DIST Sphinx-4.5.0.tar.gz 6698212 BLAKE2B e6c46d35492c3d3068c4f97e497d33973ca86b40934578804fcec901fa89d2c52b45a7546b835b873846dd16936c1bd34a7b053aec8206c688d974671155fd56 SHA512 b44d2a81ed67adaefe16a07ae0cf053b5e6c775023aaa6c57d7b3950f171deac410e8004f787b151c3c2fc350650aa69a4dc2dc7239d1fd3d351e5194617cb2c
 DIST Sphinx-5.0.2.tar.gz 6729086 BLAKE2B a2cbf8efca673d15e364d0db74a8c5e2c0ff469f2a102317fb9bf23aac12c12ced2593e3a5e2dd0ee2bc114f2018356d382d601a3c7ff9b2943e38b59fe45db4 SHA512 d564697f0b82a9a59dd6a81e7822dbeac00fb6cc98cdc2422f04ec87c5133b5e03057ccdfdcfe38dccff41f6c53262d49f4ee6f77047c579aa2e55370bfe2dc6
 DIST sphinx-5.1.0.gh.tar.gz 6766298 BLAKE2B d12ef1ec0edd931a597457d868e8fc3b68675df266d8bb626021fa098aacd6027af925275ccf482b7a0d1c8d3cf4c872fca96359f433017274d66bbdcc0d7efa SHA512 595f6f75703d0849393043f24ac216e0bc726a6bf9a23964f8c024e42f2558e2c4f184752835e4016da85391d494fd20bb526d7d379fa9198ac97ff5eca605a2
+DIST sphinx-5.1.1.gh.tar.gz 6766329 BLAKE2B ff385abe35d4a700cbb3cd8acc72313f7c923d48b38934cc35ea6128ef6c16eb6a33604daea25f81f60b65951b4623f62cd4c1a482b2c5e7285ce0ddb6226c80 SHA512 23261cabbcc73072134c22e7fb36f4c7911f4284cea9cc7be6006e500d9de65727f43214fb4427d307845cc684b9a569960ed276320855283a33b9542a2a6918
diff --git a/dev-python/sphinx/sphinx-5.1.1.ebuild b/dev-python/sphinx/sphinx-5.1.1.ebuild
new file mode 100644
index 000000000000..ed132f4e10f4
--- /dev/null
+++ b/dev-python/sphinx/sphinx-5.1.1.ebuild
@@ -0,0 +1,124 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{8..11} pypy3 )
+PYTHON_REQ_USE="threads(+)"
+
+inherit distutils-r1
+
+DESCRIPTION="Python documentation generator"
+HOMEPAGE="
+	https://www.sphinx-doc.org/
+	https://github.com/sphinx-doc/sphinx/
+	https://pypi.org/project/Sphinx/
+"
+SRC_URI="
+	https://github.com/sphinx-doc/sphinx/archive/v${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x64-solaris"
+IUSE="doc latex"
+
+RDEPEND="
+	<dev-python/alabaster-0.8[${PYTHON_USEDEP}]
+	>=dev-python/Babel-1.3[${PYTHON_USEDEP}]
+	<dev-python/docutils-0.20[${PYTHON_USEDEP}]
+	dev-python/imagesize[${PYTHON_USEDEP}]
+	>=dev-python/jinja-2.3[${PYTHON_USEDEP}]
+	>=dev-python/pygments-2.0[${PYTHON_USEDEP}]
+	>=dev-python/requests-2.5.0[${PYTHON_USEDEP}]
+	>=dev-python/snowballstemmer-1.1[${PYTHON_USEDEP}]
+	dev-python/sphinxcontrib-applehelp[${PYTHON_USEDEP}]
+	dev-python/sphinxcontrib-devhelp[${PYTHON_USEDEP}]
+	dev-python/sphinxcontrib-jsmath[${PYTHON_USEDEP}]
+	>=dev-python/sphinxcontrib-htmlhelp-2.0.0[${PYTHON_USEDEP}]
+	>=dev-python/sphinxcontrib-serializinghtml-1.1.5[${PYTHON_USEDEP}]
+	dev-python/sphinxcontrib-qthelp[${PYTHON_USEDEP}]
+	dev-python/packaging[${PYTHON_USEDEP}]
+	$(python_gen_cond_dep '
+		>=dev-python/importlib_metadata-4.4[${PYTHON_USEDEP}]
+	' 3.8 3.9)
+	latex? (
+		dev-texlive/texlive-latexextra
+		dev-texlive/texlive-luatex
+		app-text/dvipng
+	)
+	!dev-python/namespace-sphinxcontrib
+"
+BDEPEND="
+	doc? (
+		dev-python/sphinxcontrib-websupport[${PYTHON_USEDEP}]
+		media-gfx/graphviz
+	)
+	test? (
+		dev-python/html5lib[${PYTHON_USEDEP}]
+		virtual/imagemagick-tools[jpeg,png,svg]
+		dev-texlive/texlive-fontsextra
+		dev-texlive/texlive-latexextra
+		dev-texlive/texlive-luatex
+		app-text/dvipng
+	)
+"
+
+PATCHES=(
+	"${FILESDIR}/sphinx-3.2.1-doc-link.patch"
+	"${FILESDIR}/sphinx-4.3.2-doc-link.patch"
+)
+
+distutils_enable_tests pytest
+
+python_prepare_all() {
+	# disable internet access
+	sed -i -e 's:^intersphinx_mapping:disabled_&:' \
+		doc/conf.py || die
+
+	distutils-r1_python_prepare_all
+}
+
+python_compile_all() {
+	if use doc; then
+		esetup.py build_sphinx
+		HTML_DOCS=( "${BUILD_DIR}"/sphinx/html/. )
+	fi
+}
+
+python_test() {
+	mkdir -p "${BUILD_DIR}/sphinx_tempdir" || die
+	local -x SPHINX_TEST_TEMPDIR="${BUILD_DIR}/sphinx_tempdir"
+
+	local EPYTEST_DESELECT=(
+		# these tests require Internet access
+		tests/test_build_latex.py::test_latex_images
+		tests/test_build_linkcheck.py::test_defaults
+		tests/test_build_linkcheck.py::test_defaults_json
+		tests/test_build_linkcheck.py::test_anchors_ignored
+		# TODO
+		tests/test_ext_autodoc_autoclass.py::test_classes
+		tests/test_ext_autodoc_autofunction.py::test_classes
+		tests/test_ext_inheritance_diagram.py::test_import_classes
+	)
+	[[ ${EPYTHON} == pypy3 ]] && EPYTEST_DESELECT+=(
+		tests/test_ext_autodoc.py::test_autodoc_inherited_members_None
+		tests/test_ext_autodoc.py::test_automethod_for_builtin
+		tests/test_ext_autodoc.py::test_cython
+		tests/test_ext_autodoc.py::test_partialfunction
+		tests/test_ext_autodoc_autoclass.py::test_autodoc_process_bases
+		tests/test_ext_autodoc_autoclass.py::test_show_inheritance_for_decendants_of_generic_type
+		tests/test_ext_autodoc_autoclass.py::test_show_inheritance_for_subclass_of_generic_type
+		tests/test_ext_autodoc_autofunction.py::test_builtin_function
+		tests/test_ext_autodoc_autofunction.py::test_methoddescriptor
+		tests/test_ext_autodoc_automodule.py::test_automodule_inherited_members
+		tests/test_ext_autosummary.py::test_autosummary_generate_content_for_module
+		tests/test_ext_autosummary.py::test_autosummary_generate_content_for_module_skipped
+		tests/test_util_inspect.py::test_isattributedescriptor
+		tests/test_util_typing.py::test_stringify_type_hints_pep_585
+	)
+
+	epytest
+}