# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

EAPI="4"

inherit versionator

MY_P="${PN}$(delete_all_version_separators)"

DESCRIPTION="Picture manager / organizer written in Perl/Tk"
HOMEPAGE="http://mapivi.sourceforge.net/mapivi.shtml"
SRC_URI="mirror://sourceforge/${PN}/Mapivi_Perl/Mapivi$(delete_all_version_separators)/${MY_P}.tar.gz"

IUSE=""
LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86"

DEPEND="
	dev-lang/perl
	dev-perl/Image-MetaData-JPEG
	>=dev-perl/perl-tk-804.025
	dev-perl/ImageInfo
	media-gfx/jhead
	media-gfx/imagemagick
	virtual/jpeg"
RDEPEND=${DEPEND}

S=${WORKDIR}/${MY_P}

src_prepare() {
	sed -i -e 's:$configdir/PlugIns:/usr/share/mapivi/plugins:' mapivi || die
}

src_install() {
	dobin mapivi || die

	exeinto /usr/share/mapivi/plugins
	doexe PlugIns/{Channel-Separator,Join-RGB,checkDir-plugin,filelist-plugin,test-plugin} || die
	dodoc Changes.txt FAQ README Tips.txt || die
}

pkg_postinst() {
	ewarn "If your Gimp version is 2.3 from CVS you should run:"
	ewarn "sed -i 's:gimp-remote -n  :gimp-remote:g' /usr/bin/mapivi"
	ewarn "sed -i '22732,22734s:^.:\#:g' /usr/bin/mapivi"
	ewarn "sed -i '22735s:\#execute:execute:g' /usr/bin/mapivi"
	ewarn "after instalation to have edit in Gimp option work."
}