1 files changed, 47 insertions, 0 deletions
diff --git a/dev-cpp/gtksourceviewmm/gtksourceviewmm-2.10.3.ebuild b/dev-cpp/gtksourceviewmm/gtksourceviewmm-2.10.3.ebuild
new file mode 100644
index 000000000000..f64a3d035043
--- /dev/null
+++ b/dev-cpp/gtksourceviewmm/gtksourceviewmm-2.10.3.ebuild
@@ -0,0 +1,47 @@
+# Copyright 1999-2012 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-cpp/gtksourceviewmm/gtksourceviewmm-2.10.3.ebuild,v 1.1 2012/05/22 03:53:33 tetromino Exp $
+
+EAPI="4"
+GCONF_DEBUG="no"
+GNOME2_LA_PUNT="yes"
+
+inherit gnome2
+
+DESCRIPTION="C++ bindings for gtksourceview"
+HOMEPAGE="http://projects.gnome.org/gtksourceviewmm/"
+
+KEYWORDS="~amd64 ~ppc ~x86"
+IUSE="doc"
+SLOT="2.0"
+LICENSE="LGPL-2.1"
+
+RDEPEND=">=dev-cpp/gtkmm-2.12:2.4
+	dev-cpp/atkmm
+	>=x11-libs/gtksourceview-2.10.0:2.0
+	!>=dev-cpp/libgtksourceviewmm-1"
+
+DEPEND="${RDEPEND}
+	virtual/pkgconfig
+	doc? ( app-doc/doxygen )"
+
+pkg_setup() {
+	DOCS="AUTHORS ChangeLog* NEWS README"
+	G2CONF="${G2CONF}
+		$(use_enable doc documentation)
+		--disable-static"
+}
+
+src_prepare() {
+	gnome2_src_prepare
+
+	# Remove docs from SUBDIRS so that docs are not installed, as
+	# we handle it in src_install.
+	sed -i -e 's|^\(SUBDIRS =.*\)$(doc_subdirs)\(.*\)|\1\2|' Makefile.in || \
+		die "sed Makefile.in failed"
+}
+
+src_install() {
+	gnome2_src_install
+	use doc && dohtml -r docs/reference/html/*
+}