1 files changed, 47 insertions, 0 deletions
diff --git a/x11-misc/efax-gtk/efax-gtk-3.2.9.ebuild b/x11-misc/efax-gtk/efax-gtk-3.2.9.ebuild
new file mode 100644
index 000000000000..8a7b65d1e87f
--- /dev/null
+++ b/x11-misc/efax-gtk/efax-gtk-3.2.9.ebuild
@@ -0,0 +1,47 @@
+# Copyright 1999-2012 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/x11-misc/efax-gtk/efax-gtk-3.2.9.ebuild,v 1.1 2012/01/14 10:09:48 ssuominen Exp $
+
+EAPI=4
+
+DESCRIPTION="A graphical frontend for the 'efax' application"
+HOMEPAGE="http://efax-gtk.sourceforge.net/"
+SRC_URI="mirror://sourceforge/${PN}/${P}.src.tgz"
+
+LICENSE="GPL-2 LGPL-2.1"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="nls"
+
+RDEPEND=">=dev-libs/glib-2.10
+	media-libs/tiff:0
+	x11-libs/libX11
+	x11-libs/c++-gtk-utils:3
+	x11-libs/gtk+:3"
+DEPEND="${RDEPEND}
+	dev-util/pkgconfig
+	nls? ( sys-devel/gettext )"
+
+DOCS="AUTHORS BUGS ChangeLog README"
+
+src_prepare() {
+	# Prevent sandbox violation with chown/chgrp and existing spooldir
+	sed -i -e '/ch.*lp.*spooldir/d' efax-gtk-faxfilter/Makefile.in || die
+
+	sed -i \
+		-e '/^Encoding/d' \
+		-e '/^Icon/s:.png::' \
+		-e '/^Categories/s:Application;::' \
+		${PN}.desktop || die
+}
+
+src_configure() {
+	econf \
+		$(use_enable nls) \
+		--with-gtk-version=gtk3
+}
+
+pkg_postinst() {
+	local spooldir="${EROOT}"/var/spool/fax
+	[[ -d ${spooldir} ]] && chown lp:lp "${spooldir}"
+}