Version bump, clean old versions.

Package-Manager: portage-2.1.2_rc2-r4

3 files changed, 89 insertions, 1 deletions

diff --git a/dev-util/bzr/ChangeLog b/dev-util/bzr/ChangeLog
index 2eac9b296579..3f9a4eab4ef7 100644
--- a/dev-util/bzr/ChangeLog
+++ b/dev-util/bzr/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for dev-util/bzr
 # Copyright 2002-2006 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-util/bzr/ChangeLog,v 1.25 2006/11/28 17:18:39 marienz Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-util/bzr/ChangeLog,v 1.26 2006/12/05 02:44:19 marienz Exp $
+
+*bzr-0.13 (05 Dec 2006)
+
+  05 Dec 2006; Marien Zwart <marienz@gentoo.org> -bzr-0.11.ebuild,
+  -bzr-0.13_rc1.ebuild, +bzr-0.13.ebuild:
+  Version bump, clean old versions.
 
 *bzr-0.13_rc1 (28 Nov 2006)
 
diff --git a/dev-util/bzr/bzr-0.13.ebuild b/dev-util/bzr/bzr-0.13.ebuild
new file mode 100644
index 000000000000..56d8bb4699b1
--- /dev/null
+++ b/dev-util/bzr/bzr-0.13.ebuild
@@ -0,0 +1,79 @@
+# Copyright 1999-2006 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-util/bzr/bzr-0.13.ebuild,v 1.1 2006/12/05 02:44:19 marienz Exp $
+
+inherit distutils bash-completion elisp-common eutils
+
+MY_P=${P/_rc/rc}
+S=${WORKDIR}/${MY_P}
+
+DESCRIPTION="next generation distributed version control"
+HOMEPAGE="http://bazaar-vcs.org/"
+SRC_URI="http://bazaar-vcs.org/releases/src/${MY_P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~ia64 ~ppc ~x86 ~x86-fbsd"
+IUSE="curl emacs test"
+
+python_rdep="dev-python/celementtree
+	>=dev-python/paramiko-1.5
+	curl? ( dev-python/pycurl )"
+DEPEND=">=dev-lang/python-2.4
+	emacs? ( virtual/emacs )
+	test? ( $python_rdep )"
+RDEPEND=">=dev-lang/python-2.4
+	$python_rdep"
+
+PYTHON_MODNAME="bzrlib"
+
+DOCS="HACKING NEWS NEWS.developers doc/*"
+
+
+src_unpack() {
+	unpack ${A}
+	cd "${S}"
+
+	# Install the manpage in /usr/share/man instead of /usr/man
+	epatch "${FILESDIR}/${PN}-0.10-fix-manpage-location.patch"
+}
+
+src_compile() {
+	distutils_src_compile
+	if use emacs; then
+		elisp-compile contrib/emacs/bzr-mode.el || die "Emacs modules failed!"
+	fi
+}
+
+src_install() {
+	distutils_src_install
+	if use emacs; then
+		insinto "${SITELISP}"
+		doins contrib/emacs/bzr-mode.el*
+		elisp-site-file-install "${FILESDIR}/70bzr-gentoo.el"
+	fi
+	insinto /usr/share/zsh/site-functions
+	doins contrib/zsh/_bzr
+	dobashcompletion contrib/bash/bzr
+}
+
+pkg_postinst() {
+	distutils_pkg_postinst
+	use emacs && elisp-site-regen
+	bash-completion_pkg_postinst
+
+	einfo "If you just upgraded from a version of bzr older than 0.9"
+	einfo "you should rename your ~/.bazaar/branches.conf to locations.conf"
+	einfo "(see /usr/share/doc/${PF}/NEWS.gz)"
+}
+
+pkg_postrm() {
+	distutils_pkg_postrm
+	# regenerate site-gentoo if we are merged USE=emacs and unmerged
+	# USE=-emacs
+	has_version virtual/emacs && elisp-site-regen
+}
+
+src_test() {
+	"${python}" bzr --no-plugins selftest || die "bzr selftest failed"
+}
diff --git a/dev-util/bzr/files/digest-bzr-0.13 b/dev-util/bzr/files/digest-bzr-0.13
new file mode 100644
index 000000000000..791e8cebf0e0
--- /dev/null
+++ b/dev-util/bzr/files/digest-bzr-0.13
@@ -0,0 +1,3 @@
+MD5 14278ee54bef1cf65ee13735b134f9dd bzr-0.13.tar.gz 1126005
+RMD160 7df30a2feb06683991ebc74156c528c3c3d69f28 bzr-0.13.tar.gz 1126005
+SHA256 3bb3ef28b23b36f840c8b6f69589770764fa1fd97064d26a4f3fff4066d05237 bzr-0.13.tar.gz 1126005