Version bump.

Package-Manager: portage-2.0.54

4 files changed, 143 insertions, 2 deletions

diff --git a/app-cdr/k3b/ChangeLog b/app-cdr/k3b/ChangeLog
index 2807c2b6e7bc..9ecfd2995caf 100644
--- a/app-cdr/k3b/ChangeLog
+++ b/app-cdr/k3b/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for app-cdr/k3b
 # Copyright 1999-2006 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-cdr/k3b/ChangeLog,v 1.144 2006/03/07 23:33:36 carlo Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-cdr/k3b/ChangeLog,v 1.145 2006/04/12 14:40:55 carlo Exp $
+
+*k3b-0.12.15 (12 Apr 2006)
+
+  12 Apr 2006; Carsten Lohrke <carlo@gentoo.org> +k3b-0.12.15.ebuild:
+  Version bump.
 
 *k3b-0.12.14 (07 Mar 2006)
 
diff --git a/app-cdr/k3b/Manifest b/app-cdr/k3b/Manifest
index 72fc7950f118..c7cf09b60e42 100644
--- a/app-cdr/k3b/Manifest
+++ b/app-cdr/k3b/Manifest
@@ -1,12 +1,14 @@
-MD5 194908357308d0ad88bb7ceb6d2ddece ChangeLog 20139
+MD5 7b5190f31e433232e559185271332641 ChangeLog 20254
 MD5 116e03075e9eb434d80d5f17dd80b658 files/digest-k3b-0.12.11 135
 MD5 c39a69969d8bba48034a6f25800feefc files/digest-k3b-0.12.12 135
 MD5 b3c3534f89ed86b3a424212ab3b7982f files/digest-k3b-0.12.13 135
 MD5 317e1126acc8fb3a2d5a5441467c03fd files/digest-k3b-0.12.14 135
+MD5 092cc482ef7dad2caf41842e8c019e21 files/digest-k3b-0.12.15 135
 MD5 10958f68b572978b06e6700672716464 files/digest-k3b-0.12.8 133
 MD5 251732726ef94edb2a0e4e402d8c5815 k3b-0.12.11.ebuild 3267
 MD5 fbb9da4c62e4d26776574c87e24be4e9 k3b-0.12.12.ebuild 3267
 MD5 7a130d6e5604682f6bf7df899115b884 k3b-0.12.13.ebuild 3272
 MD5 708738a888e93f2657c0a5e567dbe0f6 k3b-0.12.14.ebuild 3272
+MD5 675f9ab9b25e7e00047ace242801dd34 k3b-0.12.15.ebuild 3272
 MD5 4dc831752e6e13e5784f912acb6b01ea k3b-0.12.8.ebuild 3209
 MD5 6cac9f56ab7373612097cef824badcf7 metadata.xml 183
diff --git a/app-cdr/k3b/files/digest-k3b-0.12.15 b/app-cdr/k3b/files/digest-k3b-0.12.15
new file mode 100644
index 000000000000..11cc1c314e2b
--- /dev/null
+++ b/app-cdr/k3b/files/digest-k3b-0.12.15
@@ -0,0 +1,2 @@
+MD5 246607f9d63b94c7f91ac86c108efdc2 k3b-0.12.15.tar.bz2 4000389
+MD5 6cbfd080b3684efae0ed4b4797b5cecb k3b-i18n-0.12.15.tar.bz2 4683857
diff --git a/app-cdr/k3b/k3b-0.12.15.ebuild b/app-cdr/k3b/k3b-0.12.15.ebuild
new file mode 100644
index 000000000000..5dfe59cb8654
--- /dev/null
+++ b/app-cdr/k3b/k3b-0.12.15.ebuild
@@ -0,0 +1,132 @@
+# Copyright 1999-2006 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/app-cdr/k3b/k3b-0.12.15.ebuild,v 1.1 2006/04/12 14:40:56 carlo Exp $
+
+inherit kde eutils
+
+DESCRIPTION="K3b, KDE CD Writing Software"
+HOMEPAGE="http://www.k3b.org/"
+SRC_URI="mirror://sourceforge/k3b/${P}.tar.bz2"
+LICENSE="GPL-2"
+
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~ppc64 ~sparc ~x86"
+IUSE="alsa css dvdr encode ffmpeg flac hal kde mp3 musepack musicbrainz sndfile vcd vorbis"
+
+DEPEND="kde? ( || ( kde-base/kdesu kde-base/kdebase ) )
+	hal? ( sys-apps/dbus sys-apps/hal )
+	media-libs/libsamplerate
+	media-libs/taglib
+	>=media-sound/cdparanoia-3.9.8
+	sndfile? ( media-libs/libsndfile )
+	ffmpeg? ( media-video/ffmpeg )
+	flac? ( media-libs/flac )
+	mp3? ( media-libs/libmad )
+	musepack? ( media-libs/libmpcdec )
+	vorbis? ( media-libs/libvorbis )
+	musicbrainz? ( media-libs/musicbrainz )
+	encode? ( media-sound/lame )
+	alsa? ( media-libs/alsa-lib )"
+
+RDEPEND="${DEPEND}
+	virtual/cdrtools
+	>=app-cdr/cdrdao-1.1.7-r3
+	media-sound/normalize
+	dvdr? ( app-cdr/dvd+rw-tools )
+	css? ( media-libs/libdvdcss )
+	encode? ( media-sound/sox
+	          media-video/transcode )
+	vcd? ( media-video/vcdimager )"
+
+DEPEND="${DEPEND}
+	dev-util/pkgconfig"
+
+need-kde 3.4
+
+I18N="${PN}-i18n-${PV}"
+
+# Supported languages and translated documentation
+LANGS="af bg br bs ca cs cy da de el en_GB es et eu fr ga he hi hu is it ja lt mk nb nl nn pa pl pt pt_BR ro ru se sl sr sr@Latn sv ta tr uk zh_CN"
+
+for X in ${LANGS}; do
+	SRC_URI="${SRC_URI} linguas_${X}? ( mirror://sourceforge/k3b/${I18N}.tar.bz2 )"
+done
+
+pkg_setup() {
+	if use hal && ! built_with_use sys-apps/dbus qt; then
+		eerror "You are trying to compile ${CATEGORY}/${PF} with the \"hal\" USE flag enabled,"
+		eerror "but sys-apps/dbus is not built with Qt support."
+		die
+	fi
+
+	kde_pkg_setup
+}
+
+src_unpack() {
+	kde_src_unpack
+
+	local MAKE_LANGS
+	for X in ${LANGS}; do
+		use linguas_${X} && MAKE_LANGS="${MAKE_LANGS} ${X}"
+	done
+
+	if [ -d "${WORKDIR}/${I18N}" ]; then
+		cd "${WORKDIR}/${I18N}"
+		sed -i -e "s,^SUBDIRS = .*,SUBDIRS = ${MAKE_LANGS}," Makefile.in
+	fi
+}
+
+src_compile() {
+	local myconf="--enable-libsuffix= \
+			--with-external-libsamplerate	\
+			--without-resmgr		\
+			$(use_with kde k3bsetup)	\
+			$(use_with hal)			\
+			$(use_with encode lame)		\
+			$(use_with ffmpeg)		\
+			$(use_with flac)		\
+			$(use_with vorbis oggvorbis)	\
+			$(use_with sndfile)		\
+			$(use_with mp3 libmad)		\
+			$(use_with musepack)		\
+			$(use_with musicbrainz)		\
+			$(use_with alsa)"
+
+	# Build process of K3b
+	kde_src_compile
+
+	# Build process of K3b-i18n
+	local _S=${S}
+	if [ -d "${WORKDIR}/${I18N}" ]; then
+		S="${WORKDIR}/${I18N}"
+		cd "${S}"
+		kde_src_compile
+	fi
+	S=${_S}
+}
+
+src_install() {
+	kde_src_install
+	dodoc FAQ KNOWNBUGS PERMISSIONS
+
+	local _S=${S}
+	if [ -d "${WORKDIR}/${I18N}" ]; then
+		S="${WORKDIR}/${I18N}"
+		cd "${S}"
+		kde_src_install
+	fi
+	S=${_S}
+
+	# Move menu entry
+	if use kde; then
+		mv ${D}/usr/share/applnk/Settings/System/k3bsetup2.desktop ${D}/usr/share/applications/kde/
+	fi
+	rm -fR ${D}/usr/share/applnk/
+}
+
+pkg_postinst() {
+	echo
+	einfo "Make sure you have proper read/write permissions on the cdrom device(s)."
+	einfo "Usually, it is sufficient to be in the cdrom group."
+	echo
+}