Version bump.

Package-Manager: portage-2.2.7/cvs/Linux x86_64
Manifest-Sign-Key: 0x4AB3E85B4F064CA3

1 files changed, 47 insertions, 0 deletions

diff --git a/dev-util/trinity/trinity-1.3.ebuild b/dev-util/trinity/trinity-1.3.ebuild
new file mode 100644
index 000000000000..b784524732ad
--- /dev/null
+++ b/dev-util/trinity/trinity-1.3.ebuild
@@ -0,0 +1,47 @@
+# Copyright 1999-2013 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-util/trinity/trinity-1.3.ebuild,v 1.1 2013/12/22 02:19:07 radhermit Exp $
+
+EAPI=5
+
+inherit toolchain-funcs
+
+DESCRIPTION="A Linux system call fuzz tester"
+HOMEPAGE="http://codemonkey.org.uk/projects/trinity/"
+SRC_URI="http://codemonkey.org.uk/projects/${PN}/${P}.tgz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="examples"
+
+DEPEND="sys-kernel/linux-headers"
+
+src_prepare() {
+	sed -e 's/^CFLAGS := /CFLAGS +=/' \
+		-e 's/-g -O2//' \
+		-e 's/-D_FORTIFY_SOURCE=2//' \
+		-e '/-o trinity/s/$(CFLAGS)/\0 $(LDFLAGS)/' \
+		-i Makefile || die
+
+	tc-export CC
+}
+
+src_configure() {
+	./configure.sh || die
+}
+
+src_compile() {
+	emake V=1
+}
+
+src_install() {
+	dobin ${PN}
+	dodoc Documentation/* README
+
+	if use examples ; then
+		exeinto /usr/share/doc/${PF}/scripts
+		doexe scripts/*
+		docompress -x /usr/share/doc/${PF}/scripts
+	fi
+}