Initial commit

This is the initial commit of the new tex-overlay that is used to
develop ebuilds for new versions of TeX Live.

Co-authored-by: Paul Zander <negril.nx@gmail.com>
Signed-off-by: Paul Zander <negril.nx@gmail.com>
Signed-off-by: Florian Schmaus <flow@gentoo.org>

1 files changed, 43 insertions, 0 deletions

diff --git a/dev-tex/biblatex/biblatex-3.19.ebuild b/dev-tex/biblatex/biblatex-3.19.ebuild
new file mode 100644
index 0000000..3b03a29
--- /dev/null
+++ b/dev-tex/biblatex/biblatex-3.19.ebuild
@@ -0,0 +1,43 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit latex-package
+
+DESCRIPTION="Reimplementation of the bibliographic facilities provided by LaTeX"
+HOMEPAGE="https://www.ctan.org/tex-archive/macros/latex/contrib/biblatex https://github.com/plk/biblatex/"
+SRC_URI="mirror://sourceforge/${PN}/${P}.tds.tgz"
+
+LICENSE="LPPL-1.3"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~riscv ~x86"
+IUSE="+biber doc examples"
+
+DEPEND="
+	dev-texlive/texlive-bibtexextra
+	dev-texlive/texlive-latexextra
+	dev-texlive/texlive-plaingeneric
+"
+RDEPEND="${DEPEND}"
+# biblatex and biber must always have compatible versions
+PDEPEND="biber? ( ~dev-tex/biber-2.$(ver_cut 2) )"
+
+S="${WORKDIR}"
+TEXMF=/usr/share/texmf-site
+
+src_install() {
+	insinto "${TEXMF}"
+	doins -r bibtex tex
+
+	dodoc doc/latex/biblatex/{README,CHANGES.md}
+	if use doc ; then
+		pushd doc || die
+		latex-package_src_doinstall doc
+		popd || die
+	fi
+
+	if use examples ; then
+		dodoc -r doc/latex/biblatex/examples
+	fi
+}